|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted October 07, 2014 12:01 PM |
|
|
Read DO receiver. Then give to all 196 creatures +1 attack using DO receiver and post here script. (4-5 lines only)
You need to understand basics first.
____________
Era II mods and utilities
|
|
bloodsucker
Legendary Hero
|
posted October 07, 2014 01:29 PM |
|
|
Salamandre said: Read DO receiver. Then give to all 196 creatures +1 attack using DO receiver and post here script. (4-5 lines only)
You need to understand basics first.
I Guess is this.
!!DO44478698/0/196/1; [repeats 196 times starting in 0 and has a step of 1]
!?FU44478698;
!!MA:Ax16/d1; [adds 1 to the monsters attack]
It works.
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted October 07, 2014 02:50 PM |
|
|
Great! So now you know that adding a script in a DO receiver will repeat as many times as is specified. Which means that in order to not repeat it, use a new function.
Now, to go deeper in if/en section, try again and this time give +1 attack to undead, +1 speed to shooters, +1 defense to flyers and +1 damage to all.
|
|
bloodsucker
Legendary Hero
|
posted October 07, 2014 03:27 PM |
|
|
Salamandre said: Great! So now you know that adding a script in a DO receiver will repeat as many times as is specified. Which means that in order to not repeat it, use a new function.
Now, to go deeper in if/en section, try again and this time give +1 attack to undead, +1 speed to shooters, +1 defense to flyers and +1 damage to all.
I also know that starting another function or DO command will not by it self stop the first one from repeting it self.
When I put the +1 to attack after the other DO I got 201 of attack on goblins, Crag maust be satisfied...
Let me ask you more general question. From what I saw while reading !!MA parameters and from Emerald Tower I believe it is easy to give some caracteristics/habilities to creatures (like Undead, Atttack and Return) but if I wanted to make liches summon a force field or firewall in front of them that would be close to impossible. Same with some habilities like Enchanters, MGs and AA/SAs. Am I right?
P.S: I think I prefer to give more attack, speed and damage to Undead while I decrease defense and speed from someone else (let me check who else is on the map), is it ok?
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted October 07, 2014 04:02 PM |
|
|
What's so hard summoning a fire wall if is lych's turn? You have BM:C for that. Don't try force field, is a buggy spell and will crash the game 2 turns later.
bloodsucker said: P.S: I think I prefer to give more attack, speed and damage to Undead while I decrease defense and speed from someone else (let me check who else is on the map), is it ok?
Phew man, this isn't about to who to give, it was just an exercise for you, so you can learn to use creatures flags + if/en receivers. Do that script, will help later.
____________
Era II mods and utilities
|
|
mister_kalu
Known Hero
|
posted October 08, 2014 02:49 AM |
|
|
hello i want to upload a video but there are one thing that i don't know how to do, at least with an invisible trick.
How i change the dispel spell ( none,basic, advanced, expert) to a simple version, which always have advanced water magic, in other words friendly and enemy destination. no mass, no own stacks without change the hero water magic skill between the actions
i suppose UN:C would help me.
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted October 08, 2014 03:13 AM |
|
|
I don't understand a word from what you ask
Please give a very precise example and use logical erm language. In erm, a friendly spell is a spell which can be cast on own units, you ask for a friendly spell then you ask to not be cast on our army. Confused.
____________
Era II mods and utilities
|
|
mister_kalu
Known Hero
|
posted October 08, 2014 03:41 AM |
|
|
okay for example magic arrow can only be casted against (on) enemy stacks, bless can only be casted on friendly stacks ( erm help words). but dispel with advanced water magic, can be casted in both sides of course on one monster, i'm not sure but this is the only spell which possess this speciality,
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted October 08, 2014 04:36 AM |
|
|
So what you want is dispel be mass-effect at advanced water? Like forgetfulness?
|
|
mister_kalu
Known Hero
|
posted October 08, 2014 04:48 AM |
|
|
no, dispel without water skill, and with basic, advanced or expert skill.. i.e always, have "advanced water magic characteristic" "
{Advanced Dispel}
Removes all spell effects from a friendly or hostile creature.
"
not mass effect
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted October 08, 2014 04:53 AM |
|
|
!?PI;
!!UN:C5932110/4/34793 C5932114/2/36864;
!?GM0;
!!UN:C5932110/4/34793 C5932114/2/36864;
____________
Era II mods and utilities
|
|
mister_kalu
Known Hero
|
posted October 09, 2014 04:01 AM |
|
|
Salamandre said: !?PI;
!!UN:C5932110/4/34793 C5932114/2/36864;
!?GM0;
!!UN:C5932110/4/34793 C5932114/2/36864;
yeah it Works but with 1 bug. you can use dispel although nobody have an active spell. the original one show a message
thanks anyway it's ok for me
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted October 09, 2014 04:04 AM |
|
|
Yeah, this code disables all checks for dispel. I think that, if you want better solution, try to ask in russian forums, they know better than me how to work directly in game memory. Erm codes have no effect on dispel.
____________
Era II mods and utilities
|
|
bloodsucker
Legendary Hero
|
posted October 09, 2014 08:44 AM |
|
|
Following Sal's guide to add experience related habilities I found the other atributes and decided to give it a try...
If I write this
!!MA:X136/32768;
my Enchanters really attack twice but in melee combat even if the example given is for archers and the descrition says "note, that if you set this flag to non-shooter, he will attack only once in melee"
The problem remains even if I write it like this
!!MA:X136/4;
!!MA:X136/32768;
Does anyone knows what is happening?
|
|
Hawaiing
Adventuring Hero
|
posted October 10, 2014 03:39 AM |
|
|
mister_kalu said:
Salamandre said: !?PI;
!!UN:C5932110/4/34793 C5932114/2/36864;
!?GM0;
!!UN:C5932110/4/34793 C5932114/2/36864;
yeah it Works but with 1 bug. you can use dispel although nobody have an active spell. the original one show a message
thanks anyway it's ok for me
This would be better.
!?PI;
!!UN:C5932168/2/8171 C5932170/1/144;
!?GM0;
!!UN:C5932168/2/8171 C5932170/1/144;
|
|
bloodsucker
Legendary Hero
|
posted October 10, 2014 06:42 PM |
|
|
bloodsucker said: Following Sal's guide to add experience related habilities I found the other atributes and decided to give it a try...
If I write this
!!MA:X136/32768;
my Enchanters really attack twice but in melee combat even if the example given is for archers and the descrition says "note, that if you set this flag to non-shooter, he will attack only once in melee"
The problem remains even if I write it like this
!!MA:X136/4;
!!MA:X136/32768;
Does anyone knows what is happening?
I didn't saw ths coming...
[Salamandre]
You must add the flags. Shooter is 4, undead 262144 so do !!MA:X171/262148 and it will give both [/]
So to give enchanters shot twice, no retaliaation and no obstacle is 136+4+32+32768+65536+2048 ??? And maybe 16 (alive) or someother things cause the entire def must be on this number, is that it?
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted October 10, 2014 07:41 PM |
|
|
Each creature has its flags already set by default. May be "alive", "undead", "strike twice", "shoot twice", "dragon" and so on.
If you give flags the way you do, by setting a value, you risk to screw the actual flags it has because you don't know which flags already has, so you overwrite them.
If you read the erm help-which gives A FULL EXAMPLE ON HOW TO ADD FLAGS, you should have known that the method of adding flags is different, you must use bits.
So I can only paste here the erm example, which means my answer is pointless, except I will comment for you some of the lines.
!?OB3/6/0; there must be an archer at 3/6/0 [you can use instead PI, instructions (!#) or any other trigger.]
!!IF:M^Set Archer to shoot twice^;
!!MA:X2/?i; check archers flag (i var)
!!VRi:|32768; add to i var "shooting twice" bits (look carefully to syntax). This way, archers keep their "alive" and "shooters" flag, you only add a new one
!!MA:X2/i; set archers to new flag value
You must process same script every time you want to add to a creature a flag it has not yet. Add whatever flags you want for enchanters in the way I show you here, then post script result to see if ok.
|
|
bloodsucker
Legendary Hero
|
posted October 10, 2014 10:21 PM |
|
|
Thank you.
I had already saw that example but you have to admit that your coments are much more clear on whats going on. I thought those numbers were to different properties like in the Experince Adding reciver...
Here is how it goes. It is still possible to visit it over and over cause I'm always finding minor problems.
One is that the summon creatures overlap others when moving/attacking (this used to happen with commander and dragons from Dragonheart).
The other, my MGs killed the adjacent henchman when attacking other creature (!!!!)
-------
ZVSE
!?OB63/67&1000;
!!FU&v1=1:E;
!!IF:Q1^I can greatly improve your units, are u interested?^;
!!FU&-1:E;
****Enchanthers def
!!MA:A136/50;
!!MA:D136/50;
!!MA:E136/75;
!!MA:M136/75;
!!MA:P136/150;
!!MA:S136/20;
!!MA:N136/32;
!!MA:N136/32; ammo
!!MA:X136/?i; shother
!!VRi:|4;
!!MA:X136/i;
!!MA:X136/?i; no obstacle
!!VRi:|2048;
!!MA:X136/i;
!!MA:X136/?i; double strike
!!VRi:|32768;
!!MA:X136/i;
!!MA:X136/?i; no retaliation
!!VRi:|65536;
!!MA:X136/i;
!!EA136:B5/0/////////////;
!!EA136:B6/0/////////////;
!!EA136:B7/0/////////////;
!!EA136:B8/0/////////////;
!!EA136:B9/0/////////////;
!!EA136:B10/0/////////////;
!!EA136:B11/0/////////////;
!!EA136:B12/0/////////////;
!!EA136:B5/1/119/53/0/0/0/0/0/1/1/1/1/1/1; Immunity 5
!!EA136:B6/1/119/112/0/0/0/0/1/1/1/1/1/1/1; Immu Dispel
!!EA136:B7/1/85/150/0/10/20/30/40/50/60/70/80/90/100; Summon MGs
!!EA136:B8/1/75/59/0/10/15/20/25/30/40/50/60/75/100; Berserk
!!EA136:B9/1/115/53/0/1/1/2/2/3/3/4/4/4/4; Haste
!!EA136:B10/1/102/115/0/0/0/0/0/1/1/1/1/1/1; Shoot Close
!!EA136:B11/1/105/61/0/0/0/0/0/1/1/1/1/1/1; Distance
!!EA136:B12/1/115/48/0/0/1/1/1/2/2/2/3/3/4; Prayer
****Master Genies def
!!MA:A37/50;
!!MA:D37/50;
!!MA:E37/75;
!!MA:M37/75;
!!MA:P37/150;
!!MA:S37/20;
!!MA:X37/?i; fly
!!VRi:|2;
!!MA:X37/i;
!!MA:X37/?i; double strike
!!VRi:|32768;
!!MA:X37/i;
!!MA:X37/?i; no retaliation
!!VRi:|65536;
!!MA:X37/i;
!!MA:X37/?i; attack all around
!!VRi:|524288;
!!MA:X37/i;
!!EA37:B5/0/////////////;
!!EA37:B6/0/////////////;
!!EA37:B7/0/////////////;
!!EA37:B8/0/////////////;
!!EA37:B9/0/////////////;
!!EA37:B10/0/////////////;
!!EA37:B11/0/////////////;
!!EA37:B12/0/////////////;
!!EA37:B5/1/119/53/0/0/0/0/0/1/1/1/1/1/1; Immunity 5
!!EA37:B6/1/119/112/0/0/0/0/1/1/1/1/1/1/1; Immu Dispel
!!EA37:B7/1/98/61/0/5/10/15/20/25/30/35/40/45/50; Red. Def
!!EA37:B8/1/102/98/0/0/0/0/0/1/1/1/1/1/1; Attack and return
!!EA37:B9/1/85/150/0/10/20/30/40/50/60/70/80/90/100; Summom SAs
!!EA37:B10/1/75/59/0/10/15/20/25/30/40/50/60/75/100; Berserk
!!EA37:B11/1/101/61/0/10/20/30/40/50/60/70/80/90/100; Death blow
!!EA37:B12/1/102/99/0/0/0/0/0/1/1/1/1/1/1; champion
**** Supreme Archangls def
!!MA:X150/?i; fly
!!VRi:|2;
!!MA:X150/i;
!!MA:X150/?i; double strike
!!VRi:|32768;
!!MA:X150/i;
!!MA:X150/?i; no retaliation
!!VRi:|65536;
!!MA:X150/i;
!!MA:X150/?i; attack all around
!!VRi:|524288;
!!MA:X150/i;
!!MA:A150/75;
!!MA:D150/75;
!!MA:E150/200;
!!MA:M150/200;
!!MA:P150/1250;
!!MA:S150/23;
!!EA150:B5/0/////////////;
!!EA150:B6/0/////////////;
!!EA150:B7/0/////////////;
!!EA150:B8/0/////////////;
!!EA150:B9/0/////////////;
!!EA150:B10/0/////////////;
!!EA150:B11/0/////////////;
!!EA150:B12/0/////////////;
!!EA150:B5/1/119/53/0/0/0/0/0/1/1/1/1/1/1; Immunity 5
!!EA150:B6/1/119/112/0/0/0/0/1/1/1/1/1/1/1; Immu Dispel
!!EA150:B7/1/102/99/0/0/0/0/0/1/1/1/1/1/1; Champion
!!EA150:B8/1/102/98/0/0/0/0/0/1/1/1/1/1/1; Attack & Return
!!EA150:B9/1/74/62/0/5/10/15/25/35/50/65/80/95/100; Blind
!!EA150:B10/1/98/61/0/10/15/20/25/30/40/50/60/70/80; Red. Def.
!!EA150:B11/1/74/78/0/10/15/20/25/30/35/40/45/50/60; Dispel Enemy
!!EA150:B12/1/75/59/0/10/15/20/25/30/40/50/60/75/100; Berserk
**** Vampires def
!!MA:A63/50;
!!MA:D63/50;
!!MA:E63/75;
!!MA:M63/73;
!!MA:P63/150;
!!MA:S63/20;
!!MA:X63/?i; fly
!!VRi:|2;
!!MA:X63/i;
!!MA:X63/?i; double strike
!!VRi:|32768;
!!MA:X63/i;
!!MA:X63/?i; no retaliation
!!VRi:|65536;
!!MA:X63/i;
!!MA:X63/?i; attack all around
!!VRi:|524288;
!!MA:X63/i;
!!EA63:B5/0/////////////;
!!EA63:B6/0/////////////;
!!EA63:B7/0/////////////;
!!EA63:B8/0/////////////;
!!EA63:B9/0/////////////;
!!EA63:B10/0/////////////;
!!EA63:B11/0/////////////;
!!EA63:B12/0/////////////;
!!EA63:B5/1/119/53/0/0/0/0/0/1/1/1/1/1/1; Immunity 5
!!EA63:B6/1/119/112/0/0/0/0/1/1/1/1/1/1/1; Immu Dispel
!!EA63:B7/1/102/98/0/0/0/0/0/1/1/1/1/1/1; Attack & Return
!!EA63:B8/1/98/61/0/10/15/20/25/30/40/50/60/70/80; Red. Def.
!!EA63:B9/1/102/99/0/0/0/0/0/1/1/1/1/1/1; Champion
!!EA63:B10/1/101/61/0/10/20/30/40/50/60/70/80/90/100; Death blow
!!EA63:B11/1/74/78/0/10/15/20/25/30/35/40/45/50/60; Dispel Enemy
!!EA63:B12/1/74/50/0/10/15/20/25/30/40/50/65/80/100; Sorrow
**** Liches def
!!MA:A64/50;
!!MA:D64/50;
!!MA:E64/77;
!!MA:M64/75;
!!MA:P64/40;
!!MA:S64/19;
!!MA:N64/24;
!!MA:N64/32; ammo
!!MA:X64/?i; shother
!!VRi:|4;
!!MA:X64/i;
!!MA:X64/?i; no obstacle
!!VRi:|2048;
!!MA:X64/i;
!!MA:X64/?i; double strike
!!VRi:|32768;
!!MA:X64/i;
!!MA:X64/?i; no retaliation
!!VRi:|65536;
!!MA:X64/i;
!!EA64:B5/0/////////////;
!!EA64:B6/0/////////////;
!!EA64:B7/0/////////////;
!!EA64:B8/0/////////////;
!!EA64:B9/0/////////////;
!!EA64:B10/0/////////////;
!!EA64:B11/0/////////////;
!!EA64:B12/0/////////////;
!!EA64:B5/1/119/53/0/0/0/0/0/1/1/1/1/1/1; Immunity 5
!!EA64:B6/1/119/112/0/0/0/0/1/1/1/1/1/1/1; Immu Dispel
!!EA64:B7/1/85/67/0/10/20/30/40/50/60/70/80/90/100; Summon Death Knights
!!EA64:B8/1/102/115/0/0/0/0/0/1/1/1/1/1/1; Shoot Close
!!EA64:B9/1/74/78/0/10/15/20/25/30/35/40/45/50/60; Dispel Enemy
!!EA64:B10/1/75/57/0/1/1/1/2/2/2/3/3/3/4; Fire Shield
!!EA64:B11/1/115/41/0/1/1/2/2/3/3/4/4/4/4; Bless
!!EA64:B12/1/75/59/0/0/5/10/15/20/30/40/50/60/75; Berserk
**** Blood Dragons def
!!MA:A154/75;
!!MA:D154/75;
!!MA:E154/175;
!!MA:M154/150;
!!MA:P154/750;
!!MA:S154/21;
!!MA:X154/?i; fly
!!VRi:|2;
!!MA:X154/i;
!!MA:X154/?i; double strike
!!VRi:|32768;
!!MA:X154/i;
!!MA:X154/?i; no retaliation
!!VRi:|65536;
!!MA:X154/i;
!!MA:X154/?i; attack all around
!!VRi:|524288;
!!MA:X154/i;
!!EA154:B5/1/119/53/0/0/0/0/0/1/1/1/1/1/1; Immunity 5
!!EA154:B6/1/119/112/0/0/0/0/1/1/1/1/1/1/1; Immu Dispel
!!EA154:B7/1/102/98/0/0/0/0/0/1/1/1/1/1/1; Attack & Return
!!EA154:B8/1/98/61/0/10/15/20/25/30/40/50/60/70/80; Red. Def.
!!EA154:B9/1/102/99/0/0/0/0/0/1/1/1/1/1/1; Champion
!!EA154:B10/1/101/61/0/10/20/30/40/50/60/70/80/90/100; Death blow
!!EA154:B11/1/74/62/0/10/15/20/25/30/35/40/45/50/60; Blind
!!EA154:B12/1/74/50/0/10/15/20/25/30/40/50/65/80/100; Sorrow
-------
I was thinking in use your big and strange Dragon Utopia for a "hard" custom battle to give this has a reward...
You may think that code is OP but strangely) this single line is more:
!!HE-1:X6/56/64/68;
Thinking of making an object open a dialog with several options to change specialty.
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted October 10, 2014 10:32 PM |
|
|
Click on the red cross icon (smiles box) to disable smiles when displaying erm codes.
Bits: you don't need to check every time i var, just do it as this:
!!MA:X154/?i; ask bits
!!VRi:|2; add them all one after the other
!!VRi:|32768;
!!VRi:|65536;
!!VRi:|524288;
!!MA:X154/i; set the final result
____________
Era II mods and utilities
|
|
bloodsucker
Legendary Hero
|
posted October 10, 2014 10:44 PM |
|
|
Salamandre said: Click on the red cross icon (smiles box) to disable smiles when displaying erm codes.
Bits: you don't need to check every time i var, just do it as this:
!!MA:X154/?i; ask bits
!!VRi:|2; add them all one after the other
!!VRi:|32768;
!!VRi:|65536;
!!VRi:|524288;
!!MA:X154/i; set the final result
Thank you, I will do it like that next time but there is no problem with this one, right?
It is possible nobody knows it's numbers but I'm almost sure this is the way to replicate Archangels, MGs and Enchanters habilities.
|
|
|