Heroes of Might and Magic Community
visiting hero! Register | Today's Posts | Games | Search! | FAQ/Rules | AvatarList | MemberList | Profile


Age of Heroes Headlines:  
5 Oct 2016: Heroes VII development comes to an end.. - read more
6 Aug 2016: Troubled Heroes VII Expansion Release - read more
26 Apr 2016: Heroes VII XPack - Trial by Fire - Coming out in June! - read more
17 Apr 2016: Global Alternative Creatures MOD for H7 after 1.8 Patch! - read more
7 Mar 2016: Romero launches a Piano Sonata Album Kickstarter! - read more
19 Feb 2016: Heroes 5.5 RC6, Heroes VII patch 1.7 are out! - read more
13 Jan 2016: Horn of the Abyss 1.4 Available for Download! - read more
17 Dec 2015: Heroes 5.5 update, 1.6 out for H7 - read more
23 Nov 2015: H7 1.4 & 1.5 patches Released - read more
31 Oct 2015: First H7 patches are out, End of DoC development - read more
5 Oct 2016: Heroes VII development comes to an end.. - read more
[X] Remove Ads
LOGIN:     Username:     Password:         [ Register ]
HOMM1: info forum | HOMM2: info forum | HOMM3: info mods forum | HOMM4: info CTG forum | HOMM5: info mods forum | MMH6: wiki forum | MMH7: wiki forum
Heroes Community > Heroes 3.5 - WoG and Beyond > Thread: ERM help and discussion
Thread: ERM help and discussion This Popular Thread is 407 pages long: 1 50 100 150 200 ... 243 244 245 246 247 ... 250 300 350 400 407 · «PREV / NEXT»
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted November 08, 2014 12:00 AM

You don't understand. Give sylvia the shackles. Then give your hero as many stoic watchmans arties to fill his backpack (set to 70).

When battle ends, shackles message doesn't trigger because your backpack is full.

Then you remove all stoics. Try the code and will see effect.
____________
Era II mods and utilities

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
bloodsucker
bloodsucker


Legendary Hero
posted November 08, 2014 04:38 AM
Edited by bloodsucker at 12:05, 08 Nov 2014.

Salamandre said:
You don't understand. Give sylvia the shackles. Then give your hero as many stoic watchmans arties to fill his backpack (set to 70).

When battle ends, shackles message doesn't trigger because your backpack is full.

Then you remove all stoics. Try the code and will see effect.


I understand perfectly, if I remove ALL copies of Stoic Whatchman the ones I already have to open the map first day will be gone, same with any copy I gain from leveling up... But the problem is only with the chosen artifact, if it's something I don't want then no problem - I go for Speculum.

P.S. Your idea has a problem (I was so lucky I leveled up in the first battle), if you are playing with the "heroes recieve an artifact when level up" (wich is a must with MoC), you still have the backpack full and you don't recieve it. I go for some "Brutes money": give mithril, give resources, give prims, etc...

P.P.S. This is the code for the new Eternal Battle 2 (the weak one) plus the two functions that are in the Initial Settings script (that has now over 1000 lines )

But this gave me and idea, I'm going to code Speculum and Spyglass to give (only for humans/ME) +12 or 15 of radius.
----------------
ZVSE

!?OB230/52/0&1000;
!!PO998:S?v1; ask what value in PO, v998 holds current object coordinates
!!IF&v1>=250:M^You have exausted your battles here for today.^; exit if already 150 times today
!!FU&v1>=250:E;

!!IF:M^You are in your %V1 battle here today^;
!!VRv1:+1; increment +1 after each visit
!!PO998:Sv1; set PO to v1

!!FU&v1=1:E;
!!IF:Q1^Here you can find easy oponents to improve your skills, want to give it a try?^;
!!FU&-1:E;
!!HE-1:P?y1/?y2/?y3;     [Get position]

!!FU45325:P;

!!HE-1:Tv998/v999/v1000/0/1;

!?BA0&v998=230/v999=52/v1000=0;
!!BA:Q0;

!!BA:H1/3;

!!VRv2:S0 T8; randomize v2 to 0-8
!!if&v2=0:;
  !!BA:M1/0/0/40 M1/1/0/40 M1/2/0/40 M1/3/1/60;
  !!BA:M1/4/0/40 M1/5/0/40 M1/6/0/40;
!!en:;
!!if&v2=1:;
  !!BA:M1/0/14/40 M1/1/15/50 M1/2/14/40 M1/3/14/40;
  !!BA:M1/4/14/40 M1/5/15/50 M1/6/14/40;
!!en:;
!!if&v2=2:;
  !!BA:M1/0/16/30 M1/1/17/30 M1/2/16/30 M1/3/17/30;
  !!BA:M1/4/16/30 M1/5/17/30 M1/6/16/30;
!!en:;
!!if&v2=3:;
  !!BA:M1/0/29/100 M1/3/29/100  M1/6/29/100;
!!en:;
!!if&v2=4:;
  !!BA:M1/0/30/30 M1/2/30/30 M1/3/31/40 M1/5/30/30 M1/6/30/30;
!!en:;
!!if&v2=5:;
  !!BA:M1/0/43/50 M1/1/43/50 M1/2/43/50 M1/3/44/50;
  !!BA:M1/4/43/50 M1/5/43/50 M1/6/43/50;
!!en:;

