Heroes of Might and Magic Community
visiting hero! Register | Today's Posts | Games | Search! | FAQ/Rules | AvatarList | MemberList | Profile


Age of Heroes Headlines:  
5 Oct 2016: Heroes VII development comes to an end.. - read more
6 Aug 2016: Troubled Heroes VII Expansion Release - read more
26 Apr 2016: Heroes VII XPack - Trial by Fire - Coming out in June! - read more
17 Apr 2016: Global Alternative Creatures MOD for H7 after 1.8 Patch! - read more
7 Mar 2016: Romero launches a Piano Sonata Album Kickstarter! - read more
19 Feb 2016: Heroes 5.5 RC6, Heroes VII patch 1.7 are out! - read more
13 Jan 2016: Horn of the Abyss 1.4 Available for Download! - read more
17 Dec 2015: Heroes 5.5 update, 1.6 out for H7 - read more
23 Nov 2015: H7 1.4 & 1.5 patches Released - read more
31 Oct 2015: First H7 patches are out, End of DoC development - read more
5 Oct 2016: Heroes VII development comes to an end.. - read more
[X] Remove Ads
LOGIN:     Username:     Password:         [ Register ]
HOMM1: info forum | HOMM2: info forum | HOMM3: info mods forum | HOMM4: info CTG forum | HOMM5: info mods forum | MMH6: wiki forum | MMH7: wiki forum
Heroes Community > Heroes 3.5 - WoG and Beyond > Thread: ERM help and discussion
Thread: ERM help and discussion This Popular Thread is 407 pages long: 1 50 100 150 200 ... 245 246 247 248 249 ... 250 300 350 400 407 · «PREV / NEXT»
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted November 11, 2014 09:39 PM
Edited by Salamandre at 21:42, 11 Nov 2014.

I know where is the error with air elementals, the script checks for their ID but later I let them in without check, as it looked to me pointless to allow their upgrade to storms when altair of air is build (which is its primary role).

Change this line:
!!if&y5>112/y5<116:;

To:
!!if&y5>111/y5<116:;

Thats all.
____________
Era II mods and utilities

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Hero_of_Light
Hero_of_Light


Responsible
Supreme Hero
posted November 11, 2014 09:55 PM

I think it worked! Thanks again for your efforts, it was really important for me
____________
Not idly do the leaves of Lorien fall.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
bloodsucker
bloodsucker


Legendary Hero
posted November 12, 2014 12:23 AM
Edited by bloodsucker at 20:25, 12 Nov 2014.

What do you think of this trick?

From "Stack Experience Bonus".txt

Cast Expert/Mass version of Spell Before Attack (p) <112>...
Almost all combat spells are available for this ability including spells such as Quicksand and Fire Wall and the Elemental Summoning spells. Friendly enchantments (e.g., Shield) will be cast as a Mass Shield on all friendly troops each time this unit attacks an enemy but if the spell has no mass version (e.g., Anti-Magic, Magic Mirror, Fire Shield) it will be cast on the enemy target stack instead.

So if I set this:

******* Needs More Test
!!EA150:B12/1/112/56/0/0/0/0/0/0/100/100/100/100/100;  Frenzy Enemy BEFORE Attack
*******
!!EA150:B13/1/75/59/0/0/0/0/0/0/100/100/100/100/100; Berserk Enemy AFTER Attack

in a creaure with no retaliation like the SAs, what to you think will happen?

Note that both spells are level 4, mind and Fire and set to happen with 100% probability after the same level so if creature can get Frenzy it will also get Berserk.
I'm Ba ba ba BAD!!!

P.S. Ops, I forgot to add this other very important lines...

!!EA150:B8/1/102/99/0/0/0/0/0/1/1/1/1/1/1;  Champion Hability
!!EA150:B9/1/102/98/0/0/0/0/0/1/1/1/1/1/1;  Attack & Return

P.S. TESTED. It's a PITA, you came from the other side of the battlefiled, with Champion giving at least 50% more damage and target has his deffense reduced to 0 (YES!!! ZERO), then your troop returns to his place (so he can Charge again next time) and the target spends his turn attacking one of his fellow with increased attack and recieves retaliation with (again, all together) ZERO! deffense. Next turn Frenzy is gone so even if you target something else enemy can't profit from it.
I may be a cheater but I am a Master Cheater.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
mister_kalu
mister_kalu


