|
|
bloodsucker
Legendary Hero
|
posted February 18, 2015 08:56 AM |
|
|
Salamandre said:
Well, it doesn't work.
For what I can understand my first mistake is to think timers can start at day 28 but I don't see nothing saying the opposite in the help.
-----------
Gonna use this to put some of my "philosophical" doubts...
1. If I want an object to appear on random maps but I want to have only one for map does it makes sense count all objects of one type on the map, randomize the number and then substitute just the one with that number? Was this ever done before?
2. Is the Forgotten Shrine really forgotten? I was thinking of making a level 4 shrine teaching Clone to human players and Town Portal to AI. This way even without playing with Conquistador and disabling Town Portal, AI could still learn it. But I was thinking of use the object called Forgotten Shrine for this.
3. By some reason, this works:
ZVSE
!#TM2:S1/999/1/255;
!?TM2;
!!UN:U17/-1/?y-1; find creature dwellings
!!VRv1:S-1;
!!DO12345/1/y-1/1&y-1>0:P17/74; [change function number to something not already used]
!?FU12345;
;x1 creature dwelling
;x2 hovel subtype
!!UN:Ux1/-1/-1/1; dwelling in v1-v3
!!OB1:U?y1;
!!FU&y1<>x2:E;
!!UN:Ov1/v2/v3;
!!UN:Iv1/v2/v3/20/1;
this works
!!UN:U39/-1/?y-1;
!!VRv1:S-1;
!!DO45327/1/y-1/1&y-1>0:P39;
!?FU45327;
;x1 lean to
!!UN:Ux1/-1/-1/1;
!!OB1:U?y1;
!!FU&y1<>x2:E;
!!UN:Ov1/v2/v3;
!!UN:Iv1/v2/v3/17/62; azure dragons
and this works
!!UN:U16/-1/?y-1;
!!VRv1:S-1;
!!DO45328/1/y-1/1&y-1>0:P16/06;
!?FU45328;
;x1 hive
!!UN:Ux1/-1/-1/1;
!!OB1:U?y1;
!!FU&y1<>x2:E;
!!UN:Ov1/v2/v3;
!!UN:Iv1/v2/v3/17/94; war zealots
but this doesn't
!!UN:U78/-1/?y-1;
!!VRv1:S-1;
!!DO45329/1/y-1/1&y-1>0:P78;
!?FU45329;
;x1 refugee camp
!!UN:Ux1/-1/-1/1;
!!OB1:U?y1;
!!FU&y1<>x2:E;
!!UN:Ov1/v2/v3;
!!UN:Iv1/v2/v3/16/02; conservatories
may I replace them using one by one using their coordinates?
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted February 18, 2015 09:13 AM |
|
|
bloodsucker said:
but this doesn't
!!UN:U78/-1/?y-1;
!!VRv1:S-1;
!!DO45329/1/y-1/1&y-1>0:P78;
!?FU45329;
;x1 refugee camp
!!UN:Ux1/-1/-1/1;
!!OB1:U?y1;
!!FU&y1<>x2:E;
!!UN:Ov1/v2/v3;
!!UN:Iv1/v2/v3/16/02; conservatories
may I replace them using one by one using their coordinates?
Meh, you copy things when it would be so easy just to look in the manual and understand why this or that. So when you copy the recipe on how to make eggs but apply it to burritos, obviously will screw.
Quote: !!FU&y1<>x2:E;
you see, in my example I asked for x2 because x2 was object subtype. You don't have any x2 in your script, x2 is defined here:
!!DO45329/1/y-1/1&y-1>0:P78; --> 78 is x1, if one more value; it will be x2.
Then conservatories are not 16/02 but 16/2. When in doubt, open map and check.
____________
Era II mods and utilities
|
|
bloodsucker
Legendary Hero
|
posted February 18, 2015 09:25 AM |
|
|
Ok, reprehension accepted but the fact is 02 is what is in help for conservatories and works, I used it for imp caches too. And Lean to are just one object without subtypes and it worked.
P.S. How can I check the numbers of the WoG Options? I know how to set them and I've been using a document I found in the Internet http://www.jksit.se/homm3/tools/wogsettings.txt to find them but there are some missing.
|
|
bloodsucker
Legendary Hero
|
posted February 19, 2015 02:24 PM |
|
|
I made this script for an object with a battle for a reward. While I have already tested it I have a doubt. I saved the Supreme Archangel stats in permanent values cause it was like that in a script I used for example but I think they could be perfectly stored in temporary variables cause they will be restored even if hero loses the battle.
ZVSE
!?OB63/75&1000;
!#VRz699:S0^Guardian Angel^;
!#HT63/75&1000:T699;
!#VRv7120:S0;
!#VRv7121:S0;
!#VRv7122:S0;
!#VRv7123:S0;
!#VRv7124:S0;
!#VRv7125:S0;
!#VRv7126:S0;
!#VRv7127:S0;
!!IF&v7127=1:M^You already had your chance^;
!!FU&v7127=1:E;
!!IF:M^If you and ONE SINGLE creature of your choice prove your value before me, I will grant her my protection.^;
!!IF:M^Your creature MUST SURVIVE the battle^;
!!IF:Q1^Do you accept my challenge?^;
!!FU&-1:E;
!!VRv7120:S0;
!!DO66154/0/6/1:P; count creatures and store creature type
!!IF&v7120>1:M^You can't bring more then one creature^;
!!FU&v7120>1:E;
!!IF&v7120<1:M^You have to bring one creature to be enchanted^;
!!FU&v7120<1:E;
!!MA:P150/?v7121 A150/?v7122 D150/?v7123 E150/?v7124 M150/?v7125; store SAs actual stats
!!MA:P150/7500 A150/250 D150/250 E150/750 M150/750; create avatar
!!HE-1:Tv998/v999/v1000/150/1; provoke
!!MA:P150/v7121 A150/v7122 D150/v7123 E150/v7124 M150/v7125; restore SAs actual stats
!!VRv7127:S1; set visited
!!HE-1:O?y5; check if hero is alive
!!FU&y5<0:E;
!!VRv7120:S0;
!!DO66154/0/6/1:P; check if creature is alive
!!IF&v7120<1:M^You have lost your creature, I can't enchant what doesn't exist.^;
!!FU&v7120<1:E;
!!FU66155:P;
!?FU66154;
!!HE-1:C0/x16/?y1/?y2;
!!VRv7120&y2<>-1:+y2;
!!VRv7126&y1<>-1:Sy1;
!?FU66155;
!!EAv7126:B13/0/////////////;
!!EAv7126:B13/1/85/150/0/15/20/25/30/35/40/50/60/70/80; Summom SAs
P.S. Does anyone knows if AI resources can became negative like it happens to human players?
|
|
bloodsucker
Legendary Hero
|
posted March 06, 2015 04:14 PM |
|
|
What do I have to do to change a special building from a town (namely trade stables by magic university)? Is there a feasible way to change the skills offered by the Magic University? I would like to have a Might Univertsity (Offense, Armourer, Archery, Tactics) in Castle.
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted March 06, 2015 04:54 PM |
|
|
Click on stables-->!!IF:G0 or custom dialog (!!DL)-->disable regular message.
|
|
bloodsucker
Legendary Hero
|
posted March 06, 2015 05:23 PM |
|
|
Salamandre said: Click on stables-->!!IF:G0 or custom dialog (!!DL)-->disable regular message.
Yeah! Thanks.
P.S.
How can I change the names of the buildings in a town?
UN:N2 looks like a read only instruction, do I use a combination of UN:N5 and UN:N6?
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted March 06, 2015 10:02 PM |
|
|
H3bitmmap.lod/Bldgspec.txt
|
|
bloodsucker
Legendary Hero
|
posted March 06, 2015 10:39 PM |
|
|
Thanks but how do I open it? I tought it was with the MMArchive but it does not let me edit it, just read. Also, what is the name of the file for creature dwellings?
Is it suposed I change these files? In that case, how can I do it and (specially) undo it in other people's instalations. Even if I manage to do it, isn't this too risky? I don't want to screw the files of everybody who plays the map.
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted March 07, 2015 07:23 AM |
|
|
You open H3bitmap.lod with MM archive. Then you extract Bldgspec.txt (right-click/extract to desktop). You open it with text edit and change the name of what you want.
Then file goes in My mod name/data/mymod.pac. That's all and try it before asking other questions, please. Knowledge comes with trials, don't wait for definitive answers before starting work.
|
|
bloodsucker
Legendary Hero
|
posted March 07, 2015 01:53 PM |
|
|
Thank you, your tip has helped me a lot.
I want to create an object that allows you to learn or advance up to twelve secondary skills.
1. I want it to be revisitable by the same hero BUT not allowing him to advance a skill twice. Are there any W vars besides the ones in the Help List of Claimed that are currently used by other standart scripts and I must leave alone?
2. The skills I'm thinking are not so much Wisdom, Earth and Offense but mostly the ones that are inaccessible to some classes, so Fire, Water, Leadership, Necromancy, First Aid, Estates, Resistance and Navigation came to my mind. Are there other secondary skills some heroes can't learn without help and I'm not aware of?
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted March 07, 2015 05:36 PM |
|
|
Don't use w vars, they are mainly for stand alone mods. Use SN:W vars.
Example:
!?OB#&1000; when visit object #
!!HE-1:N?y1; get hero ID
!!SN:W^Hero_%Y1_skill_0^/?y2; check if this hero advanced in pathfinding (ID=0) already
!!if&y2<99:; if not
!!HEy1:S0/?y3; check pathfinding level
!!VRy3&y3<3:+1; increment by one if not expert
!!HEy1:S0/y3; advance one level in pathfinding
!!SN:W^Hero_%Y1_skill_0^/99; block for this skill if visit again
!!en:;
|
|
bloodsucker
Legendary Hero
|
posted March 07, 2015 07:32 PM |
|
|
Thanks, but are you going to force me to put 18 heroes in front of a university and cicle 26 skills to see if they can learn them?
Cause until now is the only idea I have to discover this and it will take more time then to create the object.
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted March 07, 2015 07:47 PM |
|
|
Nope, if the current hero already learned that skill, the skill will not appear in the list anymore. I will write a short example a bit later, so you can start from.
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted March 07, 2015 08:42 PM |
|
|
ZVSE
; university proposes advancing in magic schools, once for every hero/per skill
!?OB104&1000; university
!!OB998:S; disable object
!!HE-1:N?y1; check hero ID
!!SN:W^Hero_%Y1_skill_14^/?y2; check if hero already advanced here in fire
!!SN:W^Hero_%Y1_skill_15^/?y3; air
!!SN:W^Hero_%Y1_skill_16^/?y4; water
!!SN:W^Hero_%Y1_skill_17^/?y5; earth
!!VRz1:S^Welcome to Bloodsucker's University. Make your pick!^;
!!HEy1:S14/?y7;
!!HEy1:S15/?y8;
!!HEy1:S16/?y9;
!!HEy1:S17/?y10;
!!VRz2:S^^;
!!VRz2&y2<99/y7<3:S^Fire magic^; v2=1
!!VRz3:S^^;
!!VRz3&y3<99/y8<3:S^Air magic^; v2=2
!!VRz4:S^^;
!!VRz4&y4<99/y9<3:S^Water magic^; v2=4
!!VRz5:S^^;
!!VRz5&y5<99/y10<3:S^Earth magic^; v2=8
!!VRz6:S^Exit^; v2=16
!!IF:G1/2/16/1/2/3/4/5/6; store result in v2
!!CM:R0;
!!FU&v2=16:E; exit
;initializ magic schools ID (14-17)
!!VRy11&v2=1:S14;
!!VRy11&v2=2:S15;
!!VRy11&v2=4:S16;
!!VRy11&v2=8:S17;
!!HEy1:Sy11/?y12; get expertise of skill picked
!!VRy12:+1; increment by 1
!!HEy1:Sy11/y12;
!!VRy13:Sy11*3+y12+2; find pic for dialog
!!IF:Q1/20/y13/1^Your hero gets:^;
!!SN:W^Hero_%Y1_skill_%Y11^/99; set that skill to 99 so can't be asked again
!!CM:R0; disable any other messages
Et voila. No global vars used, no w vars, only SN W unlimited vars, so mod will be compatible with everything.
|
|
bloodsucker
Legendary Hero
|
posted March 08, 2015 03:49 AM |
|
|
Thanks, it will be usefull.
P.S. I never saw this done but is it possible to reassign the class of heroes that belong to a specific town? Say barbarians are now the might hero from Castle and Knights from Strongold... Would it work if might was set to magic (alchemists instead of priests for instance)?
P.P.S. Does any one knows what is the table for new specialties text? I made one hero give mithril but I believe I have to customize the text and the picture. The picture I already found but I don't see the texts anywhere.
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted March 08, 2015 09:16 PM |
|
|
|
bloodsucker
Legendary Hero
|
posted March 09, 2015 08:11 PM |
|
|
This may sound like extreme ignorance from my part but are the EA habilities that traditionally came with creatures, like Azures summon water elements, hard-coded? I was unable to find them in the scripts I looked for and War Zealots immunity to dispel works but mine or Palace of the Dreams doesn't, I also didn't found any reference to Receptivity in Help and some creatures have it.
P.S. Found Recetive in the txt file "stack experience bonuses" in the Help folder but it lacks in the Help Page, it is 119 (spell immunity)/48 (receptive) while the table starts at 49.
P.P.S. When you hire an hero and it appears on the door of the town, is there an editable event? I looked but was unable to find it.
|
|
bloodsucker
Legendary Hero
|
posted March 10, 2015 07:20 PM |
|
|
1. I need the pictures for the secondary skills to make a DL. I look for them in all the files in data that opened with MMArchive but I didn't found them (well, except for logistics that was there in H3ab_bmp but is not one of those I need), am I looking in the wrong place?
2. zsetup00 and zsetup01 hold the numbers of the options to Wogify maps, yet I can't find the Custom Scripts options there. Where are they?
|
|
majaczek
Supreme Hero
Work at Magic Dimmension
|
posted March 10, 2015 08:32 PM |
|
|
1) UN44.def and UN32.DEF
2) ERS files
|
|
|