!!if&v2=6:;
  !!BA:M1/0/56/40 M1/1/56/40 M1/2/56/40 M1/3/57/60;
  !!BA:M1/4/56/40 M1/5/56/40 M1/6/56/40;
!!en:;

!!if&v2=7:;
  !!BA:M1/0/58/30 M1/1/58/40 M1/2/58/30 M1/3/58/40;
  !!BA:M1/4/58/30 M1/5/58/40 M1/6/58/30;
!!en:;

!!if&v2=8:;
  !!BA:M1/0/98/40 M1/1/98/40 M1/2/98/40 M1/3/99/60;
  !!BA:M1/4/98/40 M1/5/98/40 M1/6/98/40;
!!en:;

!?BF&v998=230/v999=52/v1000=0;;
!!DO199001/21/27/1:P10; give max experience to neutrals/AI (this will proceed stacks 21-27, which means defender stacks)
!!BF:C;
!!BF:O65/92;


!?BA1&v998=230/v999=52/v1000=0;

!!HE-1:O?v1; see if hero dead or victorious
!!FU&v1<0:E; exit if dead

!!HE3:A3/0/1/1;    remove spellBook


!!FU45326:P; Function to trade the Shackles of war for some goodies

!!VRv3:S0 R7; randomize v3 to 0-7
!!VRy1&v3=0:S8;
!!VRy1&v3=1:S14;
!!VRy1&v3=2:S20;
!!VRy1&v3=3:S26;
!!VRy1&v3=4:S54;
!!VRy1&v3=5:S60;
!!VRy1&v3=6:S97;
!!VRy1&v3=7:S156;
!!IF:Q1/8/y1/1^You've found an artifact^;
!!HE-1:A4/y1;

!#TM2:S1/999/1/255;
!?TM2;
!!PO230/52/0:S0;

-------------
*** Bad Ass Sylvia

!?FU45325;

!!HE3:X0/23;   Slyvia is now Armourer specialist
!!HE3:A2/0/?y5;    Give Spell book if it doesn't have one
!!HE3&y5=0:A1/0/17;
!!HE3:A1/125/10;   Give Shackles of War
!!HE3:S15/3 S17/3 S22/1 S23/2;     Give Expert Air and Earth and Advanced Offense and Armourer
!!HE3:M27/1 M37/1 M41/1 M46/1 M53/1 M54/1; Give some spells
!!HE3:F5/5/3/3;    Increase primary skills
!!HE3:I30;         Give the apropriate spellpoints


!!VRv7:S0 T6;    Choose random faces, hero classes and names for Slyvia
!!if&v7=0:;
  !!HE3:L1^BSylv01S.pcx^;
  !!HE3:L2^BSylv01L.pcx^;
  !!HE3:B2/12;
  !!VRz953:S^Dymos^;
!!en:;
!!if&v7=1:;
  !!HE3:L1^BSylv02S.pcx^;
  !!HE3:L2^BSylv02L.pcx^;
  !!HE3:B2/5;
  !!VRz953:S^Mytos^;
!!en:;
!!if&v7=2:;
  !!HE3:L1^BSylv03S.pcx^;
  !!HE3:L2^BSylv03L.pcx^;
  !!HE3:B2/13;
  !!VRz953:S^Tresh^;
!!en:;
!!if&v7=3:;
  !!HE3:L1^BSylv04S.pcx^;
  !!HE3:L2^BSylv04L.pcx^;
  !!HE3:B2/16;
  !!VRz953:S^Torsh^;
!!en:;
!!if&v7=4:;
  !!HE3:L1^BSylv05S.pcx^;
  !!HE3:L2^BSylv05L.pcx^;
  !!HE3:B2/10;
  !!VRz953:S^Apoch^;
!!en:;
!!if&v7=5:;
  !!HE3:L1^BSylv06S.pcx^;
  !!HE3:L2^BSylv06L.pcx^;
  !!HE3:B2/4;
  !!VRz953:S^Doom^;
!!en:;
!!if&v7=6:;
  !!HE3:L1^BSylv07S.pcx^;
  !!HE3:L2^BSylv07L.pcx^;
  !!HE3:B2/6;
  !!VRz953:S^Nespos^;