Known Hero
posted November 13, 2014 02:38 AM

Salamandre, i have tried for many ways to get the coordinates of the current hero(OW:A) but UN:U it doesn't work, the mix of PO, OB. CM and HE are ok but with some errors. do you have one method more fast and easily?

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted November 13, 2014 02:44 AM

!!OW:A-1/?y1;
!!HEy1:P?y2/?y3/?y4;

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
mister_kalu
mister_kalu


Known Hero
posted November 13, 2014 04:01 AM
Edited by mister_kalu at 11:20, 13 Nov 2014.

i didn't saw that trick, thanks

!!SN:Ev5000/1/^1.def^/^2.def^;

this receiver works inside a battle ?, i mean in real time before or after some action,  i know it yes if the battle is over  

EDIT: only once per battle if the change is out of the first screen, for example one .def of spell

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
bloodsucker
bloodsucker


Legendary Hero
posted November 13, 2014 11:28 AM
Edited by bloodsucker at 12:45, 13 Nov 2014.

@Salamandre I'm not sure if you are aware of this but in TDS Palace of Dreams the shooting habilities cost an extra 50 of wood that isn't mentioned in the option tip and doesn't have any kind of control, what means wood values can become negative. When this happens and until you find a way of "pay the debt" you can't build, upgrade or buy units or any other activity that requires resources.
Here is the code:
!?FU20016;
!!VRz54:S^Ignore distance^;
!!VRz55:S^Ignore obstacles^;
!!VRz56:S^Proximal shooting^;
!!VRz57:S^exit^;
!!VRz58:S^Choose the special skills you want to Add or Remove:^;
!!IF:G1/7017/16/58/54/55/56/57;
!!EAv7015&v7017=1:Bv7016/1/105/61/0/0/0/0/0/1/1/1/1/1/1;
!!EAv7015&v7017=2:Bv7016/1/111/61/0/0/0/0/0/1/1/1/1/1/1;
!!EAv7015&v7017=4:Bv7016/1/102/115/0/0/0/0/0/1/1/1/1/1/1;
!!IF&v7017<8:M^Done!^;
!!OW&v7017<8:R0/0/d-50; here is the problem
!!FU20021&v7017<8:P;
-----------------------------------------
My propused solution is:
in function FU20014 add a tip to the ranged skills option
!!VRz32:S^Ranged Attack Skills - requires an extra 50 of wood each^;
and trade function FU20016 for this one
!?FU20016;
!!VRz54:S^Ignore distance^;
!!VRz55:S^Ignore obstacles^;
!!VRz56:S^Proximal shooting^;
!!VRz57:S^exit^;
!!VRz58:S^Choose the special skills you want to Add or Remove:^;
!!IF:G1/7017/16/58/54/55/56/57;
!!EAv7015&v7017=1:Bv7016/1/105/61/0/0/0/0/0/1/1/1/1/1/1;
!!EAv7015&v7017=2:Bv7016/1/111/61/0/0/0/0/0/1/1/1/1/1/1;�
!!EAv7015&v7017=4:Bv7016/1/102/115/0/0/0/0/0/1/1/1/1/1/1;
!!OW&v7017<8/y-1>=80:R-1/7/d-50; tests if you have 80 or more of wood - 50 for the hability plus 30 for the general visit, y-1 is the value
!!IF&v7017<8/y-1>=80:M^Done!^; y-1 is declared in the beginning of the routine, I'm not absolutely sure about the scope of temporary vars but I think is accessible here
!!FU20021&v7017<8/y-1>=80:P; FU20021 is the function to take the resources
!!IF&v7017<8/y-1<80:M^Not enough Wood!^;





 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted November 13, 2014 11:52 AM

bloodsucker said:

!!OW&v7017<8:R0/0/d-50; here is the problem


This line should be entirely removed, it is clearly an error.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
bloodsucker
bloodsucker


Legendary Hero
posted November 13, 2014 01:03 PM

Salamandre said:
bloodsucker said:

!!OW&v7017<8:R0/0/d-50; here is the problem


This line should be entirely removed, it is clearly an error.


That is the solution I've implemented in my mod "Palace of Dreams" since more then a year ago (when Artu told me how to create a mod) but I tought you would want to keep the extra cost, even if the reason for it eludes me.

This must be corrected in the links, so people don't continue downloading a bugged version and I don't know how and probably can't do it. Can you take care of it, please.

