|
| Thread: [Wake of Gods] - Introduction/Modding/Scripting |  This thread is pages long: 1 ... 7 8 9 10 11 ... 20 30 33 · «PREV / NEXT» |
|
sprawler
Hired Hero
|
posted July 21, 2010 03:50 PM |
|
|
unit pictures
Is there any tutorial how to make unit town/hero inventory pictures, i have found the file with this pictures but when i change the picture there is still the old one in the game.
1)why there is the orginal picture of the unit after the change and not my own picture ???
2)if i change the picture in castle units , do my unit have to have the same back ground as orginal ones ??? if yes , where i can find the clean background file ???
|
|
Kreegan
Known Hero
Winged Anquietas
|
|
posted August 03, 2010 03:45 PM |
|
|
That's becouse you need to replace it in def responsible for those pictures... TWN*****.def ;P
____________
nick: Irhak
|
|
sprawler
Hired Hero
|
|
posted August 04, 2010 11:46 AM |
|
|
sorry for my english but when said i changed the picture i meant thath i replaced it a still i have the old one  i must doing something wrong.
1)first i extracted the def file
2)changed the picture
3)make a def file using the def maker
4)putted the def in the right file
and nothing ,by the way is there any tutorial how to change town image buildings ??? because when i do some changes, the game crashes when i enter the castle
|
|
ShinRA
Tavern Dweller
|
|
posted August 05, 2010 09:13 PM |
|
|
Hi. I have some questions about adding expert 2nd skills when the hero equip a certain artifact.
I want to make Bow of Sharpshooter to grants the hero Expert Archery whenever I equip it, this is the code I have so far:
zvse
!#VRz10:S^{Bow of the Sharpshooter}
When equipped, the Bow of the Sharpshooter allows your troops to shoot at close-range, and grants you the Expert {Archery} skill.^; Set this text to "z10"
!#HT5/137:T10; Show "z10", when hero right-clicks the artifact
!?AE1&v998=137; Equip Artifact 137
!!HE-1:S1/?v1; Check if hero has Archery, if yes, variable v1 will be set to 1
!!HE-1:S1/3; Give Expert Archery
!?AE0&v998=137; Unequip Artifact 137
!!HE-1:S1/v1; Remove Archery, if variable v1 is 1
!?CM2;
!!UN:R3/-1; Redraw Hero Screen
The code works as intended, but when I unequip the bow, the Expert Archery icon on my Hero 2nd skill screen is replaced with Expert Diplomacy icon, and the text is below it says about "Restart Scenario". How is that possible?
I also want to make Endless Sack of Gold to grant the hero Expert Estates skill whenever I equip it, with this code:
zvse
!#VRz990:S^{Endless Sack of Gold}
When wielded, the Endless Sack of Gold gives your Empire 1000 gold each day, and grants you the Expert {Estates} skill.^; Set this text to "z990"
!#HT5/115:T990; Show "z990", when hero right-clicks the artifact
!?AE1&v997=115; Equip Artifact 115
!!HE-1:S13/?v1; Check if hero has Estates, if yes, variable v1 will be set to 1
!!HE-1:S13/3; Give Expert Estates
!?AE0&v997=115; Unequip Artifact 115
!!HE-1:S13/v1; Remove Estates, if variable v1 is 1
!?CM2;
!!UN:R3/-1; Redraw Hero Screen
this code doesn't work as intended. the expert estates icon doesn't show up on hero 2nd skill screen. Any advice?
Thanks for attention
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
|
posted August 05, 2010 09:46 PM |
|
|
Use a high variable to store for long term, v1 will not work. Change v998 to v997 everywhere.
____________
Era II mods and utilities
|
|
ShinRA
Tavern Dweller
|
|
posted August 05, 2010 10:30 PM |
|
Edited by ShinRA at 22:39, 05 Aug 2010.
|
I changed the code to:
zvse
!#VRz10:S^{Bow of the Sharpshooter}
When equipped, the Bow of the Sharpshooter allows your troops to shoot at close-range, and grants you the Expert {Archery} skill.^; Set this text to "z10"
!#HT5/137:T10; Show "z10", when hero right-clicks the artifact
!?AE1&v997=137; Equip Artifact 137
!!HE-1:S1/?v998; Check if hero has Archery, if yes, variable v998 will be set to 1
!!HE-1:S1/3; Give Expert Archery
!?AE0&v997=137; Unequip Artifact 137
!!HE-1:S1/v998; Remove Archery, if variable v998 is 1
!?CM2;
!!UN:R3/-1; Redraw Hero Screen
This code doesn't even work. Expert Archery icon doesn't even show up when I equip bow of sharpshooter. And what do you mean using high variable for long-term storage?
|
|
ShinRA
Tavern Dweller
|
|
posted August 05, 2010 11:06 PM |
|
|
Swapping the variables does the job. The whole code:
zvse
!#VRz10:S^{Bow of the Sharpshooter}
When equipped, the Bow of the Sharpshooter allows your troops to shoot at close-range, and grants you the Expert {Archery} skill.^; Set this text to "z10"
!#HT5/137:T10; Show "z10", when hero right-clicks the artifact
!?AE1&v998=137; Equip Artifact 137
!!HE-1:S1/?v997; Check if hero has Archery, if yes, variable v997 will be set to 1
!!HE-1:S1/3; Give Expert Archery
!?AE0&v998=137; Unequip Artifact 137
!!HE-1:S1/v997; Remove Archery, if variable v997 is 1
!?CM2;
!!UN:R3/-1; Redraw Hero Screen
!#VRz990:S^{Endless Sack of Gold}
The Endless Sack of Gold gives your Empire 1000 gold each day, and grants you the Expert {Estates} skill.^; Set this text to "z990"
!#HT5/115:T990; Show "z990", when hero right-clicks the artifact
!?AE1&v996=115; Equip Artifact 115
!!HE-1:S13/?v995; Check if hero has Estates, if yes, variable v995 will be set to 1
!!HE-1:S13/3; Give Expert Estates
!?AE0&v996=115; Unequip Artifact 115
!!HE-1:S13/v995; Remove Estates, if variable v995 is 1
!?CM2;
!!UN:R3/-1; Redraw Hero Screen
Bow of the Sharpshooter code worked, but Endless Sack of Gold still doesn't work. Any advice?
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
|
posted August 05, 2010 11:07 PM |
|
|
Return a few pages and see the Gnollking's artefact how is done. Your script is a true mess, must learn basics first.
____________
Era II mods and utilities
|
|
ShinRA
Tavern Dweller
|
|
posted August 06, 2010 04:25 AM |
|
|
|
Oh, I think I got it now. Thanks for helping.
|
|
Hero_Of_Light
Responsible
Supreme Hero
|
|
posted August 29, 2010 12:24 PM |
|
|
Great thread (and very useful too)
I found a list of all the creature defs in Celestial Heavens, I think its a good addition so that you won't have to look in resedit all the time. Anyway here it is:
EDIT
OOPS!!!
It was already there on page 3. Sorry
Maybe If I'll find anything else useful I'll post it here instead.
|
|
gnollking
Supreme Hero
|
|
posted August 29, 2010 03:33 PM |
|
|
It's already on page 3 
This part:
Quote:
The most useful Defs, all of them are found on the H3sprite.lod, use ResEdit2 or MMArchive to open the lod
was written by me, so someone must have copied the list from here to CH.
____________
|
|
klwar
Tavern Dweller
|
|
posted October 17, 2010 05:45 PM |
|
|
i use TextEdit v3 to modify the file ZCRTRAIT.txt
But i can't change the stats of some monster (from earth messenger to dracolich). Only the monster's name can be changed.
Can any one help ?
|
|
pacifist
Famous Hero
|
|
posted October 22, 2010 12:03 PM |
|
|
I don't know if it's the right topic to ask this question so simply ignore if it's not the case.
Is there a way to modify the mass spells so we can select instead an advanced form of it. This is specially important for haste and dispel spells but can also be interesting for other spells as slow or even protection spells as they offer tactical possibilities that the expertise denies.
____________
http://www.youtube.com/user/alkoriak#g/u
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
|
posted October 22, 2010 12:45 PM |
|
|
Yes they can be scripted to choose from basic to expertise. Wasn't done because nobody thought there is an advantage from using a basic when you are expert. Till now. Dispel basic would be like a cheating, remove boost spells and keep force field?
____________
Era II mods and utilities
|
|
pacifist
Famous Hero
|
|
posted October 22, 2010 01:07 PM |
|
|
Well, that's a possibility and also prevents crash with dispel force field . If force field were air magic I could understand because the same level of expertise for exemple allows to have a full force field and the corresponding dispel but here force field is earth magic and an expert earth , basic air hero can do it while not an expert in both . A tower town defender also has to think twice before casting dispel or he will also destroy the only moat damage he has. Just seems illogic, the developpers didn't think of many things and this one doesn't seem unfair to me, just adds more tactical choices. In the end the player will always profit from AI weakness, but here I think more of player vs player.
____________
http://www.youtube.com/user/alkoriak#g/u
|
|
gnollking
Supreme Hero
|
|
posted November 08, 2010 03:54 PM |
|
|
I's just like to inform all you guys that I have returned to the world of Might and Magic. I'll try my best to update my threads, and most importantly, the Creatures Archive. I have already downloaded tens of new fantastic creatures and will most propably start adding them to the Archives tomorrow. I will not propably be very active in the forums but I'll try to visit this place as much as possible
@Edit, By the way, if anyone has my Artifact Script (the .erm file)
from page 6, can you please upload it for me to download it (the v.1.0)?
____________
|
|
Axe
Tavern Dweller
|
|
posted November 22, 2010 06:56 AM |
|
|
Some new script for wog 3.58f
Hi to all
I'm new on this forum, but i love and play H3 for many years.
I have discovered Wog, and i begin to modify and make some new script.
I want to post them, for some players who want to play/test them. I gather many script, but i'm not strong with ERM language, so excuse me if some error, but say me if error on script, i can ( perhaps ) repair it.
Sorry for my bad english.
I dont know if i'm on the good post, so sorry.
This is the first script the script93.erm who allow to buy some skill on different castle i dont upload it :
ZVSE
ERMS_ScriptName=script93
ERMS_ScriptAuthor=Axe
ERMS_ScriptVersion=1.0.0
ERMS_ScriptDate=22.11(November).2010
ERMS_ScriptERMVersion=2.70
ERMS_ScriptLanguage=Français (France) or English (native)
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2005.9.7.814
** OBJECT : Castle Brotherhood of Sword (town 0, obj 22) allow to learn Offence or Armorer at Basic level for 2000 gold
** OBJECT : Rampart Treasury (town 1, obj 22) give 500 gold/day and 2 Mithril /week 10% interest for 5000 gold
** OBJECT : Rampart Fountain of Fortune (town 1, obj 21) allow to learn Luck at Basic level for 2000 gold
** OBJECT : Tower Lookout Tower (town 2, obj 21) allow to learn Eagle eye or Sorcery at Basic level for 2000 gold
** OBJECT : Inferno Brimstone StormClouds (town 3, obj 21) allow to learn Fire Magic or Intelligence at Basic level for 2000 gold
** OBJECT : Necropolis Cover of Darkness (town 4, obj 17) allow to learn Necromancy at Basic level for 2000 gold
** OBJECT : Stronghold Ballista yard (town 6, obj 22) allow to learn Tactics or Archery at Basic level for 2000 gold
** OBJECT : Fortress Blood Oblelisk (town 7, obj 22) allow to learn Pathfinding or Scouting at Basic level for 2000 gold
** Variables Used: v314
** Functions: FU1007 Dwarven treasury
*******************************************
** Start Castle Brotherhood of Sword change **
*******************************************
** Castle Brotherhood of Sword mod 1.0 by Axe
** OBJECT : Castle Brotherhood of Sword (town 0, obj 22) allow to learn Offence or Armorer at Basic level for 2000 gold
** Updated: October 28, 2010
** Variables Used: v314
** Functions: None
** Main click routine **
!?CM1;
!!CA-1:T?y-7 H1/?y-3; [Get type of town and visitor hero]
!!FU&y-7<>0:E; [Exit if it's not Castle town]
!!CM:I?y-2 F?y-6; // get the clicked field
!!IF&y-6=0/y-2=22/1000:Q1/22/5/22/22/10^{Tavern} or {Brotherhood of Sword}
In which building do you want to enter ?
^;
!!FU&v1=0:E; [Exit if cancel button]
!!CM&v1=1/y-2=22:R1; [left choice Tavern]
!!CM&v1=2/y-2=22:R0; [right choice Brotherhood of Sword]//disable standard reaction
!!FU|v1=1/y-2<>22:E; // exit, if not clicked at Brotherhood of Sword
!!IF&y-6=512/1000:Q1/20/69/22/22/20/72/4^{Brotherhood of Sword}
The Brotherhood of Sword allows you to learn
{Basic Offence} or {Basic Armorer}
for 2000 Gold
^;
!!FU&y-6=512:E; [Exit if right click]
!!IF:V1/0; reset flag 1
!!OW:R-1/6/?y3; get owner's gold
!!IF&1000/y-6=0/y3<2000:Q1/20/69/20/72/1^{Brotherhood of Sword}
The Brotherhood of Sword allows you to learn
{Basic Offence} or {Basic Armorer}
for 2000 Gold
{NOT ENOUGHT GOLD}^;
!!FU&y3<2000:E; [Exit if not enought gold]
!!IF&1000/y-6=0/y-3<0:Q1/20/69/20/72/1^{Brotherhood of Sword}
The Brotherhood of Sword allows you to learn
{Basic Offence} or {Basic Armorer}
for 2000 Gold
{NO VISITOR HERO}^;
!!FU&y-3<0:E; [Exit if no visitor hero]
!!IF&1000/y-6=0/y3>1999:Q1/20/69/20/72/10^{Brotherhood of Sword}
The Brotherhood of Sword allows you to learn
{Basic Offence} or {Basic Armorer}
for 2000 Gold
^;
!!FU&v1=0:E; [Exit if cancel button]
!!VRv314&v1=1:S22; [left choice OFFENCE Brotherhood of Sword]
!!VRv314&v1=2:S23; [right choice ARMORER Brotherhood of Sword]
!!HEy-3:Sv314/?y2; get hero expertise with this skill
!!IF&y2>0/1000/v314=22:Q1/20/69/1^{Brotherhood of Sword}
Skill already owned^; msg if already owned OFFENCE
!!IF&y2>0/1000/v314=23:Q1/20/72/1^{Brotherhood of Sword}
Skill already owned^; msg if already owned ARMORER
!!FU&y2>0:E; [Exit if skill already owned]
!!IF&1000/v314=22:Q1/20/69/36/-102000/1^{Brotherhood of Sword}
Skill Learned^; msg if buy skill OFFENCE
!!IF&1000/v314=23:Q1/20/72/36/-102000/1^{Brotherhood of Sword}
Skill Learned^; msg if buy skill ARMORER
!!OW:R-1/6/d-2000; pay 2000 gold
!!HEy-3:Sv314/1; set skill to basic
!!IF:V1/0; reset flag 1
*****************************************
** End Castle Brotherhood of Sword change **
*****************************************
****************************************
** Start Rampart Town Treasury change **
****************************************
** Rampart Town Treasury mod 1.0 by Axe
** OBJECT : Rampart Treasury (town 1, obj 22) give 500 gold/day and 2 Mithril /week 10% interest for 5000 gold
** Updated: October 28, 2010
** Variables Used: v314
** Functions: FU1007 Dwarven treasury
** Main click routine **
!?CM1;
!!CA-1:T?y-7; [Get type of town]
!!FU&y-7<>1:E; [Exit if it's not rampart town]
!!CM:I?y-2 F?y-6; // get the clicked field
!!CM&y-2=22:R0; //disable standard reaction
!!FU&y-2<>22:E; // exit, if not right clicked at treasury
!!IF&y-6=512/1000:Q1/23/22/4^{Treasury}
The Treasury earns you
{10% interest} on any gold you have at the start of each week
{500} Gold per day
{2} Mithril per week^;
!!IF&y-6=0/1000:Q1/23/22/1^{Treasury}
The Treasury earns you
{10% interest} on any gold you have at the start of each week
{500} Gold per day
{2} Mithril per week^;
** Timer routine
!?TM2; // one times daily
!!VRy-4:S0;
!!VRy-5:S0;
!!VRy-7:S0;
!!VRy-8:S0;
!!VRy-9:S0;
!!UN:U98/-1/?y1;
!!IF&y1=0:E;
!!OW:C?y4;
!!VRv580:S-1; [reset coordinate index]
!!DO1007/1/y1/1&y1>0:Py4; [Loop from town owned by current player]
!!OW&1000/$weekday$=1/$day$>6/y-5>0/y-4>0:Ry4/6/?y-6;
!!VRy-7&$weekday$=1/$day$>6/1000/y-5>0/y-4>0:Sy-6 -500 *10 *y-5 :100;
!!IF&1000/$weekday$=1/$day$>6/y-5>0/y-4>0:Q1/6/y-7/23/22/7/y-9/1^{Dwarven Treasury}
Week Production
{%Y-7} Gold {%Y-9} Mithril^;
!?FU1007; [Loop from town owned by current player]
!!UN:U98/-1/-1/580; [get town location into v600-v602]
!!CA580:T?y1 O?y2; [get town Type and Owner]
!!FU&y1<>1:E; [exit if current player not own a Rampart town ]
!!CA580:B3/22; [Town has improvement 22 dwarven treasury build flag1=1]
!!FU&-1:E; exit if not rampart town and treasury not build
!!OW&x1=y2:Rx1/6/d500;
!!VRy-8&x1=y2:Sy-8 +500;
!!OW&x1=y2/$weekday$=1:Rx1/7/d2;
!!VRy-9&x1=y2/$weekday$=1:Sy-9 +2;
!!VRy-5:Sy-5 +1;
!!VRy-4&x1=y2:S1;
**************************************
** End Rampart Town Treasury change **
**************************************
*******************************************
** Start Rampart Fountain of Fortune change **
*******************************************
** Rampart Fountain of Fortune mod 1.0 by Axe
** OBJECT : Rampart Fountain of Fortune (town 1, obj 21) allow to learn Luck at Basic level for 2000 gold
** Updated: October 28, 2010
** Variables Used: v314
** Functions: None
** Main click routine **
!?CM1;
!!CA-1:T?y-7 H1/?y-3; [Get type of town and visitor hero]
!!FU&y-7<>1:E; [Exit if it's not Rampart town]
!!CM:I?y-2 F?y-6; // get the clicked field
!!CM&y-2=21:R0; //disable standard reaction
!!FU&y-2<>21:E; // exit, if not clicked at Fountain of Fortune
!!IF&y-6=512/1000:Q1/20/30/23/21/20/30/4^{Fountain of Fortune}
The Fountain of Fortune allows you to learn
{Basic Luck}
for 2000 Gold
^;
!!FU&y-6=512:E; [Exit if right click]
!!IF:V1/0; reset flag 1
!!OW:R-1/6/?y3; get owner's gold
!!IF&1000/y-6=0/y3<2000:Q1/20/30/1^{Fountain of Fortune}
The Fountain of Fortune allows you to learn
{Basic Luck}
for 2000 Gold
{NOT ENOUGHT GOLD}^;
!!FU&y3<2000:E; [Exit if not enought gold]
!!IF&1000/y-6=0/y-3<0:Q1/20/30/1^{Fountain of Fortune}
The Fountain of Fortune allows you to learn
{Basic Luck}
for 2000 Gold
{NO VISITOR HERO}^;
!!FU&y-3<0:E; [Exit if no visitor hero]
!!IF&1000/y-6=0/y3>1999:Q1/20/30/2^{Fountain of Fortune}
The Fountain of Fortune allows you to learn
{Basic Luck}
for 2000 Gold
^;
!!FU&-1:E; [Exit if cancel button]
!!VRv314:S9; [choice Luck Fountain of Fortune]
!!HEy-3:Sv314/?y2; get hero expertise with this skill
!!IF&y2>0/1000/v314=9:Q1/20/30/1^{Fountain of Fortune}
Skill already owned^; msg if already owned SORCERY
!!FU&y2>0:E; [Exit if skill already owned]
!!IF&1000/v314=9:Q1/20/30/36/-102000/1^{Fountain of Fortune}
Skill Learned^; msg if buy skill SORCERY
!!OW:R-1/6/d-2000; pay 2000 gold
!!HEy-3:Sv314/1; set skill to basic
!!IF:V1/0; reset flag 1
*****************************************
** End Rampart Fountain of Fortune change **
*****************************************
*******************************************
** Start Tower Lookout Tower change **
*******************************************
** Tower Lookout Tower mod 1.0 by Axe
** OBJECT : Tower Lookout Tower (town 2, obj 21) allow to learn Eagle eye or Sorcery at Basic level for 2000 gold
** Updated: October 28, 2010
** Variables Used: v314
** Functions: None
** Main click routine **
!?CM1;
!!CA-1:T?y-7 H1/?y-3; [Get type of town and visitor hero]
!!FU&y-7<>2:E; [Exit if it's not Tower town]
!!CM:I?y-2 F?y-6; // get the clicked field
!!CM&y-2=21:R0; //disable standard reaction
!!FU&y-2<>21:E; // exit, if not clicked at Lookout Tower
!!IF&y-6=512/1000:Q1/20/78/24/21/20/36/4^{Lookout Tower}
The Lookout Tower allows you to learn
{Basic Sorcery} or {Basic Eagle Eye}
for 2000 Gold
^;
!!FU&y-6=512:E; [Exit if right click]
!!IF:V1/0; reset flag 1
!!OW:R-1/6/?y3; get owner's gold
!!IF&1000/y-6=0/y3<2000:Q1/20/78/20/36/1^{Lookout Tower}
The Lookout Tower allows you to learn
{Basic Sorcery} or {Basic Eagle Eye}
for 2000 Gold
{NOT ENOUGHT GOLD}^;
!!FU&y3<2000:E; [Exit if not enought gold]
!!IF&1000/y-6=0/y-3<0:Q1/20/78/20/36/1^{Lookout Tower}
The Lookout Tower allows you to learn
{Basic Sorcery} or {Basic Eagle Eye}
for 2000 Gold
{NO VISITOR HERO}^;
!!FU&y-3<0:E; [Exit if no visitor hero]
!!IF&1000/y-6=0/y3>1999:Q1/20/78/20/36/10^{Lookout Tower}
The Lookout Tower allows you to learn
{Basic Sorcery} or {Basic Eagle Eye}
for 2000 Gold
^;
!!FU&v1=0:E; [Exit if cancel button]
!!VRv314&v1=1:S25; [left choice SORCERY Lookout Tower]
!!VRv314&v1=2:S11; [right choice EAGLE EYE Lookout Tower]
!!HEy-3:Sv314/?y2; get hero expertise with this skill
!!IF&y2>0/1000/v314=25:Q1/20/78/1^{Lookout Tower}
Skill already owned^; msg if already owned SORCERY
!!IF&y2>0/1000/v314=11:Q1/20/36/1^{Lookout Tower}
Skill already owned^; msg if already owned EAGLE EYE
!!FU&y2>0:E; [Exit if skill already owned]
!!IF&1000/v314=25:Q1/20/78/36/-102000/1^{Lookout Tower}
Skill Learned^; msg if buy skill SORCERY
!!IF&1000/v314=11:Q1/20/36/36/-102000/1^{Lookout Tower}
Skill Learned^; msg if buy skill EAGLE EYE
!!OW:R-1/6/d-2000; pay 2000 gold
!!HEy-3:Sv314/1; set skill to basic
!!IF:V1/0; reset flag 1
*****************************************
** End Tower Lookout Tower change **
*****************************************
*******************************************
** Start Inferno Brimstone StormClouds change **
*******************************************
** Inferno Brimstone StormClouds mod 1.0 by Axe
** OBJECT : Inferno Brimstone StormClouds (town 3, obj 21) allow to learn Fire Magic or Intelligence at Basic level for 2000 gold
** Updated: October 28, 2010
** Variables Used: v314
** Functions: None
** Main click routine **
!?CM1;
!!CA-1:T?y-7 H1/?y-3; [Get type of town and visitor hero]
!!FU&y-7<>3:E; [Exit if it's not Inferno town]
!!CM:I?y-2 F?y-6; // get the clicked field
!!CM&y-2=21:R0; //disable standard reaction
!!FU&y-2<>21:E; // exit, if not clicked at Brimstone StormClouds
!!IF&y-6=512/1000:Q1/20/45/25/21/20/75/4^{Brimstone StormClouds}
The Brimstone StormClouds allows you to learn
{Basic Fire Magic} or {Basic Intelligence}
for 2000 Gold
^;
!!FU&y-6=512:E; [Exit if right click]
!!IF:V1/0; reset flag 1
!!OW:R-1/6/?y3; get owner's gold
!!IF&1000/y-6=0/y3<2000:Q1/20/45/20/75/1^{Brimstone StormClouds}
The Brimstone StormClouds allows you to learn
{Basic Fire Magic} or {Basic Intelligence}
for 2000 Gold
{NOT ENOUGHT GOLD}^;
!!FU&y3<2000:E; [Exit if not enought gold]
!!IF&1000/y-6=0/y-3<0:Q1/20/45/20/75/1^{Brimstone StormClouds}
The Brimstone StormClouds allows you to learn
{Basic Fire Magic} or {Basic Intelligence}
for 2000 Gold
{NO VISITOR HERO}^;
!!FU&y-3<0:E; [Exit if no visitor hero]
!!IF&1000/y-6=0/y3>1999:Q1/20/45/20/75/10^{Brimstone StormClouds}
The Brimstone StormClouds allows you to learn
{Basic Fire Magic} or {Basic Intelligence}
for 2000 Gold
^;
!!FU&v1=0:E; [Exit if cancel button]
!!VRv314&v1=1:S14; [left choice FIRE MAGIC Brimstone StormClouds]
!!VRv314&v1=2:S24; [right choice INTELLIGENCE Brimstone StormClouds]
!!HEy-3:Sv314/?y2; get hero expertise with this skill
!!IF&y2>0/1000/v314=14:Q1/20/45/1^{Brimstone StormClouds}
Skill already owned^; msg if already owned FIRE MAGIC
!!IF&y2>0/1000/v314=24:Q1/20/75/1^{Brimstone StormClouds}
Skill already owned^; msg if already owned INTELLIGENCE
!!FU&y2>0:E; [Exit if skill already owned]
!!IF&1000/v314=14:Q1/20/45/36/-102000/1^{Brimstone StormClouds}
Skill Learned^; msg if buy skill FIRE MAGIC
!!IF&1000/v314=24:Q1/20/75/36/-102000/1^{Brimstone StormClouds}
Skill Learned^; msg if buy skill INTELLIGENCE
!!OW:R-1/6/d-2000; pay 2000 gold
!!HEy-3:Sv314/1; set skill to basic
!!IF:V1/0; reset flag 1
*****************************************
** End Inferno Brimstone StormClouds change **
*****************************************
*******************************************
** Start Necropolis Cover of Darkness change **
*******************************************
** Necropolis Cover of Darkness mod 1.0 by Axe
** OBJECT : Necropolis Cover of Darkness (town 4, obj 17) allow to learn Necromancy at Basic level for 2000 gold
** Updated: October 28, 2010
** Variables Used: v314
** Functions: None
** Main click routine **
!?CM1;
!!CA-1:T?y-7 H1/?y-3; [Get type of town and visitor hero]
!!FU&y-7<>4:E; [Exit if it's not NECROPOLIS town]
!!CM:I?y-2 F?y-6; // get the clicked field
!!CM&y-2=17:R0; //disable standard reaction
!!FU&y-2<>17:E; // exit, if not clicked at Cover of Darkness
!!IF&y-6=512/1000:Q1/20/39/26/17/20/39/4^{Cover of Darkness}
The Cover of Darkness allows you to learn
{Basic Necromancy}
for 2000 Gold
^;
!!FU&y-6=512:E; [Exit if right click]
!!IF:V1/0; reset flag 1
!!OW:R-1/6/?y3; get owner's gold
!!IF&1000/y-6=0/y3<2000:Q1/20/39/1^{Cover of Darkness}
The Cover of Darkness allows you to learn
{Basic Necromancy}
for 2000 Gold
{NOT ENOUGHT GOLD}^;
!!FU&y3<2000:E; [Exit if not enought gold]
!!IF&1000/y-6=0/y-3<0:Q1/20/39/1^{Cover of Darkness}
The Cover of Darkness allows you to learn
{Basic Necromancy}
for 2000 Gold
{NO VISITOR HERO}^;
!!FU&y-3<0:E; [Exit if no visitor hero]
!!IF&1000/y-6=0/y3>1999:Q1/20/39/2^{Cover of Darkness}
The Cover of Darkness allows you to learn
{Basic Necromancy}
for 2000 Gold
^;
!!FU&-1:E; [Exit if cancel button]
!!VRv314:S12; [choice NECROMANCY Cover of Darkness]
!!HEy-3:Sv314/?y2; get hero expertise with this skill
!!IF&y2>0/1000/v314=12:Q1/20/39/1^{Cover of Darkness}
Skill already owned^; msg if already owned SORCERY
!!FU&y2>0:E; [Exit if skill already owned]
!!IF&1000/v314=12:Q1/20/39/36/-102000/1^{Cover of Darkness}
Skill Learned^; msg if buy skill SORCERY
!!OW:R-1/6/d-2000; pay 2000 gold
!!HEy-3:Sv314/1; set skill to basic
!!IF:V1/0; reset flag 1
*****************************************
** End Necropolis Cover of Darkness change **
*****************************************
*******************************************
** Start Stronghold Ballista yard change **
*******************************************
** Stronghold Ballista Yard mod 1.0 by Axe
** OBJECT : Stronghold Ballista yard (town 6, obj 22) allow to learn Tactics or Archery at Basic level for 2000 gold
** Updated: October 28, 2010
** Variables Used: v314
** Functions: None
** Main click routine **
!?CM1;
!!CA-1:T?y-7 H1/?y-3; [Get type of town and visitor hero]
!!FU&y-7<>6:E; [Exit if it's not Stronghold town]
!!CM:I?y-2 F?y-6; // get the clicked field
!!CM&y-2=22:R0; //disable standard reaction
!!FU&y-2<>22:E; // exit, if not clicked at ballista yard
!!IF&y-6=512/1000:Q1/20/60/28/22/20/6/4^{Ballista Yard}
The Ballista Yard allows you to learn
{Basic Tactics} or {Basic Archery}
for 2000 Gold
^;
!!FU&y-6=512:E; [Exit if right click]
!!IF:V1/0; reset flag 1
!!OW:R-1/6/?y3; get owner's gold
!!IF&1000/y-6=0/y3<2000:Q1/20/60/20/6/1^{Ballista Yard}
The Ballista Yard allows you to learn
{Basic Tactics} or {Basic Archery}
for 2000 Gold
{NOT ENOUGHT GOLD}^;
!!FU&y3<2000:E; [Exit if not enought gold]
!!IF&1000/y-6=0/y-3<0:Q1/20/60/20/6/1^{Ballista Yard}
The Ballista Yard allows you to learn
{Basic Tactics} or {Basic Archery}
for 2000 Gold
{NO VISITOR HERO}^;
!!FU&y-3<0:E; [Exit if no visitor hero]
!!IF&1000/y-6=0/y3>1999:Q1/20/60/20/6/10^{Ballista Yard}
The Ballista Yard allows you to learn
{Basic Tactics} or {Basic Archery}
for 2000 Gold
^;
!!FU&v1=0:E; [Exit if cancel button]
!!VRv314&v1=1:S19; [left choice TACTICS Ballista Yard]
!!VRv314&v1=2:S1; [right choice ARCHERY Ballista Yard]
!!HEy-3:Sv314/?y2; get hero expertise with this skill
!!IF&y2>0/1000/v314=19:Q1/20/60/1^{Ballista Yard}
Skill already owned^; msg if already owned Tactics
!!IF&y2>0/1000/v314=1:Q1/20/6/1^{Ballista Yard}
Skill already owned^; msg if already owned Archery
!!FU&y2>0:E; [Exit if skill already owned]
!!IF&1000/v314=19:Q1/20/60/36/-102000/1^{Ballista Yard}
Skill Learned^; msg if buy skill Tactics
!!IF&1000/v314=1:Q1/20/6/36/-102000/1^{Ballista Yard}
Skill Learned^; msg if buy skill Archery
!!OW:R-1/6/d-2000; pay 2000 gold
!!HEy-3:Sv314/1; set skill to basic
!!IF:V1/0; reset flag 1
*****************************************
** End Stronghold Ballista yard change **
*****************************************
*******************************************
** Start Fortress Blood Oblelisk change **
*******************************************
** Fortress Blood Oblelisk mod 1.0 by Axe
** OBJECT : Blood Oblelisk (town 7, obj 22) allow to learn Pathfinding or Scouting at Basic level
** Updated: October 28, 2010
** Variables Used: v314
** Functions: None
** Main click routine **
!?CM1;
!!CA-1:T?y-7 H1/?y-3; [Get type of town and visitor hero]
!!FU&y-7<>7:E; [Exit if it's not Fortress town]
!!CM:I?y-2 F?y-6; // get the clicked field
!!CM&y-2=22:R0; //disable standard reaction
!!FU&y-2<>22:E; // exit, if not clicked at Blood Oblelisk
!!IF&y-6=512/1000:Q1/20/3/29/22/20/12/4^{Blood Oblelisk}
The Blood Oblelisk allows you to learn
{Basic Pathfinding} or {Basic Scouting}
for 2000 Gold
^;
!!FU&y-6=512:E; [Exit if right click]
!!IF:V1/0; reset flag 1
!!OW:R-1/6/?y3; get owner's gold
!!IF&1000/y-6=0/y3<2000:Q1/20/3/20/12/1^{Blood Oblelisk}
The Blood Oblelisk allows you to learn
{Basic Pathfinding} or {Basic Scouting}
for 2000 Gold
{NOT ENOUGHT GOLD}^;
!!FU&y3<2000:E; [Exit if not enought gold]
!!IF&1000/y-6=0/y-3<0:Q1/20/3/20/12/1^{Blood Oblelisk}
The Blood Oblelisk allows you to learn
{Basic Pathfinding} or {Basic Scouting}
for 2000 Gold
{NO VISITOR HERO}^;
!!FU&y-3<0:E; [Exit if no visitor hero]
!!IF&1000/y-6=0/y3>1999:Q1/20/3/20/12/10^{Blood Oblelisk}
The Blood Oblelisk allows you to learn
{Basic Pathfinding} or {Basic Scouting}
for 2000 Gold
^;
!!FU&v1=0:E; [Exit if cancel button]
!!VRv314&v1=1:S0; [left choice PATHFINDING Blood Oblelisk]
!!VRv314&v1=2:S3; [right choice SCOUTING Blood Oblelisk]
!!HEy-3:Sv314/?y2; get hero expertise with this skill
!!IF&y2>0/1000/v314=0:Q1/20/3/1^{Blood Oblelisk}
Skill already owned^; msg if already owned PATHFINDING
!!IF&y2>0/1000/v314=3:Q1/20/12/1^{Blood Oblelisk}
Skill already owned^; msg if already owned SCOUTING
!!FU&y2>0:E; [Exit if skill already owned]
!!IF&1000/v314=0:Q1/20/3/36/-102000/1^{Blood Oblelisk}
Skill Learned^; msg if buy skill PATHFINDING
!!IF&1000/v314=3:Q1/20/12/36/-102000/1^{Blood Oblelisk}
Skill Learned^; msg if buy skill SCOUTING
!!OW:R-1/6/d-2000; pay 2000 gold
!!HEy-3:Sv314/1; set skill to basic
!!IF:V1/0; reset flag 1
*****************************************
** End Fortress Blood Oblelisk change **
*****************************************
____________
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
|
posted November 22, 2010 08:19 AM |
|
|
Thanks, good script but unnecessarily long, you can compress it.
First, general CM check, only once:
ZVSE
!?CM1;
!!CA-1:T?y-7 H1/?v99; [Get type of town and visitor hero]
!!CM:I?v98 F?y-6; // get the clicked field
!!FU&v99<0:E; exit if no hero
!!FU19000&y-7=0/y-6=0/v98=22:Pv99; castle
!!FU19001&y-7=1/y-6=0/v98=21:Pv99; rampart
!!FU19002&y-7=2/y-6=0/v98=21:Pv99; tower
!!FU19003&y-7=3/y-6=0/v98=21:Pv99; inferno
!!FU19004&y-7=4/y-6=0/v98=17:Pv99; necropolis
!!FU19005&y-7=6/y-6=0/v98=22:Pv99; stronghold
!!FU19006&y-7=7/y-6=0/v98=22:Pv99; fortress
Then castle example:
!?FU19000;
!!IF:Q1/22/5/22/22/10^{Tavern} or {Brotherhood of Sword}
In which building do you want to enter ?
^;
!!FU|v1=1/v1=0:E;
!!CM&v1=2:R0; [right choice Brotherhood of Sword]//disable standard reaction
!!IF:Q1/20/69/20/72/10^{Brotherhood of Sword}
The Brotherhood of Sword allows you to learn
{Basic Offence} or {Basic Armorer}
for 2000 Gold
^;
!!FU&v1=0:E; [Exit if cancel button]
!!OW:R-1/6/?y3; get owner's gold
!!IF&y3<2000:Q1/20/69/20/72/1^{NOT ENOUGH GOLD}^;
!!FU&y3<2000:E; [Exit if not enought gold]
!!VRv314&v1=1:S22; [left choice OFFENCE Brotherhood of Sword]
!!VRv314&v1=2:S23; [right choice ARMORER Brotherhood of Sword]
!!VRv315&v314=22:S69;
!!VRv315&v314=23:S72;
!!HEx1:Sv314/?y2; get hero expertise with this skill
!!IF&y2>0:Q1/20/v315/1^{Brotherhood of Sword}
Skill already owned^; msg if the skill is present
!!FU&y2>0:E; [Exit if skill already owned]
!!IF:Q1/20/v315/36/-102000/1^{Brotherhood of Sword}
Skill Learned^; msg if buy any skill
!!OW:R-1/6/d-2000; pay 2000 gold
!!HEx1:Sv314/1; set skill to basic
Use next functions for each castle type. Castle bonus is way too overpowered and your necromancy skill can create some surprises, if used on very good heros. I would be careful with it :)
____________
Era II mods and utilities
|
|
Axe
Tavern Dweller
|
|
posted November 22, 2010 01:44 PM |
|
|
Hi,
Thanks Salamandre for your post  .
I'll modify my script to compress it soon, yes it is too long.
For the Castle i can only give Offence for 2000 gold, but for necromancer, i always play random maps, and often frustrated when i have necromancer town, without one of my hero who have the skill necromancy it's why i give this skill for 2000 gold .
I'll perhaps modify my script to give only 1 skill for each town, for not unbalancing much the game and post it, i hope soon.
____________
|
|
Axe
Tavern Dweller
|
|
posted November 22, 2010 03:59 PM |
|
Edited by Axe at 18:44, 22 Nov 2010.
|
Hi
As promised this is the new script :
************************************************************
ZVSE
ERMS_ScriptName=script93
ERMS_ScriptAuthor=Axe
ERMS_ScriptVersion=1.0.0
ERMS_ScriptDate=22.11(November).2010
ERMS_ScriptERMVersion=2.70
ERMS_ScriptLanguage=Français (France) or English (native)
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2005.9.7.814
** OBJECT : Castle Brotherhood of Sword (town 0, obj 22) allow to learn Offence at Basic level for 2000 gold
** OBJECT : Rampart Treasury (town 1, obj 22) give 500 gold/day and 2 Mithril /week 10% interest for 5000 gold
** OBJECT : Rampart Fountain of Fortune (town 1, obj 21) allow to learn Luck at Basic level for 2000 gold
** OBJECT : Tower Lookout Tower (town 2, obj 21) allow to learn Eagle eye or Sorcery at Basic level for 2000 gold
** OBJECT : Inferno Brimstone StormClouds (town 3, obj 21) allow to learn Fire Magic or Intelligence at Basic level for 2000 gold
** OBJECT : Necropolis Cover of Darkness (town 4, obj 17) allow to learn Necromancy at Basic level for 2000 gold
** OBJECT : Stronghold Ballista yard (town 6, obj 22) allow to learn Tactics or Archery at Basic level for 2000 gold
** OBJECT : Fortress Blood Oblelisk (town 7, obj 22) allow to learn Pathfinding or Scouting at Basic level for 2000 gold
** Variables Used: v314 v315 v580 local
** Functions: FU1007 Dwarven treasury FU19000 to FU19009
** A special thanks to Salamandre for help
** Timer routine for rampart treasury
!?TM2; // one times daily
!!VRy-4:S0;
!!VRy-5:S0;
!!VRy-7:S0;
!!VRy-8:S0;
!!VRy-9:S0;
!!UN:U98/-1/?y1;
!!IF&y1=0:E;
!!OW:C?y4;
!!VRv580:S-1; [reset coordinate index]
!!DO1007/1/y1/1&y1>0:Py4; [Loop from town owned by current player]
!!OW&1000/$weekday$=1/$day$>6/y-5>0/y-4>0:Ry4/6/?y-6;
!!VRy-7&$weekday$=1/$day$>6/1000/y-5>0/y-4>0:Sy-6 -500 *10 *y-5 :100;
!!IF&1000/$weekday$=1/$day$>6/y-5>0/y-4>0:Q1/6/y-7/23/22/7/y-9/1^{Dwarven Treasury}
Week Production
{%Y-7} Gold {%Y-9} Mithril^;
** Main click routine
!?CM1;
!!CA-1:T?y-7 H1/?v99; [Get type of town and visitor hero]
!!CM:I?v98 F?y-6; // get the clicked field
!!FU19000&y-7=0/v98=22:Pv99/y-6; castle
!!FU19001&y-7=1/v98=21:Pv99/y-6; rampart
!!FU19002&y-7=2/v98=21:Pv99/y-6; tower
!!FU19003&y-7=3/v98=21:Pv99/y-6; inferno
!!FU19004&y-7=4/v98=17:Pv99/y-6; necropolis
!!FU19006&y-7=6/v98=22:Pv99/y-6; stronghold
!!FU19007&y-7=7/v98=22:Pv99/y-6; fortress
!!FU19009&y-7=1/v98=22:Py-6; rampart treasury
*******************************************
** Start Castle Brotherhood of Sword change **
*******************************************
!?FU19000; x1=Visitor Hero x2=type of click
!!IF&x2=0:Q1/22/5/22/22/10^{Tavern} or {Brotherhood of Sword}
In which building do you want to enter ?
^;
!!FU|v1=1/v1=0:E;
!!CM&v1=2:R0; [right choice Brotherhood of Sword]//disable standard reaction
!!IF&x2=512/1000:Q1/20/69/22/22/20/69/4^{Brotherhood of Sword}
The Brotherhood of Sword allows you to learn
{Basic Offence}
for 2000 Gold
^;
!!FU&x2<>0:E; [Exit if other click than left click]
!!OW:R-1/6/?y3; get owner's gold
!!IF&y3>1999/x1>0:Q1/20/69/2^{Brotherhood of Sword}
The Brotherhood of Sword allows you to learn
{Basic Offence}
for 2000 Gold
^;
!!IF&y3>1999/x1<0:Q1/20/69/1^NO VISITOR HERO TO LEARN^; msg if no visitor hero
!!IF&y3<2000:Q1/20/69/1^NOT ENOUGH GOLD^;
!!FU|-1/x1<0/y3<2000:E; [Exit if cancel button or no visitor hero or not enought gold]
!!VRv314:S22; [choice OFFENCE]
!!VRv315:S69;
!!HEx1:Sv314/?y2; get hero expertise with this skill
!!IF&y2>0:Q1/20/v315/1^{Brotherhood of Sword}
Skill already owned^; msg if the skill is present
!!FU&y2>0:E; [Exit if skill already owned]
!!IF:Q1/20/v315/36/-102000/1^{Brotherhood of Sword}
Skill Learned^; msg if buy any skill
!!OW:R-1/6/d-2000; pay 2000 gold
!!HEx1:Sv314/1; set skill to basic
*******************************************
** Start Rampart Fountain of Fortune change **
*******************************************
!?FU19001; x1=Visitor Hero x2=type of click
!!CM:R0; //disable standard reaction
!!IF&x2=512/1000:Q1/20/30/23/21/20/30/4^{Fountain of Fortune}
The Fountain of Fortune allows you to learn
{Basic Luck}
for 2000 Gold
^;
!!FU&x2<>0:E; [Exit if other click than left click]
!!OW:R-1/6/?y3; get owner's gold
!!IF&y3>1999/x1>0:Q1/20/30/2^{Fountain of Fortune}
The Fountain of Fortune allows you to learn
{Basic Luck}
for 2000 Gold
^;
!!IF&y3>1999/x1<0:Q1/20/30/1^NO VISITOR HERO^; msg if no visitor hero
!!IF&y3<2000:Q1/20/30/1^NOT ENOUGH GOLD^;
!!FU|-1/x1<0/y3<2000:E; [Exit if cancel button or no visitor hero or not enought gold]
!!VRv314:S9; [choice LUCK]
!!VRv315:S30;
!!HEx1:Sv314/?y2; get hero expertise with this skill
!!IF&y2>0:Q1/20/v315/1^{Fountain of Fortune}
Skill already owned^; msg if the skill is present
!!FU&y2>0:E; [Exit if skill already owned]
!!IF:Q1/20/v315/36/-102000/1^{Fountain of Fortune}
Skill Learned^; msg if buy any skill
!!OW:R-1/6/d-2000; pay 2000 gold
!!HEx1:Sv314/1; set skill to basic
*******************************************
** Start Tower Lookout Tower change **
*******************************************
!?FU19002; x1=Visitor Hero x2=type of click
!!CM:R0; //disable standard reaction
!!IF&x2=512/1000:Q1/20/78/24/21/20/36/4^{Lookout Tower}
The Lookout Tower allows you to learn
{Basic Sorcery} or {Basic Eagle Eye}
for 2000 Gold
^;
!!FU&x2<>0:E; [Exit if other click than left click]
!!OW:R-1/6/?y3; get owner's gold
!!IF&y3>1999/x1>0:Q1/20/78/20/36/10^{Lookout Tower}
The Lookout Tower allows you to learn
{Basic Sorcery} or {Basic Eagle Eye}
for 2000 Gold
^;
!!IF&y3>1999/x1<0:Q1/20/78/20/36/1^NO VISITOR HERO^; msg if no visitor hero
!!IF&y3<2000:Q1/20/78/20/36/1^NOT ENOUGH GOLD^;
!!FU|v1=0/x1<0/y3<2000:E; [Exit if cancel button or no visitor hero or not enought gold]
!!VRv314&v1=1:S25; [left choice SORCERY]
!!VRv314&v1=2:S11; [right choice EAGLE EYE]
!!VRv315&v314=25:S78;
!!VRv315&v314=11:S36;
!!HEx1:Sv314/?y2; get hero expertise with this skill
!!IF&y2>0:Q1/20/v315/1^{Lookout Tower}
Skill already owned^; msg if the skill is present
!!FU&y2>0:E; [Exit if skill already owned]
!!IF:Q1/20/v315/36/-102000/1^{Lookout Tower}
Skill Learned^; msg if buy any skill
!!OW:R-1/6/d-2000; pay 2000 gold
!!HEx1:Sv314/1; set skill to basic
*******************************************
** Start Inferno Brimstone StormClouds **
*******************************************
!?FU19003; x1=Visitor Hero x2=type of click
!!CM:R0; //disable standard reaction
!!IF&x2=512/1000:Q1/20/45/25/21/20/75/4^{Brimstone StormClouds}
The Brimstone StormClouds allows you to learn
{Basic Fire Magic} or {Basic Intelligence}
for 2000 Gold
^;
!!FU&x2<>0:E; [Exit if other click than left click]
!!OW:R-1/6/?y3; get owner's gold
!!IF&y3>1999/x1>0:Q1/20/45/20/75/10^{Brimstone StormClouds}
The Brimstone StormClouds allows you to learn
{Basic Fire Magic} or {Basic Intelligence}
for 2000 Gold
^;
!!IF&y3>1999/x1<0:Q1/20/45/20/75/1^NO VISITOR HERO^; msg if no visitor hero
!!IF&y3<2000:Q1/20/45/20/75/1^NOT ENOUGH GOLD^;
!!FU|v1=0/x1<0/y3<2000:E; [Exit if cancel button or no visitor hero or not enought gold]
!!VRv314&v1=1:S14; [left choice FIRE MAGIC]
!!VRv314&v1=2:S24; [right choice INTELLIGENCE]
!!VRv315&v314=14:S45;
!!VRv315&v314=24:S75;
!!HEx1:Sv314/?y2; get hero expertise with this skill
!!IF&y2>0:Q1/20/v315/1^{Brimstone StormClouds}
Skill already owned^; msg if the skill is present
!!FU&y2>0:E; [Exit if skill already owned]
!!IF:Q1/20/v315/36/-102000/1^{Brimstone StormClouds}
Skill Learned^; msg if buy any skill
!!OW:R-1/6/d-2000; pay 2000 gold
!!HEx1:Sv314/1; set skill to basic
*******************************************
** Start Necropolis Cover of Darkness change **
*******************************************
!?FU19004; x1=Visitor Hero x2=type of click
!!CM:R0; //disable standard reaction
!!IF&x2=512/1000:Q1/20/39/26/17/20/39/4^{Cover of Darkness}
The Cover of Darkness allows you to learn
{Basic Necromancy}
for 2000 Gold
^;
!!FU&x2<>0:E; [Exit if other click than left click]
!!OW:R-1/6/?y3; get owner's gold
!!IF&y3>1999/x1>0:Q1/20/39/2^{Cover of Darkness}
The Cover of Darkness allows you to learn
{Basic Necromancy}
for 2000 Gold
^;
!!IF&y3>1999/x1<0:Q1/20/39/1^NO VISITOR HERO^; msg if no visitor hero
!!IF&y3<2000:Q1/20/39/1^NOT ENOUGH GOLD^;
!!FU|-1/x1<0/y3<2000:E; [Exit if cancel button or no visitor hero or not enought gold]
!!VRv314:S12; [choice NECROMANCY]
!!VRv315:S39;
!!HEx1:Sv314/?y2; get hero expertise with this skill
!!IF&y2>0:Q1/20/v315/1^{Fountain of Fortune}
Skill already owned^; msg if the skill is present
!!FU&y2>0:E; [Exit if skill already owned]
!!IF:Q1/20/v315/36/-102000/1^{Fountain of Fortune}
Skill Learned^; msg if buy any skill
!!OW:R-1/6/d-2000; pay 2000 gold
!!HEx1:Sv314/1; set skill to basic
*******************************************
** Start Stronghold Ballista yard change **
*******************************************
!?FU19006; x1=Visitor Hero x2=type of click
!!CM:R0; //disable standard reaction
!!IF&x2=512/1000:Q1/20/60/28/22/20/6/4^{Ballista Yard}
The Ballista Yard allows you to learn
{Basic Tactics} or {Basic Archery}
for 2000 Gold
^;
!!FU&x2<>0:E; [Exit if other click than left click]
!!OW:R-1/6/?y3; get owner's gold
!!IF&y3>1999/x1>0:Q1/20/60/20/6/10^{Ballista Yard}
The Ballista Yard allows you to learn
{Basic Tactics} or {Basic Archery}
for 2000 Gold
^;
!!IF&y3>1999/x1<0:Q1/20/60/20/6/1^NO VISITOR HERO^; msg if no visitor hero
!!IF&y3<2000:Q1/20/60/20/6/1^NOT ENOUGH GOLD^;
!!FU|v1=0/x1<0/y3<2000:E; [Exit if cancel button or no visitor hero or not enought gold]
!!VRv314&v1=1:S19; [left choice TACTICS]
!!VRv314&v1=2:S1; [right choice ARCHERY]
!!VRv315&v314=19:S60;
!!VRv315&v314=1:S6;
!!HEx1:Sv314/?y2; get hero expertise with this skill
!!IF&y2>0:Q1/20/v315/1^{Ballista Yard}
Skill already owned^; msg if the skill is present
!!FU&y2>0:E; [Exit if skill already owned]
!!IF:Q1/20/v315/36/-102000/1^{Ballista Yard}
Skill Learned^; msg if buy any skill
!!OW:R-1/6/d-2000; pay 2000 gold
!!HEx1:Sv314/1; set skill to basic
*******************************************
** Start Fortress Blood Oblelisk change **
*******************************************
!?FU19007; x1=Visitor Hero x2=type of click
!!CM:R0; //disable standard reaction
!!IF&x2=512/1000:Q1/20/3/29/22/20/12/4^{Blood Oblelisk}
The Blood Oblelisk allows you to learn
{Basic Pathfinding} or {Basic Scouting}
for 2000 Gold
^;
!!FU&x2<>0:E; [Exit if other click than left click]
!!OW:R-1/6/?y3; get owner's gold
!!IF&y3>1999/x1>0:Q1/20/3/20/12/10^{Blood Oblelisk}
The Blood Oblelisk allows you to learn
{Basic Pathfinding} or {Basic Scouting}
for 2000 Gold
^;
!!IF&y3>1999/x1<0:Q1/20/3/20/12/1^NO VISITOR HERO^; msg if no visitor hero
!!IF&y3<2000:Q1/20/3/20/12/1^NOT ENOUGH GOLD^;
!!FU|v1=0/x1<0/y3<2000:E; [Exit if cancel button or no visitor hero or not enought gold]
!!VRv314&v1=1:S0; [left choice PATHFINDING]
!!VRv314&v1=2:S3; [right choice SCOUTING]
!!VRv315&v314=0:S3;
!!VRv315&v314=3:S12;
!!HEx1:Sv314/?y2; get hero expertise with this skill
!!IF&y2>0:Q1/20/v315/1^{Blood Oblelisk}
Skill already owned^; msg if the skill is present
!!FU&y2>0:E; [Exit if skill already owned]
!!IF:Q1/20/v315/36/-102000/1^{Blood Oblelisk}
Skill Learned^; msg if buy any skill
!!OW:R-1/6/d-2000; pay 2000 gold
!!HEx1:Sv314/1; set skill to basic
*******************************************
** Start Rampart Town Treasury change **
*******************************************
!?FU19009; x1=type of click
!!CM:R0; //disable standard reaction
!!IF&x1=512/1000:Q1/23/22/4^{Treasury}
The Treasury earns you
{10% interest} on any gold you have at the start of each week
{500} Gold per day
{2} Mithril per week^;
!!IF&x1=0/1000:Q1/23/22/1^{Treasury}
The Treasury earns you
{10% interest} on any gold you have at the start of each week
{500} Gold per day
{2} Mithril per week^;
!?FU1007; [Loop from town owned by current player]
!!UN:U98/-1/-1/580; [get town location into v600-v602]
!!CA580:T?y1 O?y2; [get town Type and Owner]
!!FU&y1<>1:E; [exit if current player not own a Rampart town ]
!!CA580:B3/22; [Town has improvement 22 dwarven treasury build flag1=1]
!!FU&-1:E; exit if not rampart town and treasury not build
!!OW&x1=y2:Rx1/6/d500;
!!VRy-8&x1=y2:Sy-8 +500;
!!OW&x1=y2/$weekday$=1:Rx1/7/d2;
!!VRy-9&x1=y2/$weekday$=1:Sy-9 +2;
!!VRy-5:Sy-5 +1;
!!VRy-4&x1=y2:S1;
*************************************************************
first script : 693 lines, second one 337 lines, thx Salamandre
I hope i haven't do any errors ...
i have started a new post with some of my mods, but somes unbalanced the game
[url=http://heroescommunity.com/viewthread.php3?TID=34076]new post[/url]
____________
|
| |
|
|