!!en:;
!!HE3:B0/z953;
----------------------------------------
!?FU45326; Function to trade the Shackles of war for some goodies
!!HE-1:A2/125/?y4; check the number of shackles hero has
!!if&y4>1:;  if number of shackles > 1
   !!HE-1:A3/125/1/1;    remove shackles
   !!VRv4:S0 R3;   Randomize a value to choose some different bonus
   !!if&v4=0:; The rest of the function basicly does the same thing - check a value to choose -
      !!VRy1&v4=0:S3450; the type of bonus, give a custom message, give a certain quantity of the bonus
      !!IF:Q1/17/y1/1^You need a lot of experience so you trade the Shackles of War for some.^;
      !!HE-1:Ed3450;
   !!en:;
   !!if&v4=1:;
      !!VRy1&v4=1:S15;
      !!IF:Q1/7/y1/1^You need a lot of mithrill so you trade the Shackles of War for some.^;
      !!OW:R-1/7/d15;
   !!en:;
   !!if&v4=2:;
      !!VRv5:S0 R8;
      !!if&v5<5:;
          !!IF:M^You trade the Shackles of War for an improvement to your combat efficieny but you were cheated.^;
      !!el:;
          !!if&v5=5:;
             !!VRy1&v5=5:S1;
             !!IF:Q1/31/y1/1^You trade the Shackles of War for an improvement to your combat efficieny.^;
             !!HE-1:Fd1/d/d/d;
          !!en:;
          !!if&v5=6:;
             !!VRy1&v5=6:S1;
             !!IF:Q1/32/y1/1^You trade the Shackles of War for an improvement to your combat efficieny.^;
             !!HE-1:Fd/d1/d/d;
          !!en:;
          !!if&v5=7:;
             !!VRy1&v5=7:S1;
             !!IF:Q1/33/y1/1^You trade the Shackles of War for an improvement to your combat efficieny.^;
             !!HE-1:Fd/d/d1/d;
          !!en:;
          !!if&v5=8:;
             !!VRy1&v5=8:S1;
             !!IF:Q1/34/y1/1^You trade the Shackles of War for an improvement to your combat efficieny.^;
             !!HE-1:Fd/d/d/d1;
          !!en:;
      !!en:;
   !!en:;
   !!if&v4=3:;
      !!VRv6:S0 R6;
      !!if&v6=0:;
        !!VRy1&v6=0:S20;
        !!OW:R-1/0/d20;
        !!IF:Q1/0/y1/1^You need a lot of wood so you trade the Shackles of War for some.^;
      !!en:;
      !!if&v6=1:;
        !!VRy1&v6=1:S10;
        !!OW:R-1/1/d10;
        !!IF:Q1/1/y1/1^You need a lot of mercury so you trade the Shackles of War for some.^;
      !!en:;
      !!if&v6=2:;
        !!VRy1&v6=2:S20;
        !!OW:R-1/2/d20;
        !!IF:Q1/2/y1/1^You need a lot of ore so you trade the Shackles of War for some.^;
      !!en:;
      !!if&v6=3:;
        !!VRy1&v6=3:S10;
        !!OW:R-1/3/d10;
        !!IF:Q1/3/y1/1^You need a lot of sulfur so you trade the Shackles of War for some.^;
      !!en:;
      !!if&v6=4:;
        !!VRy1&v6=4:S10;
        !!OW:R-1/4/d10;
        !!IF:Q1/4/y1/1^You need a lot of crystal so you trade the Shackles of War for some.^;
      !!en:;
      !!if&v6=5:;
        !!VRy1&v6=5:S10;
        !!OW:R-1/5/d10;
        !!IF:Q1/5/y1/1^You need a lot of gems so you trade the Shackles of War for some.^;
      !!en:;
      !!if&v6=6:;
        !!VRy1&v6=6:S4000;
        !!OW:R-1/6/d4000;
        !!IF:Q1/6/y1/1^You need a lot of gold so you trade the Shackles of War for some.^;
      !!en:;
   !!en:;
!!en:;


 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
bloodsucker
bloodsucker


Legendary Hero
posted November 08, 2014 11:50 AM

This is my code for the new PowerUp Tower to substitute the Emerald Tower.
I've been testing it and has far as I notice everything is working fine. Except for the code that isn't there...
It builds a list of creatures with repeated names and it doesn't check the habilities the creatures can learn and the ones they already have.
I've tried to use Pulver's code but that guy must take LSD before sitting in front of the computer cause his code is perfect alucination. He is always doing something else besides what you expect and in betwen and the use of strings doesn't help understanding what is going on. As if the code wasn't hard enouch he still has all those "gnome" interactions to give and take this and that and then he calculates the number of creatures and if you have them and if the name is singular or plural or if you are using mithril or not and so on. I always get lost and end up copying a mess that doesn't do anything of what I want.
I hate to ask you this can u help me doing those filters?

-------------
ZVSE

!#UN&v1=1:B0/1; [Enable Mithril]

!?OB63/34&1000;
!!IF:M^At this power up you can increase your creatures basic stats by a modest fee in resources.^;

!!OW:R-1/0/?y-1;   Check for resources
!!OW:R-1/1/?y-2;
!!OW:R-1/2/?y-3;
!!OW:R-1/3/?y-4;
!!OW:R-1/4/?y-5;
!!OW:R-1/5/?y-6;
!!OW:R-1/7/?v6119;
!!VRz10|y-1<5/y-2<5/y-3<5/y-4<5/y-5<5/y-6<5:S^Not enough resources!^;
!!IF|y-1<5/y-2<3/y-3<5/y-4<3/y-5<3/y-6<3:D5/10;
!!IF|y-1<5/y-2<3/y-3<5/y-4<3/y-5<3/y-6<3:E1/5;
!!FU28713&y-1>=5/y-2>=3/y-3>=5/y-4>=3/y-5>=3/y-6>=3:P;

!?FU28712;     Create a list of the creatures present in the hero's army
!!HE-1:C0/x16/?y1/?y2;
!!UN&x16=0/y1>-1:N3/1/y1/0;
!!UN&x16=1/y1>-1:N3/2/y1/0;
!!UN&x16=2/y1>-1:N3/3/y1/0;
!!UN&x16=3/y1>-1:N3/4/y1/0;
!!UN&x16=4/y1>-1:N3/5/y1/0;
!!UN&x16=5/y1>-1:N3/6/y1/0;
!!UN&x16=6/y1>-1:N3/7/y1/0;

!?FU28713;     Present the list for chosing a creature
!!VRz1:S^^;
!!VRz2:S^^;
!!VRz3:S^^;
!!VRz4:S^^;
!!VRz5:S^^;
!!VRz6:S^^;
!!VRz7:S^^;

