|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted August 30, 2015 06:54 PM |
|
|
Once the battle starts, creatures are converted to battle stacks. You can give them all you want, as long as you give with BM commands. If you code MA in battle, of course changes will remain after battle. That's why in battle everyone codes BM, and in map adventure, MA.
Had you consult the zilion of scripts around, you would have known this since longtime.
____________
Era II mods and utilities
|
|
majaczek
Supreme Hero
Work at Magic Dimmension
|
posted August 30, 2015 07:17 PM |
|
Edited by majaczek at 20:19, 30 Aug 2015.
|
thanks Hawaiing
I edited a few numbers to match my Amethyst Upgrades mod (3rd grade elementals creature ID) and the function number
I'll check if it works
Quote: ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.10.5.945
ERMS_ScriptDate=30.8(August).2015
Thanks for great help to Hawaiing !
!?BG0;
!!BG:A?y1 H?y2 S?y3 Q?y4;
!!FU|y1<>1/y2<0/y3<66/y3>69:E;
!!UN:C5909376/4/522067228;[reset old hard code]
!!UN:C6919200/4/?y10;
!!VRy13:Sx1*4+21452+y10;
!!UN:Cy13/4/?y14;
!!VRy15:Sy10+21440;
!!UN:Cy15/4/?y16;
!!SN:E5133040/2/y14/y3/y16;
!!VRy17:Sv1;[skillLevel]
!!VRy17&y17<0:S0;
!!VRy17&y17>3:S3;
!!HEy2:S12/?y12;
!!if&y12>0:;
!!UN:C5909376/4/623191333;[disable summon spell and rewrite it]
!!FU55419&y3=66y4/66/159;
!!FU55419&y3=67y4/67/159;
!!FU55419&y3=68y4/68/159;
!!FU55419&y3=69y4/69/159;
!!FU:E;
!!en:;
!!if&y17>1:;
!!UN:C5909376/4/623191333;
!!if&y3=66:; Fire Magic
!!FU55419&y17=2y4/66/129;
!!FU55419&y17=3y4/66/202;
!!FU:E;
!!en:;
!!if&y3=69:; Air Magic
!!FU55419&y17=2y4/67/127;
!!FU55419&y17=3y4/67/208;
!!FU:E;
!!en:;
!!if&y3=68:; Water Magic
!!FU55419&y17=2y4/68/123;
!!FU55419&y17=3y4/68/224;
!!FU:E;
!!en:;
!!if&y3=67:; Earth Magic
!!FU55419&y17=2y4/69/125;
!!FU55419&y17=3y4/69/201;
!!FU:E;
!!en:;
!!en:;
!?FU55419;[summon creature]
*x1=0-1,x2=spellNUM(66-67,for Effect),x3=creature_type
!!UN:C6919200/4/?y10;[pCombatManager]
!!VRy11:Sx1*4+21460+y10;
!!UN:Cy11/4/?y12;[spellPower]
!!VRy13:Sx1*4+21452+y10;
!!UN:Cy13/4/?y14;[hero]
!!VRy15:Sy10+21440;
!!UN:Cy15/4/?y16;
!!SN:E5133040/2/y14/x2/y16;
!!VRy17:Sv1;[skillLevel]
!!VRy17&y17<0:S0;
!!VRy17&y17>3:S3;
!!SN:E5927824/2/y10/x2/x3/y12/y17;
!!VRy18:Sx1*4+78504+y10;
!!UN:Cy18/4/-1;[disable one elemental type limit]
I have a question: What if creature casts summon elemental? will it just summon base elemental or do nothing or crash?
I am anyway much grateful for your solution, yay!
EDIT: you made mistake in spell numbers I fixed it
I hope it will work now
EDIT: if creature casts summon elementals nothing happens - I checked... else it works very fine how to fix the Conflux Commander? I may edit Enchhanced commander script (as I already changed in mod knightmare commanders) to do it, or maybe it is enough to edit the script you have provided?
EDIT: I Guess
Quote:
!!FU|y1<>1/y2<0/y3<66/y3>69:E;
is to early
sadly you didn't wrote enough comments for me to know where to place it?
EDIT: Now it works default behaviour if casted by creature
Quote: ZVSE
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2004.10.5.945
ERMS_ScriptDate=30.8(August).2015
Thanks for great help to Hawaiing !
!?BG0;
!!BG:A?y1 H?y2 S?y3 Q?y4;
!_!FU|y1<>1/y2<0/y3<66/y3>69:E;
!!UN:C5909376/4/522067228;[reset old hard code]
!!UN:C6919200/4/?y10;
!!VRy13:Sx1*4+21452+y10;
!!UN:Cy13/4/?y14;
!!VRy15:Sy10+21440;
!!UN:Cy15/4/?y16;
!!SN:E5133040/2/y14/y3/y16;
!!FU|y1<>1/y2<0/y3<66/y3>69:E;
!!VRy17:Sv1;[skillLevel]
!!VRy17&y17<0:S0;
!!VRy17&y17>3:S3;
!!HEy2:S12/?y12;
!!if&y12>0:;
!!UN:C5909376/4/623191333;[disable summon spell and rewrite it]
!!FU55419&y3=66y4/66/159;
!!FU55419&y3=67y4/67/159;
!!FU55419&y3=68y4/68/159;
!!FU55419&y3=69y4/69/159;
!!FU:E;
!!en:;
!!if&y17>1:;
!!UN:C5909376/4/623191333;
!!if&y3=66:; Fire Magic
!!FU55419&y17=2y4/66/129;
!!FU55419&y17=3y4/66/202;
!!FU:E;
!!en:;
!!if&y3=69:; Air Magic
!!FU55419&y17=2y4/67/127;
!!FU55419&y17=3y4/67/208;
!!FU:E;
!!en:;
!!if&y3=68:; Water Magic
!!FU55419&y17=2y4/68/123;
!!FU55419&y17=3y4/68/224;
!!FU:E;
!!en:;
!!if&y3=67:; Earth Magic
!!FU55419&y17=2y4/69/125;
!!FU55419&y17=3y4/69/201;
!!FU:E;
!!en:;
!!en:;
!?FU55419;[summon creature]
*x1=0-1,x2=spellNUM(66-67,for Effect),x3=creature_type
!!UN:C6919200/4/?y10;[pCombatManager]
!!VRy11:Sx1*4+21460+y10;
!!UN:Cy11/4/?y12;[spellPower]
!!VRy13:Sx1*4+21452+y10;
!!UN:Cy13/4/?y14;[hero]
!!VRy15:Sy10+21440;
!!UN:Cy15/4/?y16;
!!SN:E5133040/2/y14/x2/y16;
!!VRy17:Sv1;[skillLevel]
!!VRy17&y17<0:S0;
!!VRy17&y17>3:S3;
!!SN:E5927824/2/y10/x2/x3/y12/y17;
!!VRy18:Sx1*4+78504+y10;
!!UN:Cy18/4/-1;[disable one elemental type limit]
I hope I haven't broken anything - I guessed where to move the line
|
|
Hawaiing
Adventuring Hero
|
posted August 31, 2015 04:06 AM |
|
Edited by Hawaiing at 04:08, 31 Aug 2015.
|
majaczek said:
I hope I haven't broken anything - I guessed where to move the line
You are right.I had fogot creature casts summon elemental.
So <!!UN:C5909376/4/522067228;[reset old hard code]> must reset at every BG0 or BG1.
!?BG0;
!!UN:C5909376/4/522067228;[reset old hard code]
!!BG:A?y1 H?y2 S?y3 Q?y4;
!!FU|y1<>1/y2<0/y3<66/y3>69:E;
PS;
about Amethyst.
It will lead to crash when 194#Werewolf trigger the ability.
Try and you will see it.
|
|
majaczek
Supreme Hero
Work at Magic Dimmension
|
posted August 31, 2015 02:34 PM |
|
Edited by majaczek at 14:35, 31 Aug 2015.
|
about amethyst and werewolf:
Maybe it's safer to disable that ability?
What were the UN:C code to disable guilty lines?
Are you sure that newest amethyst has the problem?
I succeed to add creatures, even shooter or casters ones via amethyst...
I made a mod which is similair to New Upgrades but have 3rd grade for every unit availible at town and without replacing old units also it have Town Guardian concept (similair to ones from Disciples II), note that Town Guardian is not yet buyable feature, for the time beeing each town with castle structure have it at siege
the mod name is for now Amethyst Upgrades
so you see Amethyst is essential for my uses
EDIT: and it have candie - graded elementals, which would be impossible without Hawaiing
|
|
Ahven
Tavern Dweller
|
posted September 01, 2015 06:29 PM |
|
|
Spell modification
Hi
I have searched trough threads instructions how to modify or create spells. Do you true WoG fans know where I can find these instructions?
So far I have been able to modify heroes, creatures and little bit about castles. I would like to add some lvl 5 damage spell to water magic.
____________
|
|
bloodsucker
Legendary Hero
|
posted September 01, 2015 07:20 PM |
|
|
Masters of Summoning mod adds a spell and TEW IV changes spell damage. See if it helps.
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted September 01, 2015 07:22 PM |
|
|
Ahven said: HiDo you true WoG fans know where I can find these instructions?
True fans are born with this present in their heart. They automatically know how to modify cosmic plasma and obtain whatever they want from game. For now, you should open the manual first (erm help) then seek knowledge inside.
____________
Era II mods and utilities
|
|
majaczek
Supreme Hero
Work at Magic Dimmension
|
posted September 01, 2015 07:29 PM |
|
|
my mod knightmare heroes modifies spellpower for specialists, and adds two or three magic related skills
PS: does spell modified by !!SS work as it is wanted to with Hawaiing's summon elementals code? I hope yes.
PPS: Hawaiing please, if you could, download my mod knightmare heroes and say if you like it
|
|
bloodsucker
Legendary Hero
|
posted September 02, 2015 12:47 AM |
|
|
How can I use SN:W vars instead of z vars in tooltips?
P.S.
I've made this script for the Roman Statue.
I already tested it and seams to be working alright but I wanted it to be revisitable after each battle even if the bonus hability should happen just once per week for all Temples (kind of like the Palace of Dreams) and I don't know how to do the first.
I mean I can work it around but I think there must be some standart property for this that I'm overlooking.
Temple of Apollo
---
ZVSE
!?TM38;
!!SN:W^TempleOfApollo^/0;
!?OB139/15&1000;
!!SN:W^TempleOfApollo^/?y9;
!!VRz1:S^Temple of Apollo^;
!!UN:A122/9/z1 A122/10/z1; [change Head of Legion description]
!!IF:Q1/8/122/1^In the Temples of Apollo you can pray for the god's favor. If you're lucky you may even get a random hability to one of your creatures.^;
!!UN:A122/9/0 A122/10/0;
!!IF:Q1^Do you want to pray?^;
!!FU&-1:E;
!!HE-1&y9=99:R1/3;
!!IF&y9=99:Q1/11/1/1^You're luck increase.^;
!!FU&y9=99:E;
!!VRv1:S0 R1; chances that god favors you
!!VRv2:S0 R4; random hability - fly, no retaliation, attack all around, two attacks, immune to fire
!!VRv3:S0 R6; slot to search for the hability
!!HE-1&v1=0:R1/3;
!!IF&v1=0:Q1/11/1/1^You're luck increase.^;
!!FU&v1=0:E;
!!VRv4&v2=0:S2; fly
!!VRv4&v2=1:S65536; no retaliation
!!VRv4&v2=2:S524288; attack all around
!!VRv4&v2=3:S32768; two attacks
!!VRv4&v2=4:S16384; immune to fire
!!VRz1&v2=0:S^Fly^;
!!VRz1&v2=1:S^No Retaliation^;
!!VRz1&v2=2:S^Attack All Around^;
!!VRz1&v2=3:S^Two Attacks^;
!!VRz1&v2=4:S^Immunity to Fire^;
!!HE-1:C0/v3/?y1/?y2; v3 position in slot y1 ID number of monster
!!HE-1&y1<1:R1/3;
!!IF&y1<1:Q1/11/1/1^You're luck increase.^;
!!FU&y1<1:E;
!!UN:N3/2/y1/1; get name of the creature
!!MA:Xy1/?y4;
!!VRy3:Sy4;
!!VRy3:&v4;
!!if&y3=0:;
!!VRv5:S0 R4;
!!IF:Q1^The god favors you. He offers to give %Z1 to your %Z2. Do you accept his blessing?^;
!!VRz1:S^God's Wrath^;
!!UN:A135/9/z1 A135/10/z1;
!!IF&-1/v5=0:Q1/8/135/1^Apollo is offended by your refuse. He sends some humble servants to remind you of you're place^;
!!UN:A135/9/0 A135/10/0;
!!HE-1&-1/v5=0:P?y6/?y7/?y8;
!!HE-1&-1/v5=0:Ty6/y7/y8/158/3500;
!!FU&-1:E;
!!VRy4:|v4;
!!MA:Xy1/y4;
!!SN:W^TempleOfApollo^/99;
!!el:;
!!IF:Q1/11/1/1^You're luck increase.^;
!!HE-1:R1/3;
!!en:;
-----
I've asked this before but since I didn't got any awser...
How can I trigger a battle just with commander?
------
Is there a timer that commonly used for montly visits like !?TM38 is used for weekly?
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted September 02, 2015 05:58 PM |
|
|
SN:W vars as z vars: not possible yet (that would be indeed great but life is unfair I know).
Commander battle only: you go in battle with only commander, obviously. Or you want while having all army, only commander show in a specific battle? Then you store all army in vars, delete army, then hero will go only with commander, restore army after battle.
Timer: always use timer 2 because is daily and compatible with ALL mods.
Then find the proper day using follow:
Day (1..n): !!VRv1:Sc;
Day (0..n): !!VRv1:Sc -1;
Day of the week (0..6): !!VRv1:Sc -1 %7;
Day of the week (1..7): !!VRv1:Sc -1 %7 +1;
Day of the month (0..27): !!VRv1:Sc -1 %28;
Week of the month (0..3): !!VRv1:Sc -1 %28 :7;
Week of the month (1..4): !!VRv1:Sc -1 %28 :7 +1;
Month: !!VRv1:Sc+27:28;
Week: !!VRv1:Sc+6:7;
Example of what you want:
!?TM2; timer 2, daily
!!VRv1:Sc -1 %28; get day of the month in v1
!!if&v1=1:;
;my script which will run only day 1 of the month
!!en:;
All this is part of erm help redone for era 2.47. A pity Bersy has no time to release.
For your big script, I don't get what you want.
|
|
bloodsucker
Legendary Hero
|
posted September 02, 2015 06:47 PM |
|
|
Salamandre said: you want while having all army, only commander show in a specific battle?
Yes, that's it. My idea is to recreate the Coliseus from Heroes IV but for commander (since in H3 the hero is not a separate entity) and since is commander who does the fighting rewards will also be for commander only (new basic skills and habilities, artifacts, maybe level experience with hero (in case of deaths). I was hoping for a less dramatic solution (a crash in betwen and you will never see that army again.
Salamandre said: For your big script, I don't get what you want.
It's working, you can try it. That one still allows all the visits you need for testing.
I elaborated a bit the problem of the one visits only but I still need to correct the Idol of Fortune strings and I'm not finding the right !!UN: parameter (if it exists).
How is suposed to work. It's kind of an Idol of Fortune (now is an Idol of Fortune), you can visit it betwen battles to increase your luck. Once a week one of the visitors MAY have the oportunity to give a random hability to a random creature in his army. If he accepts the bonus variable is set so that no more habilities are given for a week. He can refuse the bonus but there is a 20% chance the God gets offended and sends an undefeatable army (the Sacred Phoenixes are just for testing, I was intending to use this battle to train !!BM reciver).
All this is already working but not suffiently tested. I am trying to change tips and image of the Idol of Fortune but still didn't managed for that to work.
This is how the script starts now:
ZVSE
!?TM38;
!!SN:W^TempleOfApollo^/0;
!?OB139/15&1000;
!!HE-1:P?y1/?y2/?y3;
!!VRz1:S^Temple of Apollo^;
!!UN:A122/9/z1 A122/10/z1; [change Head of Legion description]
!!IF:Q1/8/122/1^In the Temples of Apollo you can pray for the god's favor. If you're lucky you may even get a random hability to one of your creatures.^;
!!UN:A122/9/0 A122/10/0;
!!IF:Q1^Do you want to pray?^;
!!FU&-1:E;
!!OBy1/y2/y3:T38;
!$OBy1/y2/1&1000;
!!SN:W^TempleOfApollo^/?y9;
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted September 02, 2015 06:52 PM |
|
|
bloodsucker said: I was hoping for a less dramatic solution (a crash in betwen and you will never see that army again.
Store army before entering battle. Then delete army, only commander will go inside. After battle, check if hero alive then restore army. Crash or no crash, there is no risk.
____________
Era II mods and utilities
|
|
bloodsucker
Legendary Hero
|
posted September 02, 2015 08:00 PM |
|
|
Do you know any map with a script setting variables for seeds of objects? Many of my objects need that or player will be tempted to reload until he gets max values from every one of them.
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted September 02, 2015 08:09 PM |
|
|
I tend to avoid such things, specifically because the reload. However I use some random seeds in Atlantis and Tew4 too, my Atlantis Coliseum gets next monster type when the battle ends. So if the player wants another monster, he needs to replay last battle entirely then hope.
In general there is always a way for the player to cheat if he wants so.
____________
Era II mods and utilities
|
|
bloodsucker
Legendary Hero
|
posted September 03, 2015 02:59 PM |
|
|
I've created a bank called Mystique Utopia. It's not finnished, I still need to add some randomness and make it cicle but it as a problem I already faced and I remember we never found a solution.
What we did before was to revert to !!OB but there are advantages in using !!CB, namely it is how it as been traditionally done and if popular is just another line to add to the Wog scripts.
When the hero visits the bank it shows a message I didn't coded saying "You have found a (...). Do you want to attack the guards?" There as to be a table somewhere where (...) is automatically looked but it is probably filled with those multi-idioms strings, so my searches for "Lost Bottle" showed no usefull results. Do you have any idea of what is the name of this file or what was in fact used to add the banks names to the game?
--- Mystique Utopia
ZVSE
!?OB16/22;
!!HE-1:P?y1/?y2/?y3;
!!HE-1:N?y9;
!!VRy4:S1 R3;
!!CBy1/y2/y3&y4=1:G0/136/20 G1/150/5 G2/136/20 G3/150/5 G4/37/30 G5/37/30 G6/37/30;
!!CBy1/y2/y3&y4=2:G0/136/40 G1/150/10 G2/136/40 G3/150/10 G4/37/60 G5/37/60 G6/37/60;
!!CBy1/y2/y3&y4=3:G0/136/60 G1/150/15 G2/136/60 G3/150/15 G4/37/90 G5/37/90 G6/37/90;
!!CBy1/y2/y3&y4=4:G0/136/100 G1/150/25 G2/136/100 G3/150/25 G4/37/150 G5/37/150 G6/37/150;
!!HEy9:O/?y10;
!!FU&y10<0:E;
!!CBy1/y2/y3&y4=1:M150/2;
!!CBy1/y2/y3&y4=2:M150/3;
!!CBy1/y2/y3&y4=3:M150/4;
!!CBy1/y2/y3&y4=4:M150/6;
!!CBy1/y2/y3&y4=1:R0/10 R1/5 R2/10 R3/5 R4/5 R5/5 R6/10000;
!!CBy1/y2/y3&y4=2:R0/20 R1/10 R2/20 R3/10 R4/10 R5/10 R6/20000;
!!CBy1/y2/y3&y4=3:R0/30 R1/15 R2/30 R3/15 R4/15 R5/15 R6/30000;
!!CBy1/y2/y3&y4=4:R0/50 R1/25 R2/50 R3/25 R4/25 R5/25 R6/50000;
!!VRy5:S1 R6;
!!if&y4>1:;
!!CBy1/y2/y3&y5=1:A3/146; * gives 1 commander artifacts only above level 1
!!CBy1/y2/y3&y5=2:A3/147;
!!CBy1/y2/y3&y5=3:A3/148;
!!CBy1/y2/y3&y5=4:A3/149;
!!CBy1/y2/y3&y5=5:A3/154;
!!CBy1/y2/y3&y5=6:A3/151;
!!if&y4>2:; * 50% chance of giving a second commander
!!VRy5:S1 R7; artifact above level 2
!!VRy6:S0 R1;
!!CBy1/y2/y3&y6>0/y5=1:A3/146;
!!CBy1/y2/y3&y6>0/y5=2:A3/147;
!!CBy1/y2/y3&y6>0/y5=3:A3/148;
!!CBy1/y2/y3&y6>0/y5=4:A3/149;
!!CBy1/y2/y3&y6>0/y5=5:A3/154;
!!CBy1/y2/y3&y6>0/y5=6:A3/151;
!!CBy1/y2/y3&y6>0/y5=7:A3/155; Slava only above level 2
!!if&y4=4/y6=0:; * 25% chance of giving a 'mystique' relic
!!VRy5:S1 R3; only if didn't got 2 comander artifacts
!!VRy7:S0 R2;
!!CBy1/y2/y3&y7=2/y5=1:A3/132;
!!CBy1/y2/y3&y7=2/y5=2:A3/138;
!!CBy1/y2/y3&y7=2/y5=3:A3/139;
!!CBy1/y2/y3&y7=2/y5=4:A3/158;
!!if&y7<2:;
!!VRy5:S1 R7; * 1 commander artifact if no relics and no previous 2
!!CBy1/y2/y3&y5=1:A3/146; second commader artifact
!!CBy1/y2/y3&y5=2:A3/147;
!!CBy1/y2/y3&y5=3:A3/148;
!!CBy1/y2/y3&y5=4:A3/149;
!!CBy1/y2/y3&y5=5:A3/154;
!!CBy1/y2/y3&y5=6:A3/151;
!!CBy1/y2/y3&y5=7:A3/155;
!!en:;
!!en:;
!!CBy1/y2/y3&y4=4:A3/156; * add a banner if level 4
!!en:;
!!en:;
!!VRy8:S0 R1;
!!CBy1/y2/y3&y8=1:A3/156; * 50% chance of giving a banner at any level
----
Is there a way to say that a bank's battle is always fought in a certain terrain or do I have to custom !!BA, !!BG for this battle to achive that?
Obviously this site's battle should be in Magic Plains.
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted September 04, 2015 07:35 AM |
|
|
You must script it in BA trigger. Look at my battlefield mod to see how is done.
|
|
bloodsucker
Legendary Hero
|
posted September 04, 2015 09:46 AM |
|
|
@SalamandreAm I right to think that neither you in TEW IV nor neutral units script add any randomness to the respawn of banks? Do you know the reasons why? Cause I am starting to find some of my own...
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted September 04, 2015 10:14 AM |
|
|
You can't add any randomness which is not worked around by the autosave. But creature banks with random creatures and quantities are a nice idea, the only problem is that the player will get false message when checking who is inside.
|
|
bloodsucker
Legendary Hero
|
posted September 04, 2015 05:18 PM |
|
|
Salamandre said: the only problem is that the player will get false message when checking who is inside.
That 's something I can easily work around. One can give a message when attacking saying "you found a snowy bank, value of bank is (1-4). Do you want to attack the guards". I don't like too excessive information, specially about artifacts. Of course, this is when the seeds become important cause the base value as to atributed in the beginning of the game to each site and be the same until the site is visited. Maybe then it can get a different seed.
I think it should be something of this kind but I'm still missing some details, cause I still didn't manage for this part to work.
** Function to loop trough Mystique Utopias.
!?FU45323;
!!UN:U16/22/?v1; [Number of Mystique Utopias: v1]
!!DO45324/1/v1/1&v1>0:P; [Loop through all Mystique Utopias]
** Function to set value of Mystique Utopias
!?FU45324;
!!VRy4:S1 R3;
!!UN:U16/22/v1/962; [get x/y/l of yellow square of object into v962-v964]
!!POv962/v963/v964:Ny4;
!!SN:W^Mystique_Utopia_%V962_%V963_%V964_Value^/?y4
and I'm confused about a not so small detail, should this code be under a !?PI; or a !?TM2&$day$=1/$once$=1; ?
BTW, I asked it before but "Do you know where I can find some extra information about !!CB ?" The help stops exactly where my problems start. One that I found already is artifacts can't be given with !!CBxyl:A3/x;. The first object seams right but the second gets the data all mixed up and I think it is because the "add to the end of the list" doesn't like when you add first artifact to a list that was somehow already opened.
|
|
Salamandre
Admirable
Omnipresent Hero
Wog refugee
|
posted September 04, 2015 05:39 PM |
|
|
This is how I learned erm, I played all maps done with then opened scripts and compared to my gameplay so I could understand what is going. If you are gonna ask for every feature which has already been used 1 billion times, life will be too short:
Map advanced infos mod, Utopia/crypts artifacts list (up to 4)
!!if|y83=25/y83=84; utopia or crypt
!!TRy80/y81/y82:E?y89; check for yellow trigger
!!FU&y89>0:E;
!!CBy80/y81/y82:T?y86; check if taken
!!FU&y86>0:E;
!!VRv2:C-1/-1/-1/-1/-1/-1/-1/-1/-1/-1/-1/-1/-1;
!!if&y83=84:; crypt
!!DO641641146/0/4/1:Py80/y81/y82/2/3;
!!CBy80/y81/y82:A2/0/?y91; get artifact
!!IF&y91>0:N8/y91/v2/v3/v4/v5/v6/v7/v8/v9/v10/v11;
!!IF&y91<1:Nv2/v3/v4/v5/v6/v7/v8/v9/v10/v11;
!!IF:N^^;
!!en:;
!!if&y83=25:; dragon utopia
!!DO641641146/0/3/1:Py80/y81/y82/2/3;
!!CBy80/y81/y82:A2/0/?y91 A2/1/?y92 A2/2/?y93 A2/3/?y94; get artifacts list
!!IF:N8/y91/8/y92/8/y93/8/y94/v2/v3/v4/v5/v6/v7/v8/v9;
!!IF:N^{~Chartreuse}DRAGON UTOPIA{~}^;
!!en:;
!?FU641641146;
!!CBx1/x2/x3:Gx16/?y86/?y87;
!!FU&y86<0:E; exit if no creature
!!VRvx4&y86>-1:S21;
!!VRvx5:Sy87*65536+y86; get picture for number
!!VRx4:+2; !!VRx5:+2;
____________
Era II mods and utilities
|
|
|