BTW, if I want to create one of those executables that install a mod what should I do? Where is this process explained?

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted November 13, 2014 01:40 PM

Is not about the extra cost, but the fact that the wood is removed from red player (OW:R0), no matter which player visits the palace. So basically costs nothing for the other 7 players.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
bloodsucker
bloodsucker


Legendary Hero
posted November 13, 2014 03:40 PM

Salamandre said:
Is not about the extra cost, but the fact that the wood is removed from red player (OW:R0), no matter which player visits the palace. So basically costs nothing for the other 7 players.


I saw that, then I didn't trust my observation... Please, can you at least tell me what to lookk for to make an executable of a mod? If I search for Executable or Mod in the pages I will have to read one hundread posts posts...

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted November 13, 2014 04:15 PM

Upload it when ready and I will make executable for you. There is no tutorial, search on net about creating sfx packages with winrar, is not biggy.
____________
Era II mods and utilities

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Mister_kalu
Mister_kalu


Known Hero
posted November 13, 2014 08:08 PM

Salamandre:

sorry for asking strange things but erm help doesn't have many examples and contents, i have read in the forum some comments about you and chinese guys, how do you know chinese language? it's more difficult than russian
now to the point, with the TL trigger could I redraw the screen?

do you know how to emulate the transition black screen? f.e when you enter into the town

and the last one, down arrow tower speed to the fastest of the right side stacks


 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
bloodsucker
bloodsucker


Legendary Hero
posted November 14, 2014 02:08 AM
Edited by bloodsucker at 09:51, 14 Nov 2014.

Salamandre said:
Upload it when ready and I will make executable for you. There is no tutorial, search on net about creating sfx packages with winrar, is not biggy.


Thank you for the tip. Sfx (self extracting files) was really the only information needed. Both my versions of WinRar and WinZip do it within a minute but I had no idea what to look for...

P.S.
In fact my PowerUps Tower processes the taking of resources even if player click on cancel.
I used !!FU:E; and I was expecting that would exit the entire script but is not how it happens

From Help
!!FUxxx:E; Exit the current function immediately
May be used without parameters, like !!FU:E;
You can use this command to avoid re-entering the function.

I'm tring to avoid the problem using this test in the beginning of my function
!?FU28714;
!!FU&v6112=>256|v6115=>512:E;

BUT if I am correct then this problem must be also present in the  code I've used for base (615 TDS - Palace of the Dreams) where function is called like this
Special Habilities
!!FU20021&v7014<2048/v7014<>8:P;

Shoothing Skills
!!FU20021&v7017<8:P;

Spells to cast after attacks
!!FU20021&v7823<2048:P;

etc...

And this is the function:
!?FU20021;
!!OW:R-1/0/d-30;
!!OW:R-1/1/d-30;
!!OW:R-1/2/d-30;
!!OW:R-1/3/d-30;
!!OW:R-1/4/d-30;
!!OW:R-1/5/d-30;
!!VRz457&499:S^Palace of Dreams (visited)^;
!!HT63/33:T457;
!!IF:V499/0;

Of course, if we are rich as Crassos (as we probably are when we finally have conditions to beat the Palace guardians) we don't notice this trivialities.



 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Siegfried
Siegfried


Famous Hero
posted November 14, 2014 01:07 PM


Hi,

Indeed, !!FU:E exits the function, but it does not exit the whole script. That may be a difference.

Constructions like:

!!FU&blabla|blah:E

are not exactly false. But better would be:

!!FU|blabla/blah:E

The '&' denotes "and", the '|' denotes "or", both followed by a list of expressions whith list elements separated by '/'.




____________

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
RerryR
RerryR


Promising
Supreme Hero
Researching Magic
posted November 14, 2014 01:59 PM

Hi,

i have a little question. is there a way to surpass the 4000 units limit in the editor? or a way to make neutrals grow beyond 4000 units with enough rounds played?
I guess its hardcoded otherwise i assume it would be possible already.
maybe you know some tricks how to handle it. i want to edit my map. the neutrals start with a zounds and shouldnt stop growing at 4000  

thanks

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
bloodsucker
bloodsucker


Legendary Hero
posted November 14, 2014 04:54 PM
Edited by bloodsucker at 16:58, 14 Nov 2014.

RerryR said:
or a way to make neutrals grow beyond 4000 units with enough rounds played?


1. It's hardcoded;