!!VRz8:S^Select the creature which you want to modify:^;
!!VRz9:S^Exit^;
!!DO28712/0/6/1:P;
!!IF:G1/6111/0/8/1/2/3/4/5/6/7/9;

!!FU28713&v6111=128:E;

!!VRy3&v6111=1:S0;
!!VRy3&v6111=2:S1;
!!VRy3&v6111=4:S2;
!!VRy3&v6111=8:S3;
!!VRy3&v6111=16:S4;
!!VRy3&v6111=32:S5;
!!VRy3&v6111=64:S6;
!!HE-1&v6111<128:C0/y3/?v6114/?y2;
!!FU28714&v6111<128:P;

!?FU28714;    Present a list of Skills to chose an improvement
!!VRz31:S^Attack^;
!!VRz32:S^Defense^;
!!VRz33:S^Damage^;
!!VRz34:S^Health^;
!!VRz35:S^Speed^;

!!MA:Nv6114/?y4;    number of shots
!!if&y4>0/y4<48;
 !!VRz36:S^48 Shots^;
!!en:;

!!MABv6114/?y5;
!!if&y5>0;
 !!VRz37:S^One extra cast (costs an extra 3 of mithril)^;
!!en:;

!!VRz38:S^A new special hability (costs an extra 5 of mithril)^;

!!VRz39:S^Exit^;
!!VRz20:S^Choose the skill you want to improve^;
!!IF:G1/6112/0/20/31/32/33/34/35/36/37/38/39;

!!FU28714&v6112=256:E;

!!if&v6112=1:;   [Attack bonus]
 !!MA:Av6114/d5;
!!en:;
!!if&v6112=2:;  [Defense bonus]
 !!MA:Dv6114/d5;
!!en:;
!!if&v6112=4:;  [Damage  bonus]
 !!MA:Ev6114/?y1;   check max damage
 !!VRy2:Sy1 :4;   get 25%
 !!VRy2&y2<3:S3;  if result less then 3 then set to 3
 !!MA:Ev6114/dy2;   give bonus

 !!MA:Mv6114/?y1;   check min damage
 !!VRy2:Sy1 :4;   get 25%
 !!VRy2&y2<3:S3;  if result less then 3 then set to 3
 !!MA:Mv6114/dy2;   give bonus
!!en:;
!!if&v6112=8:;  [Health  bonus]
 !!MA:Pv6114/?y1;   check health
 !!VRy2:Sy1 :4;   get 25%
 !!VRy2&y2<5:S5;  if result less then 5 then set to 5
 !!MA:Pv6114/dy2;   give bonus
!!en:;
!!if&v6112=16:; [Speed  bonus]
 !!MA:Sv6114/?y1;   check speed
 !!VRy2:Sy1 :4;   get 25%
 !!VRy2&y2<1:S1;  if result less then 1 then set to 1
 !!MA:Sv6114/dy2;   give bonus
!!en:;

!!if&v6112=32:;   [Shots bonus]
 !!MA:Nv6114/48;
!!en:;

!!if&v6112=64:;   [Spell casting bonus]
 !!if&v6119<3:;
    !!IF:M^Not enouch mithril^;
    !!FU28714:E;
 !!en:;
 !!OW:R-1/7/d-3;
 !!MA:Bv6114/d1;
!!en:;

!!if&v6112=128:; [Special Habilities]
 !!if&v6119<5:;
    !!IF:M^Not enouch mithril^;
    !!FU28714:E;
 !!en:;
 !!FU28715:P;
!!en:;

!!IF&v6112<256:M^Done!^;
!!FU28711&v6112<256:P;

!?FU28715;

!!VRz41:S^Fly^;       List of special habilities
!!VRz42:S^Dragon Breath^;
!!VRz43:S^No Moral^;
!!VRz44:S^Two Attacks^;
!!VRz45:S^Attack All Around^;
!!VRz46:S^No Retaliation^;
!!VRz47:S^Immune to Mind Spells^;
!!VRz48:S^Immune to Fire Spells^;
!!VRz49:S^No Close Combat Penalty^;

!!VRz50:S^Exit^;
!!VRz40:S^Choose the hability you want to add^;
!!IF:G1/6115/0/40/41/42/43/44/45/46/47/48/49/50;

!!FU28715&v6115=512:E;

!!VRy2&v6115=1:S2;       [Fly: y2]
!!VRy2&v6115=2:S8;       [Extended Attack: y2]
!!VRy2&v6115=4:S131072;  [Unaffected by Morale: y2]
!!VRy2&v6115=8:S32768;   [Two Attacks: y2]
!!VRy2&v6115=16:S524288;  [Attack All Around: y2]
!!VRy2&v6115=32:S65536;   [No Retaliation: y2]
!!VRy2&v6115=64:S1024;    [Immunity to Mind Spells: y2]
!!VRy2&v6115=128:S16384;   [Immunity to Fire Spells: y2]
!!VRy2&v6115=256:S4096;   [No Close Combat Penalty: y2]

!!MA:Xv6114/?y1; [Read Creature Flags: y1]
!!VRy1:|y2; [OR Creature Flags (y1) with Special Ability bit (y2): y1]
!!MA:Xv6114/y1; [Set updated Creature Flags: y1]

!!OW:R-1/7/d-5;

