Heroes of Might and Magic Community
visiting hero! Register | Today's Posts | Games | Search! | FAQ/Rules | AvatarList | MemberList | Profile


Age of Heroes Headlines:  
5 Oct 2016: Heroes VII development comes to an end.. - read more
6 Aug 2016: Troubled Heroes VII Expansion Release - read more
26 Apr 2016: Heroes VII XPack - Trial by Fire - Coming out in June! - read more
17 Apr 2016: Global Alternative Creatures MOD for H7 after 1.8 Patch! - read more
7 Mar 2016: Romero launches a Piano Sonata Album Kickstarter! - read more
19 Feb 2016: Heroes 5.5 RC6, Heroes VII patch 1.7 are out! - read more
13 Jan 2016: Horn of the Abyss 1.4 Available for Download! - read more
17 Dec 2015: Heroes 5.5 update, 1.6 out for H7 - read more
23 Nov 2015: H7 1.4 & 1.5 patches Released - read more
31 Oct 2015: First H7 patches are out, End of DoC development - read more
5 Oct 2016: Heroes VII development comes to an end.. - read more
[X] Remove Ads
LOGIN:     Username:     Password:         [ Register ]
HOMM1: info forum | HOMM2: info forum | HOMM3: info mods forum | HOMM4: info CTG forum | HOMM5: info mods forum | MMH6: wiki forum | MMH7: wiki forum
Heroes Community > Heroes 3.5 - WoG and Beyond > Thread: ERM help and discussion
Thread: ERM help and discussion This Popular Thread is 407 pages long: 1 50 100 150 200 ... 227 228 229 230 231 ... 250 300 350 400 407 · «PREV / NEXT»
Sal
Sal


Famous Hero
posted September 28, 2014 03:38 PM

!?BA0;
!!BA:H0/?y1 H1/?y2; [y1/y2 = attacker/defender ID]

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Siegfried
Siegfried


Famous Hero
posted September 29, 2014 06:11 AM

Thanks!

____________

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Hero_Of_Light
Hero_Of_Light


Responsible
Supreme Hero
posted September 29, 2014 03:49 PM

this is not really ERM related but I thought I'd ask here.

I've been thinking on adding the Heroes Chronicles intros into WoG, replacing the azvid000.smk files with the original Tarnum campaign intros. In some cases it worked, but in other less so.

Apparently some of the HC intros were made into different languages and so the sound of english, german etc narrator are all played together.

I downloaded Bink Video and edited them successfully but no matter what coding I try the video isn't playable in the game.

Does anyone know how to edit the videos using RAD video tools? Or else, can anyone extract the english language smk intros of:

Warlords of the Wasteland
Conquest of the Underworld
Revolt of the Beastmasters
The Sword of Frost

and send them to me somehow? Although I really would like to know how to use RAD tools so that I can add another video myself.
____________
Not idly do the leaves of Lorien fall.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Sal
Sal


Famous Hero
posted September 29, 2014 09:56 PM

if you browse Era\Tools\RSBinkPlayer, you will find a readme file where Grayface email is provided. He made the tools for reading bik/smk, so he is the only one who can help.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Siegfried
Siegfried


Famous Hero
posted October 01, 2014 09:13 AM

Hi,

is it possible to _check_ a creatures upgrade? I know there is a command to set it, but i want to check it. So for given creature check if creature has an upgrade and if so, what.
____________

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted October 01, 2014 10:34 AM
Edited by Salamandre at 11:02, 01 Oct 2014.

Conflux creatures ID are a mess so they must be scripted separately. You can do this:

!!VRy1:S0R130;             [random monster until firebird ID]
!!MA:Oy1/?y2 Ly1/?y3;     [get monster's faction (y2) and level (y3)]
!!FU&y2<0:E;              [exit if neutral]
!!if&y1<112:;             [if before conflux]
!!VRy4:Sy1%2;             [check if monster ID is multiple of 2]
!!FU&y4<>0:E;             [already upgraded, exit]
!!UN:Ty2/y3/1/?y4;        [y4 stores the upgrade]
!!en:;
 !!if&y1>111:;
 [...manually check every conflux monster...screwed ID's]
 !!en:;

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Siegfried
Siegfried


Famous Hero
posted October 01, 2014 05:44 PM
Edited by Siegfried at 19:20, 01 Oct 2014.

Thanks.

I already know this. But this has flaws. It is possible with erm to add new upgrades (f.ex. Monk - Zealot - War Zealot). With your method it would not be possible to check if the war zealot is an upgrade somehow to the monk. I would just be able to find the default upgrade.

So f.ex. this:

!!MA:U9/169;

Would _set_ the war zealot as an upgrade to the zealot. I would think of something like:

!!MA:U9/?y1;

to check if there is an upgrade to the zealot, and if yes, which one. Since upgrades are configurable completely with erm, the static method would not work

Well, i'll do some tests. I just thought somebody already knows this.

Update:
Well, it seems as long as the default update is used, the result of !!MA:U.../?... is -1, and then i can apply something like your code. If there is a non-default upgrade, then this construct gives the number of the upgraded creature. So i will just first try this, and in case the result is >= 0 use it. If it is -1, then i use the default checking, and if it is -2, then there is no upgrade.
____________

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted October 01, 2014 06:40 PM

The "set" command is not configured to work with "check" and there is none actually doing that.

But if you work into custom mod and proceed custom upgrades, store on day 1 all your upgrades in SN:W vars.

!?PI;
[store normal creatures first, then:]
;example custom upgrade monk to zealot
!!MA:U9/169;
!!SN:W^custom_9^/169;


Then in loop:
!!DO12345/0/196/1:P;
!?FU12345;
!!SN:W^custom_%X16^/?y1;
!!IF&x16=9:M^%Y1^; you will get y1=169 when check monk ID

This is the only way, and without using any global var.
____________
Era II mods and utilities

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Siegfried
Siegfried


Famous Hero
posted October 01, 2014 08:09 PM
Edited by Siegfried at 20:10, 01 Oct 2014.

So for now i'm using this code:

** Check if stack x1 is upgraded version of stack x2
!?FU%IsUpgraded%;
!!IF:V1/0;                ** Preset to false
!!FU&x1<0:E;                ** Invalid
!!FU&x2<0:E;                            ** Invalid
** Check configured update
!!MA:Ux2/?y1;                ** Get upgrade
!!FU&y1=-2:E;                           ** There is no upgrade
!!IF&y1=x1:V1/1;                        ** If found, set true
!!FU&y1=x1:E;                           ** ... and exit
** If not found, check why
** Maybe it's a default upgrade?
!!if&y1=-1:;                            ** -1 -> default upgrade
       !!if&y1<%Chaos Hydra%:;
               !!VRy2:Sx1&1;
               !!if&y2=x2:;            ** If stack x2 is not upgraded
                       !!VRy2:|=1;     ** Upgrade
                       !!IF&y2=x1:V1:1;** If found, set true
                       !!FU&y2=x1:E;   ** ... and exit
               !!el:;                  ** If x2 is already upgraded:
                       !!FU:E;         ** exit
               !!en:;
       !!el:;                          ** If this is some "strange" stack
               !!if&x2=%Air Elemental%/x1=%Storm Elemental%:;
                       !!IF:V1/1;
                       !!FU:E;
               !!en:;
               ** TODO: other special creatures
       !!en:;
!!en:;

I still have to add the recursive part for checking if f.ex. the War Zealot is (somehow) an upgraded version of the Monk (which should give true). This should be included in case there is a configured upgrade. It is not necessary for the default updates.

Note: I use a sed script to replace those %whatever% to numbers from the format list
____________

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Hero_Of_Light
Hero_Of_Light


Responsible
Supreme Hero
posted October 03, 2014 12:28 AM

@Salamadre

Can you help me with the script you made for my mod about the artifacts?
I want to completely remove the Magic Mirror bonus given by artifacts 157 and 163 because I think it's too much of a bonus. I deleted some lines but artifact 163 still gives magic mirror. Can you remove this effect? Here is your script.

***New artifacts

**scepter of Power

***Heroes Summoning script

;vars used: v110-v113, v444-v445, v8001-v8018, v9711-v9712, FU100, FU333-337, flags 50, 200-202, 411,
;w85-86

!#UN:P900/?v561; [Check if Stack Experience is enabled: v296]
!#UN&v561=0:P906/1; [Disable gaining of Stack Experience from battles if Stack Experience is disabled]

!?BA0&1000;
!!UN:P900/1; [Enable Stack Experience]
!!IF:V202/0; cast twice flag
!!VRv8011:C-1/-1/-1/-1/-1/-1/-1/-1;
; Sceptre of power
!!BA:H0/?v9711 H1/?v9712;
;art 163
!!HEv9711:A2/163/d/?y6;  [check for artifact]
!!HEv9712&v9712>-1:A2/163/d/?y8;  [check for artifact]
!!VRv8013&y6>0:S0;
!!VRv8014&y8>0/v9712>-1:S0;
;art 164, gives expert haste
!!HEv9711:A2/164/d/?y7;  [check for artifact]
!!HEv9712&v9712>-1:A2/164/d/?y9;  [check for artifact]
!!VRv8015&y7>0:S0;
!!VRv8016&y9>0/v9712>-1:S0;
;crimson shield
**!!HEv9711:A2/157/d/?y1;
**!!HEv9712&v9712>-1:A2/157/d/?y2;
**!!VRv8011&y1>0:S0;
**!!VRv8012&y2>0/v9712>-1:S0;
;summon creatures
!!IF|v9711=146/v9712=146:V411/1; activate special BF if one of heroes in
;cast twice
!!HEv9711:A2/170/d/?y2;
!!HEv9712&v9712>=0:A2/170/d/?y4;
!!IF|y2>0/y4>0:V202/1;
!!VRv444&y2=1:S0;  set the side which will cast twice
!!VRv444&y4=1:S1;
!!IF:V200/1 V201/0;
!!HEv9711:A2/162/d/?y2;  [check for artifact]
!!HEv9712&v9712>-1:A2/162/d/?y4;  [check for artifact]
;art 162, use w85
!!if&y2>0:; If attacker has it
!!IF:Wv9711;
!!VRw85:S99;
!!FU333:Pv9711;
!!en:;
!!if&y4>0/v9712>-1:; if defender has it
!!IF:Wv9712;
!!VRw85:S99;
!!FU333:Pv9712;
!!en:;
;art 161, does the opposite
!!HEv9711:A2/161/d/?y3;  [check for artifact]
!!HEv9712&v9712>-1:A2/161/d/?y5;  [check for artifact]
;Art 161, use w86
!!if&y3>0:; If attacker has it
!!IF:Wv9711;
!!VRw86:S99;
!!FU338:Pv9711;
!!en:;
!!if&y5>0/v9712>-1:; if defender has it
!!IF:Wv9712;
!!VRw86:S99;
!!FU338:Pv9712;
!!en:;
;sea creatures bonus
!!BA:P?y16/?y17/?y18;
!!TRy16/y17/y18:T?y19/d/d/d/d/d/d/d;
!!IF&y19=8:V50/1;

!?BF&1000;
;apply magic mirror if crimson shield on
**!!DO334/0/7/1&v8011=0:P;
**!!DO334/0/7/1&v8013=0:P;
**!!DO334/21/28/1&v8012=0:P;
**!!DO334/21/28/1&v8014=0:P;
;art 163
!!DO336/21/28/1&v8013=0:P;
!!DO336/0/7/1&v8014=0:P;
;art 164, haste
!!DO337/0/7/1&v8015=0:P;
!!DO337/21/28/1&v8016=0:P;

***!?FU334; *magic mirror 999 turns, expert level
***!!BMx16:M36/999/3;

!?FU336; *stone gaze(?) 3 turn, expert level
!!BMx16:M70/3/3;

!?FU337; *expert haste 999 turns, expert level
!!BMx16:M53/999/3;

!?FU333; change SP/KN in ATT/DEF  art ID=162, w85 used
;x1=Hero ID
!!HEx1:F?v110/?v111/?v112/?v113; Get stats
!!HEx1:I?v8018;
!!VRv114:Cv110/v111/v112/v113;
!!VRv110:+v112;
!!VRv111:+v113;
!!VRv112:-v112;
!!VRv113:-v113;
!!HEx1:Fv110/v111/v112/v113;

!?FU338; change ATT/DEF in SP/KN art ID=161, w86 used
;x1=Hero ID
!!HEx1:F?v110/?v111/?v112/?v113; Get stats
!!HEx1:S24/?y1; get if intelligence
!!VRv8019:Sv111*10;
!!VRv8019&y1=1:*5:4; %25
!!VRv8019&y1=2:*3:2;  %50
!!VRv8019&y1=3:*2;   %100
!!HEx1:Idv8019;
!!VRv114:Cv110/v111/v112/v113;
!!VRv112:+v110;
!!VRv113:+v111;
!!VRv110:-v110;
!!VRv111:-v111;
!!HEx1:Fv110/v111/v112/v113;

!?BG1&1000;
!!BU:C?y1; *check if battle ended this turn
!!FU&y1=0:E;
;art 162
!!IF:Wv9711; read hero w vars
!!HEv9711&w85=99:Fv114/v115/v116/v117; reset stats as before battle
!!HEv9711&w85=99:Iv8018;
!!VRw85:S0;
!!IF&v9712>-1:Wv9712;
!!HEv9712&v9712>-1/w85=99:Fv114/v115/v116/v117; reset stats as before battle
!!HEv9712&v9712>-1/w85=99:Iv8018;
!!VRw85:S0;  *DONE

;ART 161
!!IF:Wv9711; read hero w vars
!!HEv9711&w86=99:Fv114/v115/v116/v117; reset stats as before battle
!!VRv8019&w86=99:*-1;
!!HEv9711&w86=99:Idv8019;
!!VRw86:S0;
!!IF&v9712>-1:Wv9712;
!!HEv9712&w86=99/v9712>-1:Fv114/v115/v116/v117; reset stats as before battle
!!VRv8019&w86=99:*-1;
!!HEv9712&w86=99/v9712>-1:Idv8019;
!!VRw86:S0;

!?BF&1000/411;
!!VRv8001:C-1/-1/-1/-1/-1/-1/-1/-1/-1;
;Catherine: quantity of summoned creatures = to her level
!!if|v9711=146/v9712=146:;
!!VRy1:S164 R3; [Random War Machine]
!!HE146:Ed/?y2;
!!VRy2&y1=164:Sy2:2; If Cannon/2
!!VRy2&y1=167:Sy2:2; If Craneq/2
!!VRv8001&v9711=146:S0; Attacker
!!VRv8001&v9712=146:S1;  Defender
!!BU&v8001=0:Sy1/y2/38/v8001/-1/1; [Summon creatures]
!!BU&v8001=1:Sy1/y2/46/v8001/-1/1; [Summon creatures]
!!en:;
!!IF:V411/0; disable

;sea bonus
!?BR&50/1000;
!!DO100/0/41/1:P;
!!IF:V50/0;

!?FU100;
!!BMx16:T?y1;
!!FU&y1<>123/y1<>129/y1<>170/y1<>171:E; exit if not water creatures
!!BMx16:Sd1; increase speed by 1

;cast twice
!?BG0&1000/202;
!!BG:A?v445;
!!FU&v445<>1:E;
!!BG:Q?v445; **added check for side
!!FU&v445<>v444:E;
!!IF&200:V201/1;
!!IF:V200/0;

!?BR&1000/202;
!!IF:V200/1;

!?BG1&1000/201/202;
!!BHv444:M0;  side=v444
!!IF:V201/0;

;artefacts giving skills
;165, gives expert luck
!?AE1&v998=165;
!!HE-1:S9/?y1;
!!IF:W-1;
!!VRw5:Sy1;
!!HE-1:S9/3;

!?AE0&v998=165; shield unequip
!!IF:W-1;
!!HE-1:S9/w5;

;166, gives expert Logistics
!?AE1&v998=166;
!!HE-1:S0/?y1;
!!IF:W-1;
!!VRw9:Sy1;
!!HE-1:S0/3;
!!HE-1:S2/?y2;
!!IF:W-1;
!!VRw8:Sy2;
!!HE-1:S2/3;

!?AE0&v998=166; unequip
!!IF:W-1;
!!HE-1:S0/w9;
!!IF:W-1;
!!HE-1:S2/w8;

;167, gives  expert leadership
!?AE1&v998=167;
!!HE-1:S6/?y1;
!!IF:W-1;
!!VRw6:Sy1;
!!HE-1:S6/3;

!?AE0&v998=167;
!!IF:W-1;
!!HE-1:S6/w6;

;168, gives  expert estates
!?AE1&v998=168;
!!HE-1:S13/?y1;
!!IF:W-1;
!!VRw7:Sy1;
!!HE-1:S13/3;

!?AE0&v998=168;
!!IF:W-1;
!!HE-1:S13/w7;

;169, gives to beastmasters and witches +6 to all primary skills
;class 14-15
!?AE1&v998=169;
!!HE-1:B2/?y1;
!!HE-1|y1=14/y1=15:Fd10/d10/d10/d10;

!?AE0&v998=169;
!!HE-1:B2/?y1;
!!HE-1|y1=14/y1=15:Fd-10/d-10/d-10/d-10;

;163, gives +6 to all primary skills
!?AE1&v998=163;
!!HE-1:Fd6/d6/d6/d6;

!?AE0&v998=163;
!!HE-1:Fd-6/d-6/d-6/d-6;

!?CM2;
!!CM:I?y1;
!!FU&y1>67/y1<75:E;
!!UN:R3/-1; Redraw Hero Screen

[End of Battle]
!?BA1;
!!UN:P900/v561; [Restore Stack Experience status]
____________
Not idly do the leaves of Lorien fall.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted October 03, 2014 06:27 AM
Edited by Salamandre at 06:29, 03 Oct 2014.

If you want to delete them, you need to cut the receiver or trigger code, adding ** in front will change nothing.

So all lines where you added **/***, disable them by replacing ! with * or simply delete the line.

example:

!?BF&1000;
;apply magic mirror if crimson shield on
**!!DO334/0/7/1&v8011=0:P;   [this will still work, you only added **, changes nothing, ** will be ignored by erm]

!?BF&1000;
;apply magic mirror if crimson shield on
**DO334/0/7/1&v8011=0:P; [this will be disabled, replaced !! receiver code with **, erm will ignore the whole line now]

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
bloodsucker
bloodsucker


Legendary Hero
posted October 03, 2014 10:55 AM

Please don't ban me for asking this but, in a poor attempt to write an Hello World I wrote this lines I basicly copied from TEW III

ZVSE
!!HE109:F6/4/4/5;
!#HE109:C0/0/136/16 C0/1/37/20 C0/2/37/20 C0/3/150/5 C0/4/37/20 C0/5/37/20 C0/6/136/16;
!#HE109:S0/1 S2/3 S7/2 S11/1 S15/1  S16/1 S17/3 S18/1 S19/1 S21/3 S22/3 S23/2;
!#HE109:A1/98/8 A1/70/6 A1/58/1 A1/64/9 A1/125/10 A1/19/149 A1/20/151 A1/21/146 A1/22/148 A1/23/154 A1/24/147;

I don't get any error messages but nothing happens.
I was also trying to gave him a brute for commander with this line but I have the same problem...

!#CO109:T5;
!#CO1090/1 P1/1 P2/1 P3/1 P4/1 P5/1;

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Hero_Of_Light
Hero_Of_Light


Responsible
Supreme Hero
posted October 03, 2014 12:09 PM

@Salamandre

Thanks it worked!

Do you think you can oblige me with some extra help? It's not that important but I think it would be a nice addition.

You see, since I started working on Tarnum campaigns I came up with the idea to replace the Shield of Ancient Medusa with the Sword of Frost (leaving the same effect and having the sword "freeze" all opponents).

I thought it would be a nice touch to add a few lines on the script above and have this check:

If one of the heroes in combat (either attacking or defending) has the Armaggedon's Blade and the other has the Sword of Frost (art 163) then both heroes are defeated at the start of the battle. Do you think that this is possible?
____________
Not idly do the leaves of Lorien fall.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted October 03, 2014 03:44 PM
Edited by Salamandre at 15:57, 03 Oct 2014.

bloodsucker
Make sure the hero you want to modify isn't already customized in editor, because then it will be ignored. Then add your codes as receivers under PI trigger

ZVSE

!?PI;
!!HE109:F6/4/4/5;
!!
!!
!!
and so on, same for commander. Not !#, only !!.


HoL, do I read right what you want? If both artifacts are in battle on the two heroes, each hero dies and both armies are lost?

You do realize how flawed will be this option, as human player will have only to send a hero with 1 pikeman, but equipped with AB artifact, against strong AI, then rehire hero in tavern, while AI lost all army.
____________
Era II mods and utilities

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
bloodsucker
bloodsucker


Legendary Hero
posted October 03, 2014 04:03 PM

Thanks, Sal.
Good to see u using ur old alias.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Hero_Of_Light
Hero_Of_Light


Responsible
Supreme Hero
posted October 03, 2014 04:35 PM

Well, since the Sword of Frost I made is art 163 (which was a blank wog artifact) it will not actually show in random maps and will only be available on custom maps.

Furthermore, I say defeat both heroes and not retreat. Armageddon's Blade will be lost and even If an insignificant hero makes the sacrifice, still this very powerful artifact will be lost. Let alone the fact that you'll need to know that opponent has the Sword of Frost equipped before you sent your hero to the slaughter so it is actually a really long shot.

As I said, it's not that crucial to the game. I just thought it would be a nice touch, since in heroes lore, Armageddon and Frost combine will bring great disaster
____________
Not idly do the leaves of Lorien fall.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted October 03, 2014 04:46 PM

I don't know a sure way to defeat a hero so he doesn't show anymore in tavern. I saw many people claiming erm can remove one hero from taverns pool, but there is always some bug which will enable them, sooner or later.

So I will make a script like that: if heroes left/right have the two artifacts equipped, artifacts will clash each other and will be destroyed in fight (remove both artifacts). Then armageddon animation due to this magical disaster and battle is over, both heroes die (you will still find them in tavern but without artifacts).

Then you manually choose from script what to keep or not.
____________
Era II mods and utilities

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted October 03, 2014 06:34 PM
Edited by Salamandre at 18:38, 03 Oct 2014.

ZVSE

;script for HoL
;if fighting heroes have Armageddon blade and sword 162 equipped, everyone gets smashed
!?BA0&1000; battle start
!!SN:W^HoL_disaster^/0;  initialize clash
!!BA:H0/?y11 H1/?y12;    check heroes ID
!!HEy11:A2/128/?y1/?y2 A2/162/?y3/?y4;
!!HEy12&y12>-1:A2/128/?y5/?y6 A2/162/?y7/?y8;  check if they have artifacts 128/162
!!VRy9|y2=1/y4=1:S99;
!!VRy10|y6=1/y8=1:S99;
!!SN&y9=99/y10=99:W^HoL_disaster^/99;  create condition
!!SN&y9=99/y10=99:W^HoL_lefthero^/y11;   store attacker/defender ID
!!SN&y9=99/y10=99:W^HoL_righthero^/y12;


!?BG0&1000; action start
!!SN:W^HoL_disaster^/?y1;
!!FU&y1<99:E;
!!BG:A0;  disable battle stack action
!!IF:Q1/8/128/8/162/1^text describing the artifacts clash (your custom message)^;
!!SN:W^HoL_lefthero^/?y11;  get heroes ID
!!SN:W^HoL_righthero^/?y12;
!!HEy11:A2/128/?y1/?y2 A2/162/?y3/?y4;
!!HEy11&y2>0:A3/128/1/1;
!!HEy11&y4>0:A3/162/1/1;
!!HEy12:A2/128/?y1/?y2 A2/162/?y3/?y4;
!!HEy12&y2>0:A3/128/1/1;
!!HEy12&y4>0:A3/162/1/1;  remove artifacts
!!DO229999/0/41/1:P; kill all creatures
!!BU:R;    redraw battlefield
!!HEy11:K;  kill both heroes
!!HEy12:K;

!?BA1&1000; after battle
!!SN:W^HoL_disaster^/?y1;
!!FU&y1<99:E;
!!SN:W^HoL_lefthero^/?y11;
!!SN:W^HoL_righthero^/?y12;
!!HEy11:B0/?z1;  get both heroes names for further message
!!HEy12:B0/?z2;
!!IF:Q1/8/128/8/162/1^Both %Z1 and %Z2 died in combat, and artifacts are lost (your custom message).^;

!?FU229999;
!!BMx16:H?y1; check stack HP
!!BMx16&y1>0:P?y2;
!!BMx16&y1>0:C14/y2/3/3/1;  cast earthquake  (play with values until your get visually what you like)
!!BMx16&y1>0:V38;  create sparks animation
!!BMx16&y1>0:N0 K1;  kill stack
____________
Era II mods and utilities

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Hero_Of_Light
Hero_Of_Light


Responsible
Supreme Hero
posted October 03, 2014 08:43 PM

It seemed OK at first but there are some problems (along with the older artifact script).

I edited the script like this (artifact was actually 163 and not 162 and I made it cast Armageddon instead of Earthquake). The thing is that when attacker has Armageddon's blade then it seems to work OK. But when the defender has Armageddon then the attacker has a first move. It isn't actually going to move though. There are some other problems in animation, for instance if a hero has a creature immune to armageddon then it is cast twice and the creature dies after the animation. It doesn't really feel right.

It gets even worse with Tactics. If opponent has the Sword of Frost then your armies can't really move and the game can't continue as it waits for you to move your creatures and you can't. This is a bug from the previous script.

I have some suggestions:

1st) How about making it simpler... If Armageddon's Blade and Sword of Frost is present, show text, have both Heroes retreat and the swords destroyed.

2nd) Add a check on artifact 163 function of the previous post for tactics. If attacker or defender has tactics make the effect (petrify) start from round two.
____________
Not idly do the leaves of Lorien fall.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
bloodsucker
bloodsucker


Legendary Hero
posted October 03, 2014 10:22 PM

Well, first Hello Wolrd works.

**Gundula start army, skills and artefacts
ZVSE
!?PI;
!!HE109:F6/4/4/5;
!!HE109:C0/0/136/12/15000/2 C0/1/37/16/15000/2 C0/2/37/16/15000/2 C0/3/150/5/15000/2 C0/4/37/16/15000/2 C0/5/37/16/15000/2 C0/6/136/12/15000/2;
!!HE109:S0/1 S2/3 S7/2 S11/1 S15/1 S16/1 S17/3 S18/1 S19/1 S21/3 S22/3 S23/2;
!!HE109:A1/98/8 A1/70/6 A1/58/1 A1/64/9 A1/125/10 A1/126/11 A1/96/20 A1/156/21 A1/156/22 A1/156/23 A1/156/24 A1/156/25 A1/156/26 A1/156/27 A1/140/28;
!!HE109:Id90;
!!HE109:W15000;

****
Now, for second Hello World I was trying to create an object that gives all 6 basic skills at basic level and six commander artifacts...

ZVSE

!?OB63/28;

!!CO-1:S0/+1 S1/+1 S2/+1 S3/+1 S4/+1 S5/+1;
!!HE-1:A4/146 A4/147 A4/148 A4/149 A4/151 A4/154 A4/155;

This also works but has a bunch of funtional problems:
1. I remember it was easy to set a string with the name of the object but now all Wog scripts use strings for international compatiblity and I don't understand what their doing.

2. It gives the basic skills to a commander who has none but will decrease to basic the skills of a commander who has some on advanced or above. (It's ok for me to use on my own but impossible to publish any map)

3. In fact it GIVES a bunch of high level artifacts over and over again. Can AND WILL BE used to upgrade heroes and craft for prims...
It has good if I could set it to visit but I didn't understood how is done nor in the "ALms House" nor in the "Battle Academy" or the "Emerald Tower".

P.S. These are ERM doubts but they are also extremely basic, should I post them somewhere else?

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Jump To: « Prev Thread . . . Next Thread » This Popular Thread is 407 pages long: 1 50 100 150 200 ... 227 228 229 230 231 ... 250 300 350 400 407 · «PREV / NEXT»
Post New Poll    Post New Topic    Post New Reply

Page compiled in 0.4024 seconds