2. Woodmelon uses a trick to circunvent this in TDS - can you show us how it is done Sal?

-------------------
I think I've finally finnished the Power Ups Tower. It works quite nice but it only charges correctly if u choose the special options and until now I wasn't able to figure out why.
I'll put the code here (as promised) and within a few hours (I have to go now) I will try to correct this last problem and upload an executable somewhere.
---------------------------
ZVSE

!#UN&v1=1:B0/1; [Enable Mithril]

!?OB63/34&1000;
!!IF:M^At this power up you can increase your creatures basic stats by a modest fee in resources.^;

!!OW:R-1/0/?y-1;   Check for resources
!!OW:R-1/1/?y-2;
!!OW:R-1/2/?y-3;
!!OW:R-1/3/?y-4;
!!OW:R-1/4/?y-5;
!!OW:R-1/5/?y-6;
!!OW:R-1/7/?v6119;
!!VRz10|y-1<5/y-2<5/y-3<5/y-4<5/y-5<5/y-6<5:S^Not enough resources!^;
!!IF|y-1<5/y-2<3/y-3<5/y-4<3/y-5<3/y-6<3:D5/10;
!!IF|y-1<5/y-2<3/y-3<5/y-4<3/y-5<3/y-6<3:E1/5;
!!FU28712&y-1>=5/y-2>=3/y-3>=5/y-4>=3/y-5>=3/y-6>=3:P;