!?FU28711;        Remove resources for payment
!!OW:R-1/0/d-5;
!!OW:R-1/1/d-3;
!!OW:R-1/2/d-5;
!!OW:R-1/3/d-3;
!!OW:R-1/4/d-3;
!!OW:R-1/5/d-3;

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted November 08, 2014 05:47 PM
Edited by Salamandre at 17:55, 08 Nov 2014.

Well, for abilities not showing if creature has, you must replace FU28715, this part, and add those flags:

!?FU28715;
!!MA:Xv6114/?v3;
!!VRy1:Sv3;
!!VRy1:&2;
!!VRz41&y1=0:S^Fly^;       List of special habilities
!!VRz41&y1=2:S^^;
!!VRy1:Sv3;
!!VRy1:&8;
!!VRz42&y1=0:S^Dragon Breath^;
!!VRz42&y1=8:S^^;
!!VRy1:Sv3;
!!VRy1:&131072;
!!VRz43&y1=0:S^No Moral^;
!!VRz43&y1=131072:S^^;
!!VRy1:Sv3;
!!VRy1:&32768;
!!VRz44&y1=0:S^Two Attacks^;
!!VRz44&y1=32768:S^^;
!!VRy1:Sv3;
!!VRy1:&524288;
!!VRz45&y1=0:S^Attack All Around^;
!!VRz45&y1=524288:S^^;
!!VRy1:Sv3;
!!VRy1:&65536;
!!VRz46&y1=0:S^No Retaliation^;
!!VRz46&y1=65536:S^^;
!!VRy1:Sv3;
!!VRy1:&1024;
!!VRz47&y1=0:S^Immune to Mind Spells^;
!!VRz47&y1=1024:S^^;
!!VRy1:Sv3;
!!VRy1:&16384;
!!VRz48&y1=0:S^Immune to Fire Spells^;
!!VRz48&y1=16384:S^^;
!!VRy1:Sv3;
!!VRy1:&4096;
!!VRz49&y1=0:S^No Close Combat Penalty^;
!!VRz49&y1=4096:S^^;
!!VRz50:S^Exit^;
!!VRz40:S^Choose the hability you want to add^;
!!IF:G1/6115/0/40/41/42/43/44/45/46/47/48/49/50;
!!FU&v6115=512:E;

So this part works.

But then I tested your script and its totally messed, with resources disappearing even if I click on exit, wrong syntax often and such.
Sorry but I have no time for making your mod for you. You made great progress, but some scripts are too heavy for you right now. It took me one year before I was able to do a similar script to emerald tower, which is rather complex.

bloodsucker said:

I've tried to use Pulver's code but that guy must take LSD before sitting in front of the computer


No, I rather think you are on LSD to believe you can understand Fnord's codes in one month. That guy is our erm father.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
artu
artu


Promising
Undefeatable Hero
My BS sensor is tingling again
posted November 08, 2014 06:08 PM

Oh, Holy ERM father, who dares to speak against thy might!

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Hero_Of_Light
Hero_Of_Light


Responsible
Supreme Hero
posted November 08, 2014 06:22 PM

I was wondering if it is possible to have a third upgrade for a creature without the use of the WoG option "Universal Creature Upgrades".

I think I asked this before... With the WoG option enabled the third upgrades for creatures are available in towns as well (and not just in Hill Forts). However, I would like to have the third upgrades without this option. Is it possible?

I don't really need this to work for many creatures... All I need is these third upgrades:

Creature 142 to 49
Creature 85 to 87
Creature 101 to 173

These interchangeable creatures:

Creature 57 to 56
Creature 86 to 140

And the four Elementals (112-115) all to upgrade to Storm Elementals (127).
____________
Not idly do the leaves of Lorien fall.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted November 08, 2014 08:09 PM

No idea what's about. Universal creatures upgrade enables upgrades for creatures if the corresponding dwelling is build: ie in Rampart you can upgrade angels to AA if gold dragons nest is build.

What is "third upgrade"? Never heard such term in erm manual.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
bloodsucker
bloodsucker


Legendary Hero
posted November 08, 2014 09:11 PM
Edited by bloodsucker at 21:34, 08 Nov 2014.

Hero_Of_Light said:
I was wondering if it is possible to have a third upgrade for a creature without the use of the WoG option "Universal Creature Upgrades".




I'm not sure if I followed your idea but I coded this and it works

!!MA:U36/37;
!!MA:U37/136;    Master Genies upgrade to Enchanters

**** are neutral ...
!!MA:O36/-1;
!!MA:O37/-1;
***** are a level 5 monster
!!MA:L36/4;
!!MA:L37/4;
***************

*** Vampire Lords upgrade to Dread Knights
!!MA:U63/67;

*** Diamond Golems upgrade to Enchanthers
!!MA:U117/136;

I use the Universal Upgrades Option but I think this works without it, in fact the Universal Creature Upgrades seems to work like this.

Artu said:
Oh, Holy ERM father, who dares to speak against thy might!

You took me wrong, I don't speak against - I say the guy codes like he has "opened the doors of perception". The code is almost flawless but seems not to make any sense and the more you look the more confused you get. It remembers me of the "One Thousand and One Nights", one story is told inside another that is told inside another and then suddenly a break and it returns to the first to then continue with the third that opens for a fourth.
He is an ERM god, but is more incompreensible that the one in the bible.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted November 08, 2014 09:36 PM

I know you didn't speak against, was joking, but when erm codes I can not place any smile icon, so you have to deal with my apparent anger!
____________
Era II mods and utilities

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Hero_Of_Light
Hero_Of_Light


Responsible
Supreme Hero
posted November 08, 2014 09:38 PM

When I talk about third upgrades I am referring to my mod.

Just like the "extended upgrades" WoG option. There are some creatures that I want to give a third upgrade.

For instance:

Goblins upgrade to Hobgoblins normally. I want Hobgoblins to be upgraded to Wolf Riders. So I use this command.

!!MA:U85/87;

However, it won't work unless the "Universal Upgrades" WoG option is enabled. This upgrade is only available at Hill Forts. I would like to make it available in Stronghold towns as well.
____________
Not idly do the leaves of Lorien fall.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted November 08, 2014 10:01 PM

From what i know there is no way to do such thing. The manual says such upgrades will work only at hill fort.
____________
Era II mods and utilities

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Hero_Of_Light
Hero_Of_Light


Responsible
Supreme Hero
posted November 08, 2014 10:10 PM

It is possible. When universal creatures upgrades option is enabled, third upgrades are made possible. The thing is that when I look at the script I can't figure out how it does it. Here is the script.

********************************************************************************
  Universal Creature Upgrades
********************************************************************************

Variables Used: v3300-v3302, v3310-v3312
Functions Used: FU3300-FU3303

------------------------------------------------------------------------------------------------------------------

!#VRv3300:S-1; [Initialize v3300 to -1]

------------------------------------------------------------------------------------------------------------------

!?CM1;
!!UN:P174/?v1; [Check if Universal Upgrading is enabled: v1=1 if Yes]
!!FU3300&v1=1:P;

[Set/Reset town types for creature upgrading]
!?FU3300;
!!CA-1:T?y1; [Town type: y1]
!!CM:I?y2; [Position clicked: y2]