*****************
[Store unique creature numbers in v6360-v6366 (-1 equals no creature)]
[v1=number of unique creature numbers in hero's army]

!?FU28712;
!!VRv1:S0;
!!VRv6360:C-1/-1/-1/-1/-1/-1/-1; (-1 equals no creature)
!!VRz180:S^^;
!!VRz181:S^^;
!!VRz182:S^^;
!!VRz183:S^^;
!!VRz184:S^^;
!!VRz185:S^^;
!!VRz186:S^^;

!!HE-1:C0/0/?y1/?y2;   [Slot 0]
!!VRv1&y2>0:+1;
!!VRv6360&y2>0:Sy1;
!!UN&y2>0:N3/180/y1/1;

!!HE-1:C0/1/?y1/?y2;   [Slot 1]
!!VRy4:S0;
!!VRy4&v1=1/y1=v6360:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S6359 +v1;
!!VRy5&y2>0/y4<>99:S179 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;

!!HE-1:C0/2/?y1/?y2;   [Slot 2]
!!VRy4:S0;
!!VRy4&v1>=1/y1=v6360:S99;
!!VRy4&v1=2/y1=v6361:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S6359 +v1;
!!VRy5&y2>0/y4<>99:S179 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;

!!HE-1:C0/3/?y1/?y2;   [Slot 3]
!!VRy4:S0;
!!VRy4&v1>=1/y1=v6360:S99;
!!VRy4&v1>=2/y1=v6361:S99;
!!VRy4&v1=3/y1=v6362:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S6359 +v1;
!!VRy5&y2>0/y4<>99:S179 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;

!!HE-1:C0/4/?y1/?y2;   [Slot 4]
!!VRy4:S0;
!!VRy4&v1>=1/y1=v6360:S99;
!!VRy4&v1>=2/y1=v6361:S99;
!!VRy4&v1>=3/y1=v6362:S99;
!!VRy4&v1=4/y1=v6363:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S6359 +v1;
!!VRy5&y2>0/y4<>99:S179 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;

!!HE-1:C0/5/?y1/?y2;   [Slot 5]
!!VRy4:S0;
!!VRy4&v1>=1/y1=v6360:S99;
!!VRy4&v1>=2/y1=v6361:S99;
!!VRy4&v1>=3/y1=v6362:S99;
!!VRy4&v1>=4/y1=v6363:S99;
!!VRy4&v1=5/y1=v6364:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S6359 +v1;
!!VRy5&y2>0/y4<>99:S179 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;

!!HE-1:C0/6/?y1/?y2;   [Slot 6]
!!VRy4:S0;
!!VRy4&v1>=1/y1=v6360:S99;
!!VRy4&v1>=2/y1=v6361:S99;
!!VRy4&v1>=3/y1=v6362:S99;
!!VRy4&v1>=4/y1=v6363:S99;
!!VRy4&v1>=5/y1=v6364:S99;
!!VRy4&v1=6/y1=v6365:S99;
!!VRv1&y2>0/y4<>99:+1;
!!VRy3&y2>0/y4<>99:S6359 +v1;
!!VRy5&y2>0/y4<>99:S179 +v1;
!!UN&y2>0/y4<>99:N3/y5/y1/1;
!!VRvy3&y2>0/y4<>99:Sy1;

!!VRz187:S^Select the creature which you want to modify:^;
!!VRz188:S^Exit^;
!!VRv6111:S0;
!!IF:G1/6111/0/187/180/181/182/183/184/185/186/188;

!!FU&v6111=128:E;

!!VRv2:S0;
!!VRv2&v6111=1:Sv6360;
!!VRv2&v6111=2:Sv6361;
!!VRv2&v6111=4:Sv6362;
!!VRv2&v6111=8:Sv6363;
!!VRv2&v6111=16:Sv6364;
!!VRv2&v6111=32:Sv6365;
!!VRv2&v6111=64:Sv6366;

!!FU28714&v6111<128:P;

!?FU28714;    Present a list of Skills to chose an improvement
!!VRz31:S^Attack^;
!!VRz32:S^Defense^;
!!VRz33:S^Damage^;
!!VRz34:S^Health^;
!!VRz35:S^Speed^;

!!VRz36:S^^;  Initialize shots text to null
!!MA:Nv2/?y6;    check number of shots
!!if&y6>0/y6<48;
 !!VRz36:S^48 Shots^;
!!en:;

!!VRz37:S^^;  Initialize casts text to null
!!MA:Bv2/?y7; check number of casts
!!if&y7>0;   if number of casts >0 creature is a caster
 !!VRz37:S^One extra cast (costs an extra 3 of mithril)^;
!!en:;

!!VRz38:S^A new special hability (costs an extra 5 of mithril)^;

!!VRz39:S^Exit^;
!!VRz20:S^Choose the skill you want to improve^;

!!VRv6112:S0;
!!IF:G1/6112/0/20/31/32/33/34/35/36/37/38/39;

!!FU&v6112=256:E;

!!if&v6112=1:;   [Attack bonus]
 !!MA:Av2/d5;
!!en:;
!!if&v6112=2:;  [Defense bonus]
 !!MA:Dv2/d5;
!!en:;
!!if&v6112=4:;  [Damage  bonus]
 !!MA:Ev2/?y1;   check max damage
 !!VRy2:Sy1 :4;   get 25%
 !!VRy2&y2<3:S3;  if result less then 3 then set to 3
 !!MA:Ev2/dy2;   give bonus

 !!MA:Mv2/?y1;   check min damage
 !!VRy2:Sy1 :4;   get 25%
 !!VRy2&y2<3:S3;  if result less then 3 then set to 3
 !!MA:Mv2/dy2;   give bonus
!!en:;
!!if&v6112=8:;  [Health  bonus]
 !!MA:Pv2/?y1;   check health
 !!VRy2:Sy1 :4;   get 25%
 !!VRy2&y2<5:S5;  if result less then 5 then set to 5
 !!MA:Pv2/dy2;   give bonus
!!en:;
!!if&v6112=16:; [Speed  bonus]
 !!MA:Sv2/?y1;   check speed
 !!VRy2:Sy1 :4;   get 25%
 !!VRy2&y2<1:S1;  if result less then 1 then set to 1
 !!MA:Sv2/dy2;   give bonus
!!en:;

!!if&v6112=32:;   [Shots bonus]
 !!MA:Nv2/48;
!!en:;

!!if&v6112=64:;   [Spell casting bonus]
 !!if&v6119<3:;
    !!IF:M^Not enouch mithril^;
    !!FU&v6119<3:E;
 !!en:;
 !!MA:Bv2/d1;
!!en:;

!!if&v6112=128:; [Special Habilities]
 !!if&v6119<5:;
    !!IF:M^Not enouch mithril^;
    !!FU&v6119<5:E;
 !!en:;
 !!FU28715:P;
!!en:;

!!FU28711:P;
!!IF&v6112<256:M^Done!^;

!?FU28715;  Build a List of Special Habilities Creature still doesn't have
!!MA:Xv2/?v3;
!!VRy1:Sv3;
!!VRy1:&2;
!!VRz41&y1=0:S^Fly^;
!!VRz41&y1=2:S^^;
!!VRy1:Sv3;
!!VRy1:&8;
!!VRz42&y1=0:S^Dragon Breath^;
!!VRz42&y1=8:S^^;
!!VRy1:Sv3;
!!VRy1:&131072;
!!VRz43&y1=0:S^No Moral^;
!!VRz43&y1=131072:S^^;
!!VRy1:Sv3;
!!VRy1:&32768;
!!VRz44&y1=0:S^Two Attacks^;
!!VRz44&y1=32768:S^^;
!!VRy1:Sv3;
!!VRy1:&524288;
!!VRz45&y1=0:S^Attack All Around^;
!!VRz45&y1=524288:S^^;
!!VRy1:Sv3;
!!VRy1:&65536;
!!VRz46&y1=0:S^No Retaliation^;
!!VRz46&y1=65536:S^^;
!!VRy1:Sv3;
!!VRy1:&1024;
!!VRz47&y1=0:S^Immune to Mind Spells^;
!!VRz47&y1=1024:S^^;
!!VRy1:Sv3;
!!VRy1:&16384;
!!VRz48&y1=0:S^Immune to Fire Spells^;
!!VRz48&y1=16384:S^^;

!!VRy1:Sv3;
!!VRy2:Sv3;
!!VRy1:&4096; (Check No Close Combat Penalty)
!!VRy2:&4;    (Check Shooter)
!!VRz49&y1=0/y2=4:S^No Close Combat Penalty^;
!!VRz49&y1=0/y2=0:S^^;
!!VRz49&y1=4096:S^^;

!!VRz50:S^Exit^;
!!VRz40:S^Choose the hability you want to add^;
!!VRv6115:S0;
!!IF:G1/6115/0/40/41/42/43/44/45/46/47/48/49/50;
!!FU&v6115=512:E;

*** Add the Special Hability
!!VRy2&v6115=1:S2;       [Fly: y2]
!!VRy2&v6115=2:S8;       [Extended Attack: y2]
!!VRy2&v6115=4:S131072;  [Unaffected by Morale: y2]
!!VRy2&v6115=8:S32768;   [Two Attacks: y2]
!!VRy2&v6115=16:S524288;  [Attack All Around: y2]
!!VRy2&v6115=32:S65536;   [No Retaliation: y2]
!!VRy2&v6115=64:S1024;    [Immunity to Mind Spells: y2]
!!VRy2&v6115=128:S16384;   [Immunity to Fire Spells: y2]
!!VRy2&v6115=256:S4096;   [No Close Combat Penalty: y2]

!!MA:Xv2/?y1; [Read Creature Flags: y1]
!!VRy1:|y2; [OR Creature Flags (y1) with Special Ability bit (y2): y1]
!!MA:Xv2/y1; [Set updated Creature Flags: y1]


!?FU28711;        Remove resources for payment
!!FU|v6111=128/v6112=256/v6115=512:E;

!!OW:R-1/0/d-5;
!!OW:R-1/1/d-3;
!!OW:R-1/2/d-5;
!!OW:R-1/3/d-3;
!!OW:R-1/4/d-3;
!!OW:R-1/5/d-3;

!!if&v6112=64:;
  !!OW:R-1/7/d-3;
!!en:;

!!if&v6112=128:;
  !!OW:R-1/7/d-5;
!!en:;



 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Orzie
Orzie


Responsible
Supreme Hero
posted November 20, 2014 06:57 AM
Edited by Orzie at 06:57, 20 Nov 2014.

A question about changing the map version manually

Just wanted to ask if it is possible to change the map format from WoG back to RoE, AB and/or SoD, either by hex editing or any other way. This is a very much required development. I have heard about some sort of a tool for that before, but never seemed to find it. Any suggestions?

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Salamandre
Salamandre


Admirable
Omnipresent Hero
Wog refugee
posted November 20, 2014 07:10 AM

Ask Biobob, HERE. That map is made with wog then hex reversed to sod.
____________
Era II mods and utilities

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
orzie
orzie


Responsible
Supreme Hero
posted November 20, 2014 01:11 PM

Thanks a lot, I hope this will be helpful.

 Send Instant Message | Send E-Mail | View Profile | Quote Reply | Link
Jump To: « Prev Thread . . . Next Thread » This Popular Thread is 407 pages long: 1 50 100 150 200 ... 245 246 247 248 249 ... 250 300 350 400 407 · «PREV / NEXT»
Post New Poll    Post New Topic    Post New Reply

Page compiled in 0.5684 seconds