[Check creature types]
!!CA-1:P?y3/?y4/?y5; [Town's position: y3/y4/y5]

!!POy3/y4/y5:O?y6; [PO:O: y6]

!!FU3302&y6>0/y6<8:Py1; [Restore creatures unless nothing is stored yet]

[Set creature to be upgraded (if upgraded creature dwelling is built)]
!!FU3301&y2>=115/y2<=121:Py1/y2; [Garrison slots]
!!FU3301&y2>=140/y2<=146:Py1/y2; [Visiting hero slots]

------------------------------------------------------------------------------------------------------------------

[Determine which creature is clicked]
[x1=town type, x2=position clicked]
!?FU3301;
!!VRy1:S-1;  !!VRy2:S-1;

!!VRy1&x2>=115/x2<=121:Sx2 -115; [Garrison creature slot number: y1]
!!VRy2&x2>=140/x2<=146:Sx2 -140; [Visiting hero creature slot number: y2]

[Determine creature type: y5]
!!CA-1:H0/?y3 H1/?y4; [Garrison hero: y3, Visiting hero: y4]
!!HEy3&y3>=0/y1>=0:C0/y1/?y5/d; [Garrison hero creature: y5]
!!CA-1&y3<0/y1>=0:M2/y1/?y5/d; [Garrison creature: y5]
!!HEy4&y4>=0/y2>=0:C0/y2/?y5/d; [Visiting hero creature: y5]

!!FU&y5<0:E; [Exit if not a creature]

!!MA:Uy5/?y7; [Check for a custom upgrade: y7]

[Default upgrade for all towns except Conflux]
!!VRy6&y7=-1/y5<=111:Sy5 %2; [Remainder of creature number divided by 2: y6]
!!VRy7&y7=-1/y5<=111/y6=0:Sy5 +1; [If non-upgraded, upgrade is y7]

[Default upgrade for Conflux]
!!VRy7&y7=-1/y5=112:S127; [Air Elemental]
!!VRy7&y7=-1/y5=113:S125; [Earth Elemental]
!!VRy7&y7=-1/y5=114:S129; [Fire Elemental]
!!VRy7&y7=-1/y5=115:S123; [Water Elemental]
!!VRy7&y7=-1/y5=118:S119; [Pixie]
!!VRy7&y7=-1/y5=120:S121; [Psychic Elemental]
!!VRy7&y7=-1/y5=130:S131; [Firebird]

!!VRy6:S1; [Initialize y6 to 1]
!!VRy6&y7>=0:S0; [Set y6 to 0 if y7>=0]

!!FU|y6=1/y7=-2:E; [Exit if no upgrade]

!!MA:Ly5/?v3302; [Store creature's level in v3302]

!!VRy8:S37 +v3302; [Upgraded dwelling of this creature's level: y8]
!!CA-1:B3/y8; [Check if town has this upgraded dwelling built: Flag 1 True if yes]
!!CA-1&-1:B3/19; [Check if horde building 1 is built: Flag 1 is true if yes]
!!CA-1&-1:B3/25; [Check if horde building 2 is built: Flag 1 is true if yes]

!!FU&-1:E; [Exit if upgraded dwelling isn't built]

!!VRv3300:Sy5; [Store creature number: v3300]
!!MA:Oy5/?v3301;  [Store creature's town type in v3301]
!!MA:Oy5/x1; [Change creature to this town type]

!!VRv3310:Sy7; [Store upgraded creature number: v3310]
!!MA:Oy7/?v3311;  [Store upgraded creature's town type in v3311]
!!MA:Ly7/?v3312; [Store upgraded creature's level in v3312]
!!MA:Oy7/x1; [Change upgraded creature to this town type]

[Check & Store creature type and level]
!!CA-1:P?y13/?y14/?y15; [Town's position: y13/y14/y15]
!!POy13/y14/y15:B0/?y16 B1/?y17 O?y18; [PO:B0: y16  PO:B1: y17  PO:O: y18]
!!VRy9:Sy18 -1; [Subtract 1 from y18 to get real creature level: y9]
!!UN&v3302<>y9:Tx1/v3302/0/?y18; [If this level not stored, get non-upgraded type: y18]
!!UN&v3302<>y9:Tx1/v3302/1/?y19; [If this level not stored, get upgraded type: y19]
!!VRy10&v3302<>y9:Sy18 +1; [Non-upgraded type +1: y10]
!!VRy11&v3302<>y9:Sy19 +1; [Upgraded type +1: y11]
!!VRy12&v3302<>y9:Sv3302 +1; [Creature level +1: y12]
!!POy13/y14/y15&v3302<>y9:B0/y10; [If this level not stored, store non-upgraded type (+1)]
!!POy13/y14/y15&v3302<>y9:B1/y11; [If this level not stored, store upgraded type (+1)]
!!POy13/y14/y15&v3302<>y9:Oy12; [If this level not stored, store creature level (+1)]

[Set this town's creature of this level]
!!UN:Tx1/v3302/0/y5; [Set non-upgraded creature]
!!UN:Tx1/v3302/1/y7; [Set upgraded creature]

------------------------------------------------------------------------------------------------------------------

[Reset changed town creature types]
!?FU3302;
!!CA-1:P?y1/?y2/?y3; [Town's position: y1/y2/y3]

[Creature type: y4 (non-upgraded) and y5 (upgraded), y6 (level)]
!!POy1/y2/y3:B0/?y4 B1/?y5 O?y6; [PO:B0: y4  PO:B1: y5  PO:O: y6]
!!VRy4&y4>0:-1; [Subtract 1 from y4 to get non-upgraded creature number]
!!VRy5&y5>0:-1; [Subtract 1 from y5 to get upgraded creature number]
!!VRy6&y6>0:-1; [Subtract 1 from y6 to get creature level]

!!UN&y4>=0:Tx1/y6/0/y4; [Reset non-upgraded]
!!UN&y5>=0:Tx1/y6/1/y5; [Reset upgraded]

!!FU&v3300<0:E; [Exit function if no creature changed]

[Restore creature: v3300]
!!MA:Ov3300/v3301;  [Restore creature's town type]

[Restore upgraded creature: v3310]
!!MA:Ov3310/v3311;  [Restore upgraded creature's town type]

[Reset v3300 to -1]
!!VRv3300:S-1;

------------------------------------------------------------------------------------------------------------------

[Post-visit Town Trigger for the AI]
!$OB98&-1000;

!!UN:P174/?v1; [Check if Universal Upgrading is enabled: v1=1 if Yes]
!!FU&v1<>1:E; [Exit if not enabled]

!!HE-1:N?v1; [Hero number: v1]
!!CA998:T?v2; [Town type: v2]

[Check each creature in AI hero's army]
!!DO3303/0/6/1:Pv1/v2;

------------------------------------------------------------------------------------------------------------------

[Check each creature in AI hero's army]
[x1=hero number, x2=town type]
!?FU3303;

!!HEx1:C0/x16/?y1/?y7; [Type of creature: y1, Number: y7]

!!FU|y1<0/y7=0:E; [Exit if creature slot is empty]

!!MA:Oy1/?y2; [Town creature belongs to: y2]
!!MA:Uy1/?y3; [Creature's upgrade number: y3]
!!MA:Ly1/?y4; [Creature's level: y4]
!!VRy6:Sy4 +37; [Upgraded dwelling number in town: y6]
!!CA998:B3/y6; [Check if upgraded dwelling is built: Flag 1 is true if yes]
!!CA998&-1:B3/19; [Check if horde building 1 is built: Flag 1 is true if yes]
!!CA998&-1:B3/25; [Check if horde building 2 is built: Flag 1 is true if yes]

[Exit if native town, creature has no upgrade or upgraded dwelling isn't built]
!!FU|y2=x2/y3=-2/-1:E;

[Default upgrade for all towns except Conflux: y3]
!!VRy5&y3=-1/y1<=111:Sy1 %2; [Remainder of creature number divided by 2: y5]
!!VRy3&y3=-1/y1<=111/y5=0:Sy1 +1; [If non-upgraded, upgrade is y3]

[Default upgrade for Conflux: y3]
!!VRy3&y3=-1/y1=112:S127; [Air Elemental]
!!VRy3&y3=-1/y1=113:S125; [Earth Elemental]
!!VRy3&y3=-1/y1=114:S129; [Fire Elemental]
!!VRy3&y3=-1/y1=115:S123; [Water Elemental]
!!VRy3&y3=-1/y1=118:S119; [Pixie]
!!VRy3&y3=-1/y1=120:S121; [Psychic Elemental]
!!VRy3&y3=-1/y1=130:S131; [Firebird]

!!VRy5:S1; [Initialize y5 to 1]
!!VRy5&y3>=0:S0; [Set y5 to 0 if y3>=0]

!!FU|y5=1:E; [Exit if no upgrade]

!!HEx1:C0/x16/y3/d; [Upgrade creature]

------------------------------------------------------------------------------------------------------------------

[End of Universal Creature Upgrades]

____________
Not idly do the leaves of Lorien fall.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
bloodsucker
bloodsucker


Legendary Hero
posted November 08, 2014 10:11 PM
Edited by bloodsucker at 22:13, 08 Nov 2014.

Hero_Of_Light said:
This upgrade is only available at Hill Forts. I would like to make it available in Stronghold towns as well.


That is said in the help it wont work, but you may try to work around it with the !!HE:D - Call upgrade dialog for hero's army (no parameters).
I was thinking of use it to create Onomaeus hability - Train any level 10 peasant to any type of gladiator; if I decided to retake the development of my Spartacus mod but I didn't tested it yet.
But it looks like what you need. First you have to code the upgrade somewhere, then you create a routine to open the "Hill Fort" on your heroes or in one of your heroes.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted November 08, 2014 10:40 PM

HoL,

Your example does not show how would be possible. Universal upgrades will perform upgrades on creatures which can normally be upgraded in some specific town, but now it works in all towns.

ex: pikeman will be upgraded to halberd when in other town. But halberd can't be upgraded to anything, no matter the town. But can be upgraded to anything, if at hill fort.

Show me universal upgrades script upgrading an already upgraded creature.
____________
Era II mods and utilities

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Hero_Of_Light
Hero_Of_Light


Responsible
Supreme Hero
posted November 08, 2014 10:51 PM

OK...

This command:

!!MA:U85/87;

If put it on script AND universal upgrades WoG option is ON it will give hobgoblins a third upgrade in every town that has upg level 1 dwelling built. Tested and working. I've been using this on nearly all of my mods.

What I want is to have this command work on Stronghold only.

To elaborate some more:

Goblins normally upgrade to Hobgoblins. If this command is added to a script then Hobgoblins would have a third upgrade, the Wolf riders.

Now, this upgrade won't work in town. It works only on Hill Forts.

With Universal upgrades on, ALL upgrades are available in all of the towns. And so, this third upgrade is available as well.

The thing is that I don't want for this upgrade to be available in all of the towns. I want it to be available only on Stronghold.
____________
Not idly do the leaves of Lorien fall.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted November 08, 2014 11:00 PM

You don't need universal upgrades for such thing.

!?CM1;
!!CA-1:T?y2;
!!FU&y2<>6:E; exit if not stronghold
!!MA:U85/87; set hobs to upgrade to raiders

!$OB98&1000;
!!MA:U85/-2; prohibit hobs upgrade when leaving town

Thats all.
____________
Era II mods and utilities

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Hero_Of_Light
Hero_Of_Light


Responsible
Supreme Hero
posted November 08, 2014 11:21 PM

It doesn't work.

Again I don't think you realize what I am saying. I will try to explain again.

Let's say that you have a Stronghold that has all the buildings built.

Now, when you click on a Goblin army in the town there is an upgrade button. It upgrades them to Hobgoblins.

When you click on the Hobgoblins normally there is no upgrade button. Hobgoblins are the last upgrade.

Now this command:

!!MA:U85/87; set hobs to upgrade to raiders

Will enable a THIRD upgrade for the Goblins. However, this THIRD upgrade will be available only at Hill Forts.

Now, what does the Universal Creatures upgrade do.

It checks whether you clicked on a creature and whether the appropriate level building is built on a town. If that is so, then the creature can be upgraded in every town.

This script has another benefit as well. It allows CUSTOM UPGRADES to appear in towns.

So when I added this command on my script:

!!MA:U85/87;

If the Universal Creatures Upgrades is OFF then nothing happens (except on Hill Forts).

IF the Universal Creatures Upgrades is ON then this THIRD upgrade is available in towns also.

The problem is that I don't like that. I don't want to have this WoG Option ON as a default. I want to have these THIRD upgrades in the appropriate towns without this WoG option.

I know the solution to my problem is somewhere in this script. I just can't find it.
____________
Not idly do the leaves of Lorien fall.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted November 08, 2014 11:31 PM

Ok, then use my script with universal upgrades ON. Then hobs will be upgradable to raiders only in strongholds.
____________
Era II mods and utilities

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Hero_Of_Light
Hero_Of_Light


Responsible
Supreme Hero
posted November 08, 2014 11:38 PM

That's no good either. What good will do me if Hobgoblins are upgraded into Wolf Riders only in Stronghold when ALL other creatures upgrade in every town?

What I want to do is to make my mod independent from the Universal Creatures Upgrades. To be blunt, I DON'T like Universal Creatures Upgrades. I think it can easily work as cheat in the game and I don't like that.

I want to have my third upgrades without this script. I just thought that the script was close to enabling third upgrades in towns that's why I posted it, to serve as a basis to a new script that only enables custom third upgrades (and nothing else).
____________
Not idly do the leaves of Lorien fall.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted November 08, 2014 11:44 PM

Ok I understand. I don't know at all how universal upgrades works (never used it), I will take a look.
____________
Era II mods and utilities

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Jump To: « Prev Thread . . . Next Thread » This Popular Thread is 407 pages long: 1 50 100 150 200 ... 243 244 245 246 247 ... 250 300 350 400 407 · «PREV / NEXT»
Post New Poll    Post New Topic    Post New Reply

Page compiled in 0.5930